_GUIDisable() - Create a dimmed effect on a GUI.

[guinness]

Right Clicked (on Desktop) >> Personalize >> Basic and High Contrast Themes >> Windows Classic and then I ran Example 1 and it works so I'm lost at what the problem is.

Edited March 27, 2012 by guinness

[supersonic]

guinness,

you are right! ... in case of not using Group Policy Objects (Active Directory). We're using them to force the use of defined themes. Normally you cannot change to another theme if it is set by a GPO. If you do so (e. g. under MS-Windows 7 from Aero Theme to Cassic Theme), then a kind of a configuration conflict appears. The Aero or Classic Theme is neither active nor deacitve. It's a somehow strange state.

I'm trying to address this issue and figure out more about it. As soon as I have something reproducible I will post it.

Thanks for your help so far.

Greets,

-supersonic.

[supersonic]

guinness,

I was restless over this issue and found another way to get it almost solved. One of the problems is that MS-Windows XP and MS-Windows Vista+ behaves different if using '$WM_SIZEBOX'. Regarding this you have to use variant offsets. This UDF version can cover much more different theme cases - at least for me.

expandcollapse popup

#include-once

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
; #INDEX# =======================================================================================================================
; Title .........: _GUIDisable
; AutoIt Version : v3.2.2.0 or higher
; Language ......: English
; Description ...: Creates a dimming effect on the current/selected GUI.
; Note ..........:
; Author(s) .....: guinness
; Remarks .......: Thanks to Yashied for WinAPIEx.au3 and the idea of detecting operating system version information.
; ===============================================================================================================================

; #INCLUDES# ====================================================================================================================
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

; #GLOBAL VARIABLES# ============================================================================================================
Global $__GUIDisable_Array[2] = [0, 0]

; #CURRENT# =====================================================================================================================
; _GUIDisable: Creates a dimming effect on the current/selected GUI.
; ===============================================================================================================================

; #INTERNAL_USE_ONLY#============================================================================================================
; __GUIDisable_Animate: Animates the dimmed effect.
; __GUIDisable_OSVI: Detect if using Microsoft Windows Vista+.
; __GUIDisable_WM_SIZE: Automatically re-sizes the dimmed effect when the GUI is re-sized.
; ===============================================================================================================================

