Episode Seeker

[EmilyLove]

I watch alot of anime and stuff and some sites don't have navigation to go to the next or previous episode or it's inconvenient. To resolve my delima, I created a script to change episodes at the press of a hotkey. It will work with any site that tracks the episode via url, in sequential order, and isn't also tracked by another identifier. Sites like Hulu and Crunchyroll won't work (tho their navigations is anything but inconvient). No this is for more obscure websites that have a simple url layout like www.example.com/video/bleach-024-engligh-dub.

To start up it will give you instructions. Hover over the first digit of the episode in the url(in the above example,  you would put your mouse over the 0) and press Ctrl+Insert to set the coordinates. From now on, when you press Ctrl+Left/Right, you will go forward or back an episode based on which button you pressed. It clicks the url, copies the ep number only, changes the ep number in variable, format it for leading 0 to match the source, and paste back in and submit, all in half a sec. It also attempts to exit full screen by pressing esc.

Here is the source. You don't need to do anything special to compile it. All of my works are open source and licensed with GPLv3. Enjoy =D

expandcollapse popup

Global $x = "656";some default coordinates to load on start
Global $y = "44" ;^
Opt("WinTitleMatchMode", -2);Case insensitive ANYWHERE match mode
HotKeySet("^{ins}", "GetCoord")
HotKeySet("^{left}", "SeekPrev")
HotKeySet("^{right}", "SeekNext")
MsgBox(0, "How To Use", "Move your mouse under the first digit in the url that keeps track of which episode you are on, then press Ctrl+Insert.")
While 1;idle when not in use
    Sleep(1000)
WEnd
Func SeekPrev()
    Seek("Left")
EndFunc   ;==>SeekPrev
Func SeekNext()
    Seek("Right")
EndFunc   ;==>SeekNext
Func Seek($direction)
    ClipPut("");Erase contents of clipboard.
    Select ;First one that is true is the only one that gets used. If you have other browsers running, you may need to reorder this list.
        Case ProcessExists("iexplorer.exe") = True ;If iexplorer.exe is running then...
            $wintitle = "Internet Explorer";Use internet explorer.
        Case ProcessExists("MicrosoftEdge.exe") = True
            $wintitle = "Microsoft Edge"
        Case ProcessExists("opera.exe") = True
            $wintitle = "Opera"
        Case ProcessExists("firefox.exe") = True
            $wintitle = "Firefox"
        Case ProcessExists("chrome.exe") = True
            $wintitle = "Chrome"
        Case Else;Throws an error message incase you used a browser that is not set up.
            MsgBox(0, "Incompatible browser used.", "Unable to find a compatible browser to manipulate. Please use one of the follow browsers and try again: Chrome, Firefox, Opera, Microsoft Edge, Internet Explorer." & @CRLF & "You could also add an entry for your own browser. See Lines 24-33.")
            Exit
    EndSelect
    WinActivate($wintitle);Activate the window if it wasn't focused
    ControlSend($wintitle, "", "", "{esc}");Exit fullscreen (Note: ESC does not exit fullscreen on some sites)
    Sleep(50);give your browser some time to exit fullscreen.
    ControlClick($wintitle, "", "", "left", 2, $x, $y);Click where you set the coordinates.
    Do
        ControlSend($wintitle, "", "", "^c");Copy selected text to clipboard.
        $clipboard = ClipGet();Get the contents of the clipboard and store it in a string variable.
    Until StringLen($clipboard) > 0 ;Error Check Function, Make sure something was copied into the clipboard, else it waits until something is copied. It should be the value of the current ep you are on.
    $format = '%0' & StringLen($clipboard) & 'd'; Set the text format to be the same length as the original, padded with any 0's the original had.
    If $direction = "Left" Then ;If launched with Seek("Left") then decrease ep counter
        $clipboard = $clipboard - 1
    Else;Else Increase it
        $clipboard = $clipboard + 1
    EndIf
    $clipboard = StringFormat($format, $clipboard);format updated clipboard variable
    ClipPut($clipboard);write to clipboard the contents of $clipboard
    ControlSend($wintitle, "", "", "^v");paste clipboard, replacing the old ep in the url with tne new one.
    Sleep(50);Some browsers need to wait a moment after pasting, else it won't submit the correct request to the requested page.
    ControlSend($wintitle, "", "", "{enter}");Submit request to website.
EndFunc   ;==>Seek
Func GetCoord();This function sets the coordinates to be used in Seek()
    Local $coord = MouseGetPos();Get mouse Coordinates
    $x = $coord[0];Rewrites previous global variable
    $y = $coord[1];Rewrites previous global variable
    MsgBox(0, "Coordinates Updated", "X = " & $x & "." & @CRLF & "y = " & $y & "." & @CRLF & @CRLF & "Press Ctrl+Left to Seek Back" & @CRLF & "Press Ctrl+Right to Seek Forward")
EndFunc   ;==>GetCoord

 

[argumentum]

I had to re-start the PC after running your code 

[guinness]

I had to re-start the PC after running your code 

Care to enlighten the OP what exactly happened so they can fix it.

[argumentum]

Care to enlighten the OP what exactly happened so they can fix it.

sure, I loaded the code an run it here on this same page. It did not like it. No big deal. The Ctrl key got stuck or something. I should have not run it. I was lazy and curious . My bad.

[EmilyLove]

Yea, sorry. I have no idea how to fix CTRL key getting stuck. I have tried sending down and up commands in previous scripts but it still glitches up. You can also just close the script from the tray in the taskbar (near the clock) if you have issues.

It should also be noted that this script was designed to work with sites that host videos and follow a certain url pattern. It's pointless to use this script on this website.

Edited September 16, 2015 by BetaLeaf