Values from Inputbox to another?

Shocker · January 31, 2013

Hi there,

is it possible to set single values from one into another Input Box in real time?

#include
#include
#include
#include
#include
#include
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GUI", 275, 134, 348, 249)
$Button1 = GUICtrlCreateButton("Create", 54, 101, 80, 25)
$Button2 = GUICtrlCreateButton("Close", 139, 101, 80, 25)
$Label1 = GUICtrlCreateLabel("1. Value", 8, 16, 40, 25)
$Label2 = GUICtrlCreateLabel("2. Value", 8, 46, 40, 25)
$Label3 = GUICtrlCreateLabel("3. Value", 8, 76, 40, 25)
$Input1 = GUICtrlCreateInput("", 56, 10, 200, 21)
GUICtrlSetLimit(-1, 15, 15)
$Input2 = GUICtrlCreateCombo("", 56, 40, 200, 25)
$Input3 = GUICtrlCreateInput("", 56, 70, 200, 21)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1

Case $Button2
Exit
Case _getinput()
EndSwitch
WEnd

Func _getinput()
$x = GUICtrlRead($Input1)
$d = StringMid($x, 3, 3) & StringMid($x, 10, 2)
GUICtrlSetData($Input3, $d)
EndFunc

e.g. you set abcdefghijklmno into first Box and get cdejk in third Box.

How can i stop it, if i leave first Box or supress it if a Value already exists in third Box?

guinness · February 1, 2013

Look at registering the WM_COMMAND. Search the Forum for examples concerning WM_COMMAND and inputs.

nitekram · February 1, 2013

WOW, someone changed the help section...I have looked, in the download sections and there is no zip files for 3.3..., but would like to add the location of old help files to my sig?

The reason I ask, the other example, though small, was easier for me to understand. thanks

Edited February 1, 2013 by nitekram

guinness · February 1, 2013

nitekram,

I think you might have posted in the wrong section.

nitekram · February 1, 2013

Yea, I think I am in the right section, but might not be in the right mind...I do not think I would have ever been able to figure out how to update my script with the HelpFile example.

I find everyone on here so ready to help...maybe I can see about getting your work to be used be more. Idea down below.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt('MustDeclareVars', 1)

Global $aInputValues[5], $iBegin = 0

Example1()

; example 1
Func Example1()
    Local $msg, $Total

    GUICreate("My GUI") ; will create a dialog box that when displayed is centered
    $aInputValues[0] = GUICtrlCreateInput('', 5, 5, 40)
    GUICtrlCreateLabel('value one', 75, 5)
    $aInputValues[1] = GUICtrlCreateInput('', 5, 45, 40)
    GUICtrlCreateLabel('value two', 75, 45)
    $aInputValues[2] = GUICtrlCreateInput('', 5, 85, 40)
    GUICtrlCreateLabel('value three', 75, 85)
    $aInputValues[3] = GUICtrlCreateInput('', 5, 125, 40)
    GUICtrlCreateLabel('value four', 75, 125)
    $aInputValues[4] = GUICtrlCreateInput('', 5, 165, 40)
    GUICtrlCreateLabel('total', 75, 165)
    GUISetState(@SW_SHOW) ; will display an empty dialog box

    GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop

        If $iBegin Then
            If TimerDiff($iBegin) > 1000 Then ; wait 1 sec <<<<<<<<<<<<<<<
                $Total = 0
                For $j = 0 To UBound($aInputValues) - 2
                    $Total += GUICtrlRead($aInputValues[$j])
                Next
                GUICtrlSetData($aInputValues[4], $Total)
                $iBegin = 0
            EndIf
        EndIf

    WEnd
    GUIDelete()
EndFunc   ;==>Example1

Func MY_WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16)    ;HiWord

    If $iCode = $EN_CHANGE Then

        For $i = 0 To UBound($aInputValues) - 2
            If $iIDFrom = $aInputValues[$i] Then
                $iBegin = TimerInit() ; Start timer flag
                ExitLoop
            EndIf
        Next
    EndIf

EndFunc;==>_WM_COMMAND

I am wondering is there a place here, and if not able to get added, a new forum section call HELP EXAMPLES. It would be kind of cool how others use the same functions in different ways. I would like to enter the first HELP EXAMPLE, it was not written by me, but helped me to figure out how to port it to my script.

ps I am also posting this code on the helpfile posts

guinness · February 1, 2013

I was hoping Shocker would search the Forum before handing over code, as this is an invaluable skill to learn.

nitekram · February 1, 2013

Yea, I understand...but I do not get to help very often, so I try when I can. And since I was helped on about the same subject and it took me about 40 minutes to find it - and it was my post - lol. Besides, it was Melba23 that did all the work.

The OP still has things to figure out, and I wanted to get the same answer. So you know kill two birds with one stone and not hyjack the thread in the process - lol.