; #FUNCTION# ====================================================================================================================
; Name ..........: _GUIDisable
; Description ...: Creates a dimming effect on the current/selected GUI.
; Syntax ........: _GUIDisable($hHandle[, $iAnimate = 1[, $iBrightness = 5[, $bColor = 0x000000]]])
; Parameters ....: $hHandle             - GUI handle the effect should be applied to. This can either be a variable of the GUI handle or -1 for the current GUI.
;                  $iAnimate            - [optional] Animate the dimmed effect. Animate = 1 or don't animate = 0. Default is 1.
;                  $iBrightness         - [optional] Percentage of how bright the effect is. Default is 5.
;                  $bColor              - [optional] Color of the dimming effect. Default is 0x000000.
; Return values .: NSuccess - Returns handle of dimmed GUI.
;                  Failure - Returns 0 and sets @error to non-zero
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _GUIDisable($hHandle, $iAnimate = 1, $iBrightness = 5, $bColor = 0x000000)
    Local Const $AW_SLIDE_IN_TOP = 0x00040004, $AW_SLIDE_OUT_TOP = 0x00050008
    Local $iLabel, $aStyle, $aWinGetPos, $iLeft = 0, $iTop = 0, $bIsClassicTheme = False, $sCurrentTheme = RegRead("HKCUSoftwareMicrosoftWindowsCurrentVersionThemes", "CurrentTheme")

    If $hHandle = -1 And $__GUIDisable_Array[0] = 0 Then
        $iLabel = GUICtrlCreateLabel("", -99, -99, 1, 1)
        $hHandle = _WinAPI_GetParent(GUICtrlGetHandle($iLabel))
        If @error Then
            Return SetError(1, 0 * GUICtrlDelete($iLabel), 0)
        EndIf
        GUICtrlDelete($iLabel)
    EndIf

    Switch IsHWnd($__GUIDisable_Array[0])
        Case 0
            $__GUIDisable_Array[1] = $hHandle

            $aStyle = GUIGetStyle($__GUIDisable_Array[1])

            $bIsClassicTheme = (StringInStr($sCurrentTheme, "basic.theme", 0) = 0 And StringInStr($sCurrentTheme, "Ease of Access Themes", 0) > 0)

            If BitAND($aStyle[0], $WS_SIZEBOX) Then
                If __GUIDisable_OSVI() >= 0x0600 Then ; Microsoft Windows Vista+.
                    If $bIsClassicTheme Then
                        $iLeft -= 1
                        $iTop -= 1
                    Else
                        $iLeft -= 5
                        $iTop -= 5
                    EndIf
                Else
                    $iLeft -= 1
                    $iTop -= 1
                EndIf
            EndIf

            $aWinGetPos = WinGetClientSize($__GUIDisable_Array[1])
            $__GUIDisable_Array[0] = GUICreate("", $aWinGetPos[0], $aWinGetPos[1], $iLeft, $iTop, $WS_POPUP, $WS_EX_MDICHILD, $__GUIDisable_Array[1])
            GUISetBkColor($bColor, $__GUIDisable_Array[0])
            WinSetTrans($__GUIDisable_Array[0], "", Round($iBrightness * (255 / 100)))
            GUIRegisterMsg($WM_SIZE, "__GUIDisable_WM_SIZE")
            If $iAnimate Then
                __GUIDisable_Animate($__GUIDisable_Array[0], $AW_SLIDE_IN_TOP, 250)
            Else
                GUISetState(@SW_SHOW, $__GUIDisable_Array[0])
            EndIf
            GUISetState(@SW_DISABLE, $__GUIDisable_Array[0])
            GUISwitch($__GUIDisable_Array[1])

        Case Else
            If $iAnimate Then
                __GUIDisable_Animate($__GUIDisable_Array[0], $AW_SLIDE_OUT_TOP, 250)
            EndIf
            GUIDelete($__GUIDisable_Array[0])
            GUISwitch($__GUIDisable_Array[1])
            For $A = 0 To 1
                $__GUIDisable_Array[$A] = 0
            Next

    EndSwitch
    Return $__GUIDisable_Array[0]
EndFunc   ;==>_GUIDisable

; #INTERNAL_USE_ONLY#============================================================================================================
Func __GUIDisable_Animate($hHandle, $bSlide, $iSpeed)
    Return DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hHandle, "dword", $iSpeed, "dword", $bSlide)
EndFunc   ;==>__GUIDisable_Animate

Func __GUIDisable_OSVI() ; Taken from WinAPIEx.au3 by Yashied.
    Local $tGD_OSVI = DllStructCreate("dword;dword;dword;dword;dword;wchar[128]")
    DllStructSetData($tGD_OSVI, 1, DllStructGetSize($tGD_OSVI))
    Local $aGD_Return = DllCall("kernel32.dll", "int", "GetVersionExW", "ptr", DllStructGetPtr($tGD_OSVI))
    If (@error <> 0) Or (Not $aGD_Return[0]) Then
        Return SetError(1, 0, 0)
    EndIf
    Return BitOR(BitShift(DllStructGetData($tGD_OSVI, 2), -8), DllStructGetData($tGD_OSVI, 3))
EndFunc   ;==>__GUIDisable_OSVI

Func __GUIDisable_WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $iHeight = _WinAPI_HiWord($ilParam)
    Local $iWidth = _WinAPI_LoWord($ilParam)
    If $hWnd = $__GUIDisable_Array[1] Then
        Local $aWinGetPos = WinGetPos($__GUIDisable_Array[0])
        If @error = 0 Then
            WinMove($__GUIDisable_Array[0], "", $aWinGetPos[0], $aWinGetPos[1], $iWidth, $iHeight)
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>__GUIDisable_WM_SIZE

Please give feedback if you like.

Greets,

-supersonic.

Edited March 28, 2012 by supersonic

[guinness]

I will have a look and see what results I get, if everything works then I will use your idea but probably will go with this snippet of code for finding out whether or not the system is greater than Vista.

Func _IsWindowsVersion()
    Return RegRead("HKEY_LOCAL_MACHINESOFTWAREMicrosoftWindows NTCurrentVersion", "CurrentVersion") >= 6.0
