Trying to make script to see if Windows 7 is activated.

[Kovacic]

One of the simplest things I need to do, and I cant do it. All I need is a script that checks to see if Windows 7 has been activated. I looked through many of the WMI references from the website below and cant find the right one to query.

http://www.activexperts.com/admin/scripts/wmi/vbscript/

I was wondering if anyone has one.

Thanks in advance!!

[JohnOne]

one here you can port.

http://www.pcreview.co.uk/forums/getting-activation-status-information-t605565.html

[guinness]

Search Scriptomatic in the Forum and use Win32_WindowsProductActivation.

[FireFox]

Note that if you have a pirated copy the WMI samples won't work.

Edit :

Global $strComputer, $objWMIService, $colWPA

$strComputer = "."

$objWMIService = ObjGet("winmgmts:" _
         & "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")

If IsObj($objWMIService) Then
    $colWPA = $objWMIService.ExecQuery _
            ("Select * from Win32_WindowsProductActivation")

    If IsObj($colWPA) Then
        Local $blHasWPA = False

        For $objWPA In $colWPA
            $blHasWPA = True

            ConsoleWrite( _
                    "Activation Required: " & $objWPA.ActivationRequired & @CRLF & _
                    "Caption: " & $objWPA.Caption & @CRLF & _
                    "Description: " & $objWPA.Description & @CRLF & _
                    "IsNotificationOn: " & $objWPA.IsNotificationOn & @CRLF & _
                    "Product ID: " & $objWPA.ProductID & @CRLF & _
                    "Remaining Evaluation Period: " & $objWPA.RemainingEvaluationPeriod & @CRLF & _
                    "Remaining Grace Period: " & $objWPA.RemainingGracePeriod & @CRLF & _
                    "Server Name: " & $objWPA.ServerName & @CRLF & _
                    "Setting ID: " & $objWPA.SettingID & @CRLF)
        Next

        If Not $blHasWPA Then
            ConsoleWrite("Bad guy I gotya !" & @CRLF)
        EndIf
    EndIf
EndIf

Edited February 9, 2013 by FireFox

[Kovacic]

Im not running pirated copies, at least I hope I'm not... I am writing a profiler for the company I work for, and part of it is to activate windows and office if its not already activated. I have the Office portion working, but when I ran the code above, I got "Bad guy I gotya !"

I did find this though: http://msdn.microsoft.com/en-us/library/windows/desktop/aa394520(v=vs.85).aspx People are saying Win32_WindowsProductActivation class doesnt work in vista and 7 :/

I found this, but I'm not 100% sure how to invoke it, looks like I have some testing to do:

class SoftwareLicensingProduct

{

string ID;

string Name;

string Description;

string ApplicationID;

string ProcessorURL;

string MachineURL;

string ProductKeyURL;

string UseLicenseURL;

uint32 LicenseStatus;

uint32 LicenseStatusReason;

uint32 GracePeriodRemaining;

datetime EvaluationendDate;

string OfflineInstallationId;

string PartialProductKey;

string ProductKeyID;

string LicenseFamily;

string LicenseDependsOn;

boolean LicenseIsAddon;

uint32 VLActivationInterval;

uint32 VLRenewalInterval;

string KeyManagementServiceProductKeyID;

string KeyManagementServiceMachine;

uint32 KeyManagementServicePort;

string DiscoveredKeyManagementServiceMachineName;

uint32 DiscoveredKeyManagementServiceMachinePort;

uint32 IsKeyManagementServiceMachine;

uint32 KeyManagementServiceCurrentCount;

uint32 RequiredClientCount;

uint32 KeyManagementServiceUnlicensedRequests;

uint32 KeyManagementServiceLicensedRequests;

uint32 KeyManagementServiceOOBGraceRequests;

uint32 KeyManagementServiceOOTGraceRequests;

uint32 KeyManagementServiceNonGenuineGraceRequests;

uint32 KeyManagementServiceTotalRequests;

uint32 KeyManagementServiceFailedRequests;

uint32 KeyManagementServiceNotificationRequests;

uint32 GenuineStatus;

uint32 ExtendedGrace;

string TokenActivationILID;

uint32 TokenActivationILVID;

uint32 TokenActivationGrantNumber;

string TokenActivationCertificateThumbprint;

string TokenActivationAdditionalInfo;

datetime TrustedTime;

};

Edited February 11, 2013 by Kovacic

[guinness]

You're not a "bad guy" read towards the end of this page.

[Kovacic]

I know what the product key should be, so what I might do is something like this, taking code from FireFox of course (the user, not the browser)

Global $strComputer, $objWMIService, $colWPA

