If WinVista or later...?

[supraspecies]

Hello. Im looking to make an IF statement with condition "IF WinVista OR later...". I know I can write it like:

If @OSVersion="Win_Vista" OR @OSVersion="Win_7" OR @OSVersion="Win_8"

but i don't want to do it like that. Won't be compatible with future OS.

I also don't want to make:

If NOT @OSVersion="Win_XP" OR @OSVersion="Win_XPe" OR @OSVersion="Win_2000"

because I don't want to exclude every single OS ever made. There has to be a better way.

I'm particulary interested in "or later..." part.

Hm... Maybe @OSBuild? If the build number increases with each OS, that could be a way. But I don't know that for certain.

Edited March 2, 2013 by supraspecies

[KaFu]

I use this WinApiEx internal functions in all of my programs to detect the OS version.

Here's the MSDN documentation for this function.

$__WINVER = __WINVER()

if $__WINVER >= 0x0600 then ; Vista or higher
    ConsoleWrite($__WINVER & @tab & "Vista or higher" & @crlf)
Else
    ConsoleWrite($__WINVER & @tab & "Lower than Vista" & @crlf)
endif

Func __WINVER()
    Local $tOSVI = DllStructCreate('dword;dword;dword;dword;dword;wchar[128]')
    DllStructSetData($tOSVI, 1, DllStructGetSize($tOSVI))
    Local $Ret = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'ptr', DllStructGetPtr($tOSVI))
    If (@error) Or (Not $Ret[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    Return BitOR(BitShift(DllStructGetData($tOSVI, 2), -8), DllStructGetData($tOSVI, 3))
EndFunc ;==>__WINVER

Edited March 2, 2013 by KaFu

[supraspecies]

Yes, looks like it's what I'm looking for. Thank you very much.

[guinness]

Or

Func _IsWindowsVersion()
    Return RegRead('HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\', 'CurrentVersion') >= 6.0
EndFunc   ;==>_IsWindowsVersion

[Chimaera]

Or

Global $OS = _OsDetect()

Func _OsDetect()
Local $OS = 'V+'
If @OSVersion = 'WIN_2000' Or @OSVersion = 'WIN_2003' Or @OSVersion = 'WIN_XP' Or @OSVersion = 'WIN_XPe' Then
$OS = 'V-'
EndIf
;~ ConsoleWrite($OS & @CRLF)
Return $OS
EndFunc ;==>_OsDetect

The lower ones never change

[supraspecies]

Or

Global $OS = _OsDetect()

Func _OsDetect()
Local $OS = 'V+'
If @OSVersion = 'WIN_2000' Or @OSVersion = 'WIN_2003' Or @OSVersion = 'WIN_XP' Or @OSVersion = 'WIN_XPe' Then
$OS = 'V-'
EndIf
;~ ConsoleWrite($OS & @CRLF)
Return $OS
EndFunc ;==>_OsDetect

The lower ones never change

True enough, but I'm just a perfectionist of sorts. What if someone tries to install my program on Win95? Win98? WinME? Win 3.11? Come to think of it, I'm not even sure what's gonna happen if someone tries to run an AutoIT script under these OS. Edited March 3, 2013 by supraspecies

[Chimaera]

True enough, but I'm just a perfectionist of sorts. What if someone tries to install my program on Win95? Win98? WinME? Win 3.11? Come to think of it, I'm not even sure what's gonna happen if someone tries to run an AutoIT script under these OS.

It wouldn't be supported anyway, most of AutoIt is Windows 2000 upwards.

[guinness]

Even though it isn't supported by AutoIt, it should work to a certain degree.

[JFX]

Hm... Maybe @OSBuild? If the build number increases with each OS, that could be a way. But I don't know that for certain.

Exactly, Build nummer will increase with every windows version, usually even with every SP.

IF @OSBuild >= 6000 Then
MsgBox(0, "", "Vista or later")
EndIf

[BrewManNH]

True enough, but I'm just a perfectionist of sorts. What if someone tries to install my program on Win95? Win98? WinME? Win 3.11? Come to think of it, I'm not even sure what's gonna happen if someone tries to run an AutoIT script under these OS.

If you have anyone still using those versions of Windows, they'll find out soon enough that it won't work for them. Why do you care that someone is using an OS from the last century? Is it your problem to try to fix the world's stupidity within your script? You can only make reasonable assumptions as far as what to check for, once you get past the desire to prevent every possible problem, you'll realize that you can only fix what is reasonable to expect.

Put a disclaimer in the code to tell whoever that it only works on Windows OSs from, for example, Vista and above, and that if they use it on anything else then it's their problem and not your's.