IpAddress field

[mar3011]

hi I have a problem with the IP address field I want to enter the indicated page on the Internet after entering the IP address, but it does not work pops up all the time, "
Make sure that the web address http://0.0.0.0 is correct. "From the input field everything works, but I want to write in this field only the IP address, I used to enter the ES_Numbers style it works, but I can only write the number, dots do not work.I have read the help file about  _GUICtrlIpAddress_Create but it did not help me,anyone can help?

here is code

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <IE.au3>
#include <GuiIPAddress.au3>
#Region ### START Koda GUI section ### Form=C:\Users\Marcin\Desktop\Projekty Oficjalne\AutoLogin\AutoLog.kxf
$Form1 = GUICreate("Internet Login", 542, 181, 339, 261)
$Group3 = GUICtrlCreateGroup("IP ADDRESS E.G..192.168.0.1", 16, 40, 161, 49)
$IpAddress =  _GUICtrlIpAddress_Create($Form1, 24, 56, 145, 21)

$gPin = GUICtrlCreateInput("", 216, 56, 105, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
$gHaslo = GUICtrlCreateInput("", 216, 112, 105, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
$Btn_Zaloguj = GUICtrlCreateButton("Log In", 216, 152, 97, 25)
$Group1 = GUICtrlCreateGroup("Your Pin", 208, 40, 121, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Your Password", 208, 96, 121, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("", -99, -99, 1, 1)
 $oIE = _IECreateEmbedded()
 $object=GUICtrlCreateObj($oIE,336, 8, 201, 169)
GUISetState(@SW_SHOW)



While 1
    $msg = GUIGetMsg()
    if $msg=-3 Then Exit
    If $msg=$Btn_Zaloguj Then Btn_Zaloguj()
WEnd

Func Btn_Zaloguj()
    $read1=GuiCtrlread($IpAddress)
    _IENavigate($oIE,$read1)
    EndFunc

[FrancescoDiMuro]

Good morning @mar3011
I tried your script, and the IP Address field seems to work correctly.
What is the issue?

[mar3011]

44 minutes ago, FrancescoDiMuro said:

Good morning @mar3011
I tried your script, and the IP Address field seems to work correctly.
What is the issue? 

I am popping up: "I can not display the page" and this is the ip address to my login router,

 

 

Edited July 30, 2018 by mar3011

[careca]

Fails because _GUICtrlIpAddress_Create retrieves a handle.

 

Func Btn_Zaloguj()
    $read1=GuiCtrlread($IpAddress)
    _IENavigate($oIE,_GUICtrlIpAddress_Get ( $IpAddress ))
EndFunc

 

[careca]

I liked this and saved it for myself, just did a couple of changes:

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <IE.au3>
#include <WinAPI.au3>
#include <GuiIPAddress.au3>
#Region ### START Koda GUI section ### Form=C:\Users\Marcin\Desktop\Projekty Oficjalne\AutoLogin\AutoLog.kxf
$Gui = GUICreate("Internet Login", 1, 1)
WinMove($Gui, '', 0,0,@DesktopWidth/1.7, @DesktopHeight/1.75)
;=============================================================================
$Group3 = GUICtrlCreateGroup("IP ADDRESS E.G..192.168.0.1", 16, 40, 161, 49)
$IpAddress =  _GUICtrlIpAddress_Create($Gui, 24, 56, 145, 21)
_GUICtrlIpAddress_Set($IpAddress, '192.168.1.1')
;=============================================================================
$Group1 = GUICtrlCreateGroup("Your Pin", 40, 100, 121, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$gPin = GUICtrlCreateInput("", 50, 120, 105, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
;=============================================================================
$Group2 = GUICtrlCreateGroup("Your Password", 40, 160, 121, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$gHaslo = GUICtrlCreateInput("", 50, 180, 105, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
;=============================================================================
$Btn_Zaloguj = GUICtrlCreateButton("Log In", 50, 220, 97, 25, $BS_DEFPUSHBUTTON)
;=============================================================================
 $oIE = _IECreateEmbedded()
 $object=GUICtrlCreateObj($oIE,190, 8, @DesktopWidth/2, @DesktopHeight/2)
GUISetState(@SW_SHOW)
;=============================================================================
While 1
    $msg = GUIGetMsg()
    if $msg=-3 Then Exit
    If $msg=$Btn_Zaloguj Then Btn_Zaloguj()
WEnd
;=============================================================================
Func Btn_Zaloguj()
    _IENavigate($oIE,_GUICtrlIpAddress_Get ( $IpAddress ))
EndFunc
;=============================================================================

 

Edited July 30, 2018 by careca