EndFunc   ;==>_IsWindowsVersion

Thanks for your persistence in improving this UDF.

Edited March 28, 2012 by guinness

[guinness]

Thanks ever so much supersonic for your continue support and help. I updated the code with your suggestions just because it sorted your problem and I didn't see any problems on my machine. I also decided to remove a few unneeded functions (in my humble opinion.) I also changed the comparison in StringInStr to 2 as it's a little quicker.

Let me know if you're happy with how I credited you. Thanks.

[supersonic]

You're welcome! Everything is fine. Keep up the good work.

[guinness]

You're welcome! Everything is fine. Keep up the good work.

Thanks. You too.

[guinness]

I've updated the UDF and examples in the first post. Enjoy!

[Danyfirex]

thank you so much. this is excelent. regards

[guinness]

I updated the UDF in the initial post to fix 'an array out of bounds' if using a non-native AutoIt GUI, which this was initially designed for.

[guinness]

Example 2: Using a non-native AutoIt GUI.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#include '_GUIDisable.au3'

Example_2()

Func Example_2()
    ; Run Notepad
    Run('notepad.exe')

    ; Wait 10 seconds for the Notepad window to appear.
    Local $hWnd = WinWait('[CLASS:Notepad]', '', 5)

    ; Apply the dimmed effect.
    Local $hGUIDisable = _GUIDisable($hWnd, 1, 25)

    ; Get the position of the dimmed effect and adjust accordingly.
    Local $aWinGetPos = WinGetPos($hGUIDisable)
    If @error = 0 Then
        WinMove($hGUIDisable, '', $aWinGetPos[0] - 5, $aWinGetPos[1] - 5)
    EndIf

    ; Wait for 2 seconds to display the Notepad window.
    Sleep(2000)

    ; Destroy the dimmed effect.
    _GUIDisable($hWnd, 1)

    ; Wait for 1/2 second.
    Sleep(500)

    ; Close the Notepad window using the classname of Notepad.
    WinClose($hWnd)
EndFunc   ;==>Example_2

Edited January 7, 2013 by guinness

[guinness]

Updated the UDF with syntax changes only.

[mesale0077]

ı want

label add "hello word"

$Label1 = GUICtrlCreateLabel("hello word", 100, 55, 150, 180) ;<= add
GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif") ;<= add
GUICtrlSetColor(-1, 0xFFFFFF) ;<= added
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT);<= add

this code add

Example 2: Using a non-native AutoIt GUI.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#include '_GUIDisable.au3'

Example_2()

Func Example_2()
; Run Notepad
Run('notepad.exe')

; Wait 10 seconds for the Notepad window to appear.
Local $hWnd = WinWait('[CLASS:Notepad]', '', 5)

; Apply the dimmed effect.
Local $hGUIDisable = _GUIDisable($hWnd, 1, 25)

; Get the position of the dimmed effect and adjust accordingly.
Local $aWinGetPos = WinGetPos($hGUIDisable)
If @error = 0 Then
WinMove($hGUIDisable, '', $aWinGetPos[0] - 5, $aWinGetPos[1] - 5)
EndIf

; Wait for 2 seconds to display the Notepad window.
Sleep(2000)

; Destroy the dimmed effect.
_GUIDisable($hWnd, 1)

; Wait for 1/2 second.
Sleep(500)

; Close the Notepad window using the classname of Notepad.
WinClose($hWnd)
EndFunc ;==>Example_2

like this

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#include '_GUIDisable.au3'

Example_2()

Func Example_2()
Local $hGUI = GUICreate('_GUIDisable()', 300, 100, -1, -1, BitXOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX, $WS_MINIMIZEBOX))

Local $iButton_1 = GUICtrlCreateButton('Effect 1', 190, 70, 100, 25)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKSIZE + $GUI_DOCKTOP)

GUISetState(@SW_SHOW, $hGUI)

Local $hTimer = 0, $iLabel = 0
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop

Case $iButton_1
; Enable the dimmed effect on the current GUI with the animation turned on.
_GUIDisable(-1, 1, 25)

