Using Regex in _ArraySearch to find CRLF

[gritts]

I am working on a script that parses through a log file. At then end of a log file entry (several lines) there is a blank line (CRLF). I want to use the _ArraySearch and the Regex search option to determine what line the current entry I am parsing ends. The closest I have come is below but it only matches the CRLF that my loop through the file array is on.

The log file is read into an array. Once I match the first criteria, I search for the end of the related log entries (the CRLF). Once I have that information I will do further parsing. I'm just stuck getting the results I need.

For $aRow = 1 to $aDumpFile[0]
    ;ConsoleWrite($aDumpFile[$aRow]&@CRLF)
    If StringInStr($aDumpFile[$aRow],"AB000DD4") Then
        $iEntryEnd = _ArraySearch($aDumpFile,"(*CRLF)",$aRow,0,0,3)
        ConsoleWrite("Entry End: "&$iEntryEnd&@CRLF)
        For $aSubRow = $aRow to $iEntryEnd
            ConsoleWrite("Sub entry: "&$aDumpFile[$aSubRow]&@CRLF)
        Next
    EndIf

Next

[BrewManNH]

How are you getting the log file into the array? Is the blank line in your array? Is there a CRLF in that spot in the array or is it just an empty entry? If it's just an empty entry look for that, if it's a CRLF look for that, because the other entries probably won't contain a CRLF anywhere in them.

[guinness]

So you know R determines an EOL char.

[gritts]

I am not sure if the CRLF is being read in as part of the array to be honest. I had thought of searching for @CRLF alone and didn't come out with a method using the _ArraySearch. (Probably is a means but when you work on 6 things at once  )

The log file I am parsing is read into the array with the following:

_FileReadToArray(@ScriptDir&"\20140909.dmp",$aDumpFile)

Don't let the extension distract you, it is just a text file with a different extension.

I've played with this some more using what is in the help files and I think my "trying to overthink REGEX" is shooting me in the foot here. 

[BrewManNH]

If there's a blank line in the log, it will more than likely show up as an empty string in the array. Do a search for any empty elements in your array by looping through the array. Something like this.

#include <MsgBoxConstants.au3>
#include <array.au3>
Example()

Func Example()
    ; Read the file into an array using the filepath.
    Local $aArray = FileReadToArray("C:\Windows\WindowsUpdate.log")
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "", "There was an error reading the file. @error: " & @error) ; An error occurred reading the current script file.
        Return
    Else
        _ArrayDisplay($aArray)
    EndIf
    For $I = 0 To UBound($aArray) - 1
        ; Loop through the array and look for empty strings in an array element
        If $aArray[$I] = "" Then ConsoleWrite("Empty line found in $aArray[" & $I & "]" & @CRLF)
    Next
EndFunc   ;==>Example

Edited September 10, 2014 by BrewManNH

[kylomas]

gritts,

Can you post a representative example of the file?

[mikell]

Maybe isolate the wanted part before reading to array ?

#Include <Array.au3>

$txt = "AutoIt has been designed to be as small as possible and stand-alone with no external .dll files " & @crlf & _ 
"or registry entries required making it safe to use on Servers."  & @crlf & _ 
"Scripts can be compiled into stand-alone executables with Aut2Exe." & @crlf & _ 
@crlf & _ 
"Also supplied is a AB000DD4 combined COM and DLL version of AutoIt called AutoItX." & @crlf & _ 
"that allows you to add the unique features of AutoIt" & @crlf & _ 
"to your own favorite scripting or programming languages!" & @crlf & _ 
 @crlf & _ 
"Best of all, AutoIt continues to be free - but if you want to support the time, " & @crlf & _ 
"money and effort spent on the project and web hosting then you may donate at the AutoIt homepage." & @crlf 

Msgbox(0,"", $txt)   ; initial text
 
$res = StringRegExpReplace($txt, '(?s).*\R{2}(.*?AB000DD4.*?)\R{2}.*', "$1")  ; isolate the part
$lines = StringRegExp($res, '(?m)^(\N*)\R?', 3)   ; read the part to array 
_ArrayDisplay($lines)

Edited September 10, 2014 by mikell

[gritts]

Thank you guys for your input. @Univarsilist your code pretty much is what I do to locate the section of the log I wish to parse.

For example:

Here is some test text from process AKB48 that completed a 4:00pm

Stat 1: 334

Stat 2: 4456

Stat 3: 5543

<crlf>

Here is some test text from process BR549 that completed a 4:00pm

Stat 1: 352

Stat 2: 44446

Stat 3: 5522

<crlf>

 

Once I have isolated the section, I plan to parse through that section using the starting and ending row numbers determined. Then possibly rinse repeat with a new value.

 

I did manage to locate the end of a section with the following:

$iEntryEnd = _ArraySearch($aDumpFile,"",$aRow)

For learning sake I'd like to figure out how to do the same with REGEX. 

[jchd]

Geez, I didn't realized mikell gave it ealier...

[kylomas]

gritts,

Not an SRE solution but may be useful to you...

#include <array.au3>

local $str  =   'Stat 1: 334' & @crlf & 'Stat 2: 4456' & @crlf & 'Stat 3: 5543' & @crlf & _
                @crlf & 'Stat 1: 352' & @crlf & 'Stat 2: 44446' & @crlf & 'Stat 3: 5522' & @crlf & @crlf & 'blah blah blah'