$strComputer = "."

$objWMIService = ObjGet("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & $strComputer & "\root\cimv2")

If IsObj($objWMIService) Then
$colWPA = $objWMIService.ExecQuery _
("Select * from SoftwareLicensingProduct")

If IsObj($colWPA) Then
Local $blHasWPA = False

For $objWPA In $colWPA
$blHasWPA = True

MsgBox(0,"", _
"Partial Product Key: " & $objWPA.PartialProductKey)
Next

If Not $blHasWPA Then
MsgBox(0,"","Aw crap, you bootleggin")
EndIf
EndIf
EndIf

Edited February 11, 2013 by Kovacic

[JLogan3o13]

This is what I use, works well on both Windows 7 and Server 2008 boxes:

$WMI = ObjGet("winmgmts:\\.\root\cimv2")
$aLicenses = $WMI.ExecQuery("Select * From SoftwareLicensingProduct")
 
   For $element In $aLicenses
      If StringInStr($element.Description, "Windows Operating System") Then
         If $element.GracePeriodRemaining = 0 Then
            MsgBox(0, "", "Product is Activated")
            ExitLoop
         Else
            ;Call SLMgr.vbs with your selected options
            ;http://technet.microsoft.com/en-us/library/ff793433.aspx
         EndIf
      EndIf
   Next

Edited February 11, 2013 by JLogan3o13

[Chimaera]

This may help with this, i bodged this together for something i was doing a while ago

expandcollapse popup

Global $ActiveCheck, $result

If @OSVersion = "WIN_2000" Or @OSVersion = "WIN_2003" Or @OSVersion = "WIN_XP" Or @OSVersion = "WIN_XPe" Then
$ActiveCheck = _XPActivationCheck()
Else
$ActiveCheck = _ActivationStatus()
EndIf

Func _ActivationStatus() ; Vista + Only ~ author trancexx
Local $oWMIService = ObjGet("winmgmts:\\.\root\cimv2")
If IsObj($oWMIService) Then
Local $oCollection = $oWMIService.ExecQuery("SELECT Description, LicenseStatus, GracePeriodRemaining FROM SoftwareLicensingProduct WHERE PartialProductKey <> null")
If IsObj($oCollection) Then
For $oItem In $oCollection
Switch $oItem.LicenseStatus
Case 0, 2 To 4, 6
$result = "Windows Is NOT Activated"
Case 1
$result = "Windows Is Activated"
Case 5
$result = "Possible Fixed Windows (Notification Mode)"
EndSwitch
;~ Return ConsoleWrite( $result & @CRLF)
Return MsgBox(0, "Activation Result", $result & @CRLF)
Next
EndIf
EndIf
EndFunc ;==>_ActivationStatus

Func _XPActivationCheck() ; XP only
Local $x = ObjGet("winmgmts:{impersonationLevel=impersonate}")
Local $y = $x.InstancesOf("win32_WindowsProductActivation")
For $Obj In $y
If $Obj.ActivationRequired Then
$result = 'Windows Is NOT Activated'
Else
$result = 'Windows Is Activated'
EndIf
Next
;~ Return ConsoleWrite( $result & @CRLF)
Return MsgBox(0, "Activation Result", $result & @CRLF)
EndFunc ;==>_XPActivationCheck

I found the Possible Fixed Windows (Notification Mode) answer usefull for Hooky/Dodgy OS because its looking for a different param which the cracks exploit but don't take it as verbatim

I would prob test it thoroughly as i cant remember whether i finished it completely

Edited February 11, 2013 by Chimaera

[Colyn1337]

This might be blasphemous, however this is my Powershell script for activating windows 7. It also refreshes at the higher level so the OS can see that the license has been activated without a reboot. Note, this is for after you've already programatically had the activation code entered (ours is in our base image).

(Get-WmiObject -Namespace "root\cimv2" -Class SoftwareLicensingProduct | Where-Object {$_.productkeyid -ne $null}).activate()
(Get-WmiObject -Namespace "root\cimv2" -Class SoftwareLicensingService).RefreshLicenseStatus()

EDIT: I highly recommend WMI Tools from microsoft, it makes scraping the WMI landscape so much easier.

Edited February 11, 2013 by Colyn1337

[Kovacic]

Actually Colyn, I was planning on bringing in much more powershell to the profiler, but I have much to learn first. 95% of my information gathering is through WMI, but I am finding some resources that work on XP, don't work on 7 or vista (not like I use vista )

JLogan3o13, I did try that code, but every laptop I ran it on, said that windows was activated, even if it wasnt.

Chimaera, This is working for me! Thanks!!!