StringRegExpReplace

[tempman 0]

Hi, I have a log with bunch of text and numbers.

pattern:

text then space than 3 random numbers then space then 1-6 random numbers then space then "text"

example:

some text 528 470316 "some text"

I need to put @TAB insted of space ONLY between numbers

some text 528@TAB470316@TAB"some text"

Local $sInput = 'some text 528 470316 "some text"'
Local $sOutput = StringRegExpReplace($sInput, '<WHAT HERE?>', '<WHAT HERE?>')
MsgBox(0, "Results", $sOutput)

[guinness 1,515]

Try this, look at the help file to understand what is going on.

#include <Constants.au3>

Local $sString = 'some text 528 470316 "some text"' ; some text 528@TAB470316@TAB"some text"
Local $sOutput = StringRegExpReplace($sString, '(?m)^([\D]+\d{3}\h)(\d{1,6})([^\r\n]+)', '\1' & @TAB & '\2' & @TAB & '\3' & @CRLF)
MsgBox($MB_SYSTEMMODAL, '', $sOutput)

[tempman 0]

Cheers!

[PhoenixXL 168]

@Guinness,

you are complicating the pattern

according to the condition replace the space preceded by a digit

Local $sString = 'some text 528 470316 "some text"' ; some text 528@TAB470316@TAB"some text"
MsgBox(64, '', StringRegExpReplace($sString, '(\d)( )', _ ;First Group Captures the Digit followed by a space [space is captured in second group]
'\1' & @TAB _ ;Restore the first group and add TAB after that
))

;Using lookarounds would be more easier
MsgBox(64, '', StringRegExpReplace($sString, '(?<=\d)( )', _ ;First Group Captures the Space preceded by a digit [Lookbehind are non-capturing]
@TAB _ ;Replace the space with the TAB
))

Edited January 21, 2013 by PhoenixXL

[guinness 1,515]

@Guinness,

you are complicating the pattern

Whoops, sorry.

[JohnQSmith 40]

@Guinness,

you are complicating the pattern

Not if some text ends with a digit. Yes, I know the OP didn't mention that possibility, but then again it wasn't ruled out either.

[PhoenixXL 168]

Not if some text ends with a digit.

Right that would match my given pattern, but that could be modified as follows

#cs
Replaces the Space preceded by a pure digit(s) into a TAB
#ce

Local $sString = 'some text2 100 528 470316 123 333 "some text"' ; some text 528@TAB470316@TAB"some text"

SetExtended(1) ;Set Extended for initiation
While @extended
$sString = StringRegExpReplace($sString, '(\h\d+)( )', _ ;First Group Captures the Space preceded by a "horizontal space follwed by a digit(s)"
'\1' & @TAB, 1) ;Restore the horizontal space and the digits and Replace the space with the TAB,  do the replacement only once.
WEnd

ConsoleWrite( StringFormat( 'Current Fixed Pattern : %s\n' , $sString) )

Instead of making the pattern to match the full string, a small part could help in better error checking and flexibility

Edited January 22, 2013 by PhoenixXL

[guinness 1,515]

PhoenixXL,

I've never thought about using SetExtended in this way, don't know if this is considered a good approach or not, first time I've seen it being used other then when returning from a function.

[PhoenixXL 168]

don't know if this is considered a good approach or not

I was lazy enough to add a "If then" statement for checking the extended macro. The approach is good till the time no other function is used inside the loop (orelse the macro would be reset)

Plus a Do Until loop would do the same effect without the requirement of the initiation,

Do
StringRegExpReplace( ... )
Until Not @extended

But habits sometimes show up

Edited January 23, 2013 by PhoenixXL