local $aRSLT = stringsplit($str,@crlf & @crlf,3)

for $1 = 0 to ubound($aRSLT) - 1
    ConsoleWrite('!  Set # ' & $1+1 & @CRLF & $aRSLT[$1] & @lf)
next

kylomas

[nitekram]

I figured that there was a post on this, so I would not start another one. I have done a search for "" and " " both are found, but there are others elements, that have LF or many spaces, how do I go about finding them, without a loop, adding one more space, and then search again? I want to find empty (no data) on any array element?

[mikell]

What you want to do is not clear
Could you provide an example ?

[nitekram]

I have an array from a test file that was created by coping the text of an alert and writing it to the file. There are multiple blank lines in my array, that I want to remove. I have removed a few of them, that have either nothing on them, or one space, but in my tests there are other lines that I am not finding in my search - I am trying to remove those lines and merge them together with the first original line of the alert. These alerts are copied from different browsers, so each on has its own unique format - same alert from the different browsers, comes in in different formats - all ASCII, but some have multiple spaces, or EOL, or something that I am not able to find?

 

I have tried this example, but it does not work.

  On 12/13/2013 at 8:14 AM, guinness said:

I use this to convert EOL characters to CRLF.

#include <Constants.au3>

; Convert all line endings to @CRLF.
Local $sString = StringEOLToCRLF("This is a sentence " & @CR & Chr(12) & "with " & Chr(13) & "whitespace." & @CRLF)

; Display the converted line endings.
MsgBox($MB_SYSTEMMODAL, "", $sString)

; Visually display that @CR and @LF have converted to @CRLF.
$sString = StringReplace($sString, @CRLF, '@CRLF')
MsgBox($MB_SYSTEMMODAL, "", $sString)

Func StringEOLToCRLF($sString) ; Regular expression by Melba23 and modified By guinness.
    Return StringRegExpReplace($sString, '((?<!\r)\n|\r(?!\n))', @CRLF)
    ; Return StringRegExpReplace($sString, '\R', @CRLF) ; By Ascend4nt
EndFunc   ;==>StringEOLToCRLF

 

 

My sample text is as follows. The last two are the exact same alert, yet I did change the info, as it is proprietary.

  Quote

11/11/15 09:26:20 AM

 

 

 

 

 

System Up Time : Notification Text (System Up Time : IP Address (X.X.X.X) : System ID (someID) : UpTime ( 6 Days, 13 Hours, 35 Minutes, 53

Seconds))

  Quote

 

11/11/15 10:45:48 AM
                        
PRISTAT Alarm - X : Alarm Text (Error - X,X : System ID (someID) : System IP Address (X.X.X.X) : Alarm Text (Part

status report Event Source: TYPE Status Down Filename: SomeFileName Line Number 1234) : Log Date and Time (Nov 11 11:53:19) : Code

X,X (X)) : Code X(X)

  Quote

 

11/11/15 10:45:48 AM
PRISTAT Alarm - X : Alarm Text (Error - X,X : System ID (SomeID) : System IP Address (X.X.X.X) : Alarm Text (Part

status report
 Event Source: TYPE
 TYPE
 Status Down
 Filename: SomeFileName
 Line Number 1234
 
 ) : Log Date and Time (Nov 11 11:53:19) :

Code X,X (X)) : Code X (X)

.

Edited November 12, 2015 by nitekram

[nitekram]

This is the closest I have come:

 

If $string = '' Or $string = ' ' Then ContinueLoop
If (StringRegExp($string, "\S", 1)) Then
; Grab the line unless it is only whitespaces.
    $sNewBody &= $string]
EndIf

EDIT

But this still is leaving me with blank lines - I am at a loss.

EDIT 2

Yeah, I had other code mixed in, so this did not work as I thought.

Edited November 12, 2015 by nitekram

[mikell]

#Include <Array.au3>

$sText = FileRead("1.txt")
Msgbox(0,"", $sText)

$lines = StringRegExp($sText, '\s*(\N+)\s*', 3)
_ArrayDisplay($lines)

Local $res
For $i = 0 to UBound($lines)-1
   $res &= $lines[$i] & " "
Next
Msgbox(0,"", $res)

Edit
Sorry, I was a little too hasty
This one works on your 3 sample texts

Edited November 12, 2015 by mikell

[nitekram]

That worked great...I wish I could get a handle on RegExp.

Thanks for your help and time.

 

EDIT - spelling

.

 

Edited November 13, 2015 by nitekram

[iamtheky]

$sText = "Entry 1 Generic log entry" & @CRLF & "Entry 2, " & @LF & "multline Security log entry" & @CRLF & "Entry 3, " & @LF & "multiline System log entry" & @CRLF &  "Entry 4, Application log entry" & @CRLF & "Line 5, telemetry log entry" & @CRLF & "Line 6 log entry"
$aText = stringsplit($sText , @CRLF , 3)


;~ $target = "Security"
$target = "System"
;~ $target = "Application"


For $entry in $aText
    If stringinstr($entry , $target) Then msgbox(0, '' , $entry)
Next

 

 

If the OP legitimately needs to separate by the next @CRLF after having selected another criteria (string i am assuming), and no other edge cases.

 

Edited November 12, 2015 by boththose