Mine, is about timing and trying to get the input before it starts another function. Say the input has >3 digits to be filled out, and based upon the value it searches and array for the value and if found it starts FunctionA, but then if the value is not found it starts FunctionB. I need to know how to stop this, and was hoping this post would give me an idea. I know my timing, is wrong, but if the enduser is not fast enough - FunctionB starts, even if the enduser was not done entering data - maybe it is just a matter of looping until a {TAB} is found and then fill in value. Just thinking outloud - but other ideas are welcome - thanks.

Shocker · February 1, 2013

Hi there,

thx for reply!

Look at registering the WM_COMMAND. Search the Forum for examples concerning WM_COMMAND and inputs.

I tried with this WM_COMMAND, found it on BIG(oogle) search

Works good, but not "real time". You must change from IPB1 to 2 or Combo and go back before Focus is on IPB1 and values set.

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("GUI", 275, 134, 348, 249)
$Button1 = GUICtrlCreateButton("Create", 54, 101, 80, 25)
$Button2 = GUICtrlCreateButton("Close", 139, 101, 80, 25)
$Label1 = GUICtrlCreateLabel("1. Value", 8, 16, 40, 25)
$Label2 = GUICtrlCreateLabel("2. Value", 8, 46, 40, 25)
$Label3 = GUICtrlCreateLabel("3. Value", 8, 76, 40, 25)
$Input1 = GUICtrlCreateInput("", 56, 10, 200, 21)
GUICtrlSetLimit(-1, 15, 15)
$Input2 = GUICtrlCreateCombo("", 56, 40, 200, 25)
$Input3 = GUICtrlCreateInput("", 56, 70, 200, 21)
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1

Case $Button2
Exit
EndSwitch
WEnd

Func _getinput()
$x = GUICtrlRead($Input1)
$d = StringMid($x, 3, 3) & StringMid($x, 10, 2)
GUICtrlSetData($Input3, $d)
EndFunc

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
Local $hWndFrom, $iIDFrom, $iCode
$hWndFrom = $ilParam
$iIDFrom = BitAND($iwParam, 0xFFFF)
$iCode = BitShift($iwParam, 16)
Switch $iCode
Case $EN_SETFOCUS
Switch $hWndFrom
Case GUICtrlGetHandle($Input1)
ConsoleWrite('Receive Focus: Input 1' & @CRLF)
_getinput()
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND

I have no idea to customize (set Focus automatic to IPB1 and make a Loop till i leave IPB1), cause i'm Beginner.

Edited February 1, 2013 by Shocker

guinness · February 1, 2013

This is the correct approach.

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

; Declare Global variables for WM_COMMAND and the custom function.
Global $__iComboWrite = 9999, $__iInputValue = 9999, $__iInputWrite = 9999

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate('Example')
    Local $iOK = GUICtrlCreateButton('OK', 310, 370, 85, 25)

    ; Create label controls.
    GUICtrlCreateLabel('1. Value', 5, 15, 40, 25)
    GUICtrlCreateLabel('2. Value', 5, 45, 40, 25)
    GUICtrlCreateLabel('3. Value', 5, 75, 40, 25)

    ; Create an input control to monitor when its value is changed.
    $__iInputValue = GUICtrlCreateInput('', 55, 10, 200, 21)
    ; Set the limit of the input control to a maximum of 15 characters.
    GUICtrlSetLimit($__iInputValue, 15)

    ; Create additional input controls.
    $__iComboWrite = GUICtrlCreateCombo('', 55, 40, 200, 25)
    $__iInputWrite = GUICtrlCreateInput('', 55, 70, 200, 21)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Register the WM_COMMAND to intercept when the value in the first input's value is changed.
    GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

; Custom function.
Func _GetInput()
    Local $sInputRead = GUICtrlRead($__iInputValue)
    Local $sMidPoint = StringMid($sInputRead, 3, 3) & StringMid($sInputRead, 10, 2)
    GUICtrlSetData($__iComboWrite, $sMidPoint, $sMidPoint) ; Set the default value as the string we're entering when using a combobox.
    GUICtrlSetData($__iInputWrite, $sMidPoint)
EndFunc   ;==>_GetInput

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam

    Local $iHiWord = _WinAPI_HiWord($wParam) ; Control identification code.
    Local $iLoWord = _WinAPI_LoWord($wParam) ; Control identifier.
    Switch $iHiWord
        Case $EN_CHANGE ; When a change event is intercepted.
            Switch $iLoWord ; Retrieve the controlid.
                Case $__iInputValue ; If it matches the first input then call the custom function _GetInput.
                    ConsoleWrite('Debug: $__iInputValue''s value was changed.' & @CRLF)
                    _GetInput()
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Edited February 1, 2013 by guinness

Shocker · February 1, 2013

Input, Input... Fatal ERROR

@guinness

GREAT, many Thx! Disable Line 52, cause it should Set only to $__iInputWrite not to Combo

