Strip any characters from a string function

[Bowmore]

I thought this function may be useful to some people. It works in almost the same way as the core AutoIt function StringStripWS. The difference is that you can specify any characters to be stripped.

Note: The function is case sensitive

expandcollapse popup

;========================================================================================================
;
; Function Name:     _StringStripChr($sString_In, $sChr, $iFlags = 2, $iCount = 0)
; Description:
; Parameters:
;    $sString_In   - The string to be stripped
;          $sChr   - The characters to be stripped (case sensitive)
;        $iFlags   - Flag to indicate the type of stripping that should be performed (add the flags together for multiple operations):
;                    1 = strip leading instances of characters in $sChr
;                    2 (Default) = strip trailing instances of characters in $sChr
;                    4 = Replace multiple instances of characters in $sChr with a single instance
;                    8 = strip all instances of $sChr (over-rides all other flags)
;        $iCount   - The max number of leading or trailing instances of $sChr to strip
;                    0 (Default) = Strip all
;
; Requirement:   None.
; Return Value:  Stripped string
; Author:       Bowmore
;
; Notes:
;
; Examples:
;         _StringStripChr("AAAAbdcaefgA", "A", 3, 0)
;         would return
;         "bdcaefg"
;
;         _StringStripChr("AAAAbdcaefgA", "A", 2, 0)
;         would return
;         "AAbdcaefg"
;
;         _StringStripChr("ABCAAbdcaefgA", "AB", 7, 0)
;         would return
;         "CAbdcaefg"
;
;         _StringStripChr("ABCAAbdcaefgA", "ABe", 8, 0)
;         would return
;         "Cbdcafg"
;
;========================================================================================================
Func _StringStripChr($sString_In, $sChr, $iFlags = 2, $iCount = 0)
    Local $sNewString = $sString_In
    Local $sChr1 = ""
 
    If (BitAND($iFlags, 8) = 8) Then
        For $i = 1 To StringLen($sChr)
            $sChr1 = StringMid($sChr, $i, 1)
            $sNewString = StringReplace($sNewString, $sChr1, "", 0, 1)
        Next
    Else
        If (BitAND($iFlags, 4) = 4) Then
            For $i = 1 To StringLen($sChr)
                $sChr1 = StringMid($sChr, $i, 1)
                $sNewString = StringRegExpReplace($sNewString, $sChr1 & "{2,}", $sChr1)
            Next
        EndIf
 
        If (BitAND($iFlags, 2) = 2) Then
            If $iCount = 0 Then
                While (StringInStr($sChr, StringRight($sNewString, 1), 1))
                    $sNewString = StringTrimRight($sNewString, 1)
                WEnd
            Else
                For $i = 1 To $iCount
                    If (StringInStr($sChr, StringRight($sNewString, 1), 1)) Then
                        $sNewString = StringTrimRight($sNewString, 1)
                    Else
                        ExitLoop
                    EndIf
                Next
            EndIf
        EndIf
 
        If (BitAND($iFlags, 1) = 1) Then
            If $iCount = 0 Then
                While (StringInStr($sChr, StringLeft($sNewString, 1), 1))
                    $sNewString = StringTrimLeft($sNewString, 1)
                WEnd
            Else
                For $i = 1 To $iCount
                    If (StringInStr($sChr, StringLeft($sNewString, 1), 1)) Then
                        $sNewString = StringTrimLeft($sNewString, 1)
                    Else
                        ExitLoop
                    EndIf
                Next
            EndIf
        EndIf
    EndIf
 
    Return $sNewString
 
EndFunc   ;==>_StringStripChr

EDIT: Corrected name of function used in examples.

Fixed option 4 to work as described.

Fixed case sensitivity issue with options 1 and 2

Edited October 22, 2011 by Bowmore

[water]

A very useful function!

Don't want to nit-pick, but: The examples use the wrong/old function name

Edited October 22, 2011 by water

[wakillon]

You need to choose : _StringStripChr or _StringTrimChr !

[Bowmore]

@water and wakillon

Thanks, it's a good job someone is paying attention as I obviously wasn't when I edited this before posting. I've corrected the examples in the original and corrected a couple of other bugs.

[czardas]

That's nice now that you have fixed the examples.

Edited October 23, 2011 by czardas

[wakillon]

A suggestion : add a Flag to indicate if the operations should be case sensitive or not.

[JibsMan]

Edit: After finding this function did not work, I searched some more and found StringReplace() which works just fine. So it really does not matter to me if this is fixed. Leaving it here FAI (For Anyone's Information).

I realize this function is kinda old, but I tried it to help me get rid of periods so I can compare versions. My code comparing with the periods keeps picking the 3.2.5.50 version instead of the 3.2.5.155 version, so I copied / pasted the entire StringStripChar function in the Include Directory.

The output in my script were periods. IE: '3.2.5.155' became '.' and '3.2.5.50' became '.'

I pulled out the _StringStripChar and made it simple.

#include <MsgBoxConstants.au3>
#include <StringStripChr.au3>

Local $sMyDir1 = "3.2.5.50"
Local $sMyDir2 = "3.2.5.155"

MsgBox($MB_OK,"", "Before Stripping "&$sMyDir1&" and "&$sMyDir2)
$sMyDir1 = _StringStripChr($sMyDir1,".",4,0)
$sMyDir2 = _StringStripChr($sMyDir2,".",4,0)
MsgBox($MB_OK,"", "Stripped Periods become "&$sMyDir1&" and "&$sMyDir2)

I can't include my entire script due to confidentiality issues.

I don't know what changed, but this does not work for me, or maybe it never did for periods.

If this code gets fixed, I'll try it again. Meantime I guess I will have to do this the "Old Math" way...

Thanks,

JibsMan

Edited March 12, 2015 by JibsMan