; Create a label with some text after calling _GUIDisable().
$iLabel = GUICtrlCreateLabel('SimpleText', 5, 5)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
$hTimer = TimerInit()
Do
; Exit the loop if $GUI_EVENT_CLOSE is captured by GUIGetMsg().
If GUIGetMsg() = $GUI_EVENT_CLOSE Then
ExitLoop
EndIf
Sleep(10)
Until TimerDiff($hTimer) > 3000

; Delete the control before closing _GUIDisable()
GUICtrlDelete($iLabel)

; Disable the dimmed effect with the animation turned on and add focus to the current GUI.
_GUIDisable(-1, 1)

EndSwitch
WEnd
GUIDelete($hGUI)
EndFunc ;==>Example_2

but nice code guinness,thank you

Edited February 2, 2013 by mesale0077

[guinness]

So you basically want to set the text to white? No clue as to why it's grey'ish. Sorry.

[Guest]

really good job!
But I also want to disable the top area of the window(where there is the button "X")

if you will add option for this then i will very thank you

[guinness]

Sorry, but that's not the purpose of the UDF.

[Guest]

ok..
but please do it! should not be a big problem to add such an option ..

I recommend you to consider the suggestions of the users because this way more users will use your udf.

I think that the "purpose" should be defined by the users

Edited October 4, 2013 by Guest

[guinness]

If it's easy to do then please do it.

Edited October 4, 2013 by guinness

[Guest]

If it's easy to do then please do it.

I mean for you this will be easy

For me it's hard. I'm bad when it comes to gui coding.

You are a genius.. So it should not be a problem for you.

[Guest]

ok i did it:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#include <Constants.au3>
#include <_GUIDisable.au3>

Example_1()

Func Example_1()
    Local $hGUI = GUICreate('_GUIDisable()', 300, 100, -1, -1, BitXOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX, $WS_MINIMIZEBOX))
    Local $iButton_1 = GUICtrlCreateButton('Effect 1', 5, 5, 100, 25)
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKSIZE + $GUI_DOCKTOP)

    Local $iButton_2 = GUICtrlCreateButton('Effect 2', 5, 30, 100, 25)
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKSIZE + $GUI_DOCKTOP)

    GUISetState(@SW_SHOW, $hGUI)

    Local $hDisableGUI = 0, $hTimer = 0
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $iButton_1
                ; Enable the dimmed effect on the current GUI with the animation turned on.
                GuiMenuDisable($hGUI,0)
                _GUIDisable(-1, 1, 25)
                ;MsgBox($MB_SYSTEMMODAL, '_GUIDisable()', 'See how the GUI is now dimmed. Once you select OK, you''ll have 5 seconds to re-size the GUI!' & @CRLF & @CRLF & _
                ;        'If you wish to exit the 5 second timer, then simply select "Close" to exit the loop.')
                $hTimer = TimerInit()
                Do
                    ; Exit the loop if $GUI_EVENT_CLOSE is captured by GUIGetMsg().
                    If GUIGetMsg() = $GUI_EVENT_CLOSE Then
                        ExitLoop
                    EndIf
                    Sleep(10)
                Until TimerDiff($hTimer) > 5000

                ; Disable the dimmed effect with the animation turned on and add focus to the current GUI.
                _GUIDisable(-1, 1)
                GuiMenuDisable($hGUI,1)
            Case $iButton_2
                ; Enable the dimmed effect on the current GUI without the animation.
                GuiMenuDisable($hGUI,0)
                $hDisableGUI = _GUIDisable($hGUI, 0, 25, 25)

                $hTimer = TimerInit()
                Do
                    ; Exit the loop if $GUI_EVENT_CLOSE is captured by GUIGetMsg().
                    If GUIGetMsg() = $GUI_EVENT_CLOSE Then
                        ExitLoop
                    EndIf
                    Sleep(10)
                Until TimerDiff($hTimer) > 5000

                _GUIDisable($hGUI, 0)
                GuiMenuDisable($hGUI,1)

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc

Func GuiMenuDisable($hWnd,$sate)
    $dSysMenu = DllCall("User32.dll", "hwnd", "GetSystemMenu", "hwnd", $hWnd, "int", $sate)
    DllCall("User32.dll", "int", "RemoveMenu", "hwnd", $dSysMenu[0], "int", 0xF060, "int", $sate)
    DllCall("User32.dll", "int", "DrawMenuBar", "hwnd", $hWnd)
EndFunc