But if already exist Values in $__iInputWrite they will be overwrite or deleted if you change $__iInputValue. Is it possible to change this?

For example...

1.) You write abcdefghijklmno into $__iInputValue, skript set cdejk in $__iInputWrite

2.) You write 123456 into $__iInputWrite, skript do nothing if you write something into $__iInputValue

Try it with this...

; Custom function.
Func _GetInput()
Local $x = GUICtrlRead($__iInputWrite)
Local $sInputRead = GUICtrlRead($__iInputValue)
Local $sMidPoint = StringMid($sInputRead, 3, 3) & StringMid($sInputRead, 10, 2)
If $x = "" then
;GUICtrlSetData($__iComboWrite, $sMidPoint, $sMidPoint) ; Set the default value as the string we're entering when using a combobox.
GUICtrlSetData($__iInputWrite, $sMidPoint)
EndIf
EndFunc ;==>_GetInput

...set no Value from $__iInputValue if already exist one in $__iInputWrite, but set only one if $__iInputWrite is empty :shifty:

3.) You write abcdefghijklmno into $__iInputValue, skript set cdejk in $__iInputWrite. If you delete now something from $__iInputValue do nothing in $__iInputWrite

Do you know what i mean?

guinness · February 1, 2013

It's because before you were only monitoring when $__iInputValue was changed, you also have to monitor $__iInputWrite if that's the case.

Use the help file and play around with this example.

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

; Declare Global variables for WM_COMMAND and the custom function.
Global $__iInputValue = 9999, $__iInputWrite = 9999

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate('Example')
    Local $iOK = GUICtrlCreateButton('OK', 310, 370, 85, 25)

    ; Create label controls.
    GUICtrlCreateLabel('1. Value', 5, 15, 40, 25)
    GUICtrlCreateLabel('2. Value', 5, 45, 40, 25)
    GUICtrlCreateLabel('3. Value', 5, 75, 40, 25)

    ; Create an input control to monitor when its value is changed.
    $__iInputValue = GUICtrlCreateInput('', 55, 10, 200, 21)
    ; Set the limit of the input control to a maximum of 15 characters.
    GUICtrlSetLimit($__iInputValue, 15)

    ; Create additional input controls.
    $__iComboWrite = GUICtrlCreateCombo('', 55, 40, 200, 25)
    $__iInputWrite = GUICtrlCreateInput('', 55, 70, 200, 21)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Register the WM_COMMAND to intercept when the value in the first input's value is changed.
    GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

; Custom function.
Func _GetInput($iRead, $iWrite)
    Local $sInputRead = GUICtrlRead($iRead)
    Local $sMidPoint = StringMid($sInputRead, 3, 3) & StringMid($sInputRead, 10, 2)
    GUICtrlSetData($iWrite, $sMidPoint)
EndFunc   ;==>_GetInput

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam

    Local $iHiWord = _WinAPI_HiWord($wParam) ; Control identification code.
    Local $iLoWord = _WinAPI_LoWord($wParam) ; Control identifier.
    Switch $iHiWord
        Case $EN_CHANGE ; When a change event is intercepted.
            Switch $iLoWord ; Retrieve the controlid.
                Case $__iInputValue ; If it matches the first input then call the custom function _GetInput.
                    ConsoleWrite('Debug: $__iInputValue''s value was changed.' & @CRLF)
                    _GetInput($__iInputValue, $__iInputWrite)
                Case $__iInputWrite ; If it matches the first input then call the custom function _GetInput.
                    ConsoleWrite('Debug: $__iInputWrite''s value was changed.' & @CRLF)
                    _GetInput($__iInputWrite, $__iInputValue)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Does that help? If not just show me before and after e.g.

Input 1: example

Input 2: amp

Edited February 1, 2013 by guinness

Shocker · February 2, 2013

@guinness

#9 was a better example

Does that help? If not just show me before and after e.g.
Input 1: example
Input 2: amp

Input1: abcdefghijklmno (you write)

Input3: cdejk (skript set)

or

Input1: (is empty)

Input3: 123456 (you write and skript do nothing set to Input1)

If you then goto Input1 and write abcdefghijklmno - script should simple ignore Input3, cause there already exist 123456.

or

Input1: abcdefghijklmno (you write)

Input3: cdejk (skript set)

If you now delete Input1 (why ever) script ignore again Input3 cause cdejk exist in the Box.

guinness · February 2, 2013

You need to play around with the logic in your custom function _GetInput.

Shocker · February 2, 2013

OK, thx. Do you have some search keywords for me how I could possibly solve it, pls?

Edited February 2, 2013 by Shocker

guinness · February 2, 2013

It's the third option that is difficult to implement or can you provide other scenarios?

Values from Inputbox to another?

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Ternary operator

Link to comment

Share on other sites

Link to comment

Share on other sites

Ternary operator

Link to comment

Share on other sites

Link to comment

Share on other sites

Ternary operator

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members