Replace text in a file

[MyEarth]

Hi,

I know there are many threads on this argument, but i'm searching the fastest method to replace some text in a file:

Local $hFile = "Test.txt"

$sData = "FIRSTNAME Lastname - BAT _ TIME1" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME2" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME3"
FileWrite($hFile, $sData)
FileClose($hFile)

$hFileOpen = FileOpen($hFile)
$ReadData = FileRead($hFileOpen)
$sNewFile = StringRegExpReplace($ReadData, '(?i:' & "TIME" & ')', "COOL")
;~ $sNewFile = StringRegExpReplace($sData, "(-)(.*)(_)", "Another Text")
FileClose($hFile)

FileOpen($hFile, 2)
FileWrite($hFile, $sNewFile)
FileClose($hFile)

1) This is the fastest method, using StringRegExpReplace?

2) How to combine 2 or more StringRegExpReplace with different pattern ( i'm totally new to this )?

Thanks

Edited April 15, 2013 by MyEarth

[Nessie]

Try this:

#include<File.au3>

$sData = "FIRSTNAME Lastname - BAT _ TIME1" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME2" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME3"

$FileName = "Test.txt"
$hFile = FileOpen($FileName, 1)
FileWrite($hFile, $sData)
FileClose($hFile)

$hFileOpen = FileOpen($FileName)
$ReadData = FileRead($hFileOpen)
FileClose($hFileOpen)
$sNewFile = StringRegExpReplace($ReadData, '(?i:' & "TIME" & ')', "COOL")
$sNewFile = StringRegExpReplace($sNewFile, "(-)(.*)(_)", "Another Text")

$hFileOpen = FileOpen($FileName, 2)
FileWrite($hFileOpen, $sNewFile)
FileClose($hFileOpen)

Here you can see how to combine 2 or more StringRegExpReplace with different pattern

Hi!

[kylomas]

MyEarth,

Building on Nessie's example

#include<File.au3>

$sData = "FIRSTNAME Lastname - BAT _ TIME1" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME2" & @CRLF & _
"FIRSTNAME Lastname - BAT _ TIME3"

$FileName = "Test.txt"
$hFile = FileOpen($FileName, 2)
FileWrite($hFile, $sData)
FileClose($hFile)

$hFileOpen = FileOpen($FileName)
$ReadData = FileRead($hFileOpen)
FileClose($hFileOpen)
$sNewFile = StringRegExpReplace($ReadData, 'TIME', 'COOL')              ; <--- simplified
$sNewFile = StringRegExpReplace($sNewFile, "- \w+ _", "Another Text")   ; <--- simplified

$hFileOpen = FileOpen($FileName, 2)                                     ; <---- overwrite file
FileWrite($hFileOpen, $sNewFile)
FileClose($hFileOpen)

shellexecute('test.txt')                                                ; open file with default ".txt" program

kylomas

[MyEarth]

Thanks, you guys can confirm the use of StringRegExpReplace is the fastest method to replace text in a file?

I see other func / method like:

StringReplace

_ReplaceStringInFile ( this solution don't have any wildcards ot things like that )

But i don't know what is the best to use and the fastest on larger file, i rely on your expertise

Edited April 16, 2013 by MyEarth

[JonBMN]

In my opinion and from many searches, it seems StringRegExpReplace is the fastest method available.

If my answer is wrong I'm sure someone with more knowledge will chime in.

[guinness]

SRER has more flexibility, though one thing for sure is _ReplaceStringInFile is designed poorly.

An improved version I submitted to the beta...

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _ReplaceStringInFile
; Description ...: Replaces substrings in a file.
; Syntax ........: _ReplaceStringInFile($sFilePath, $sSearchString, $sReplaceString[, $iCaseSensitive = Default[, $iOccurance = Default]])
; Parameters ....: $sFilePath           - Full path of file to replace substrings.
;                  $sSearchString       - The string to evaluate.
;                  $sReplaceString      - The replacement string.
;                  $iCaseSensitive      - [optional] Flag to indicate if the operations should be case sensitive.
;                                         $STR_NOCASESENSE (0) = not case sensitive, using the user's locale (default)
;                                         $STR_CASESENSE (1) = case sensitive
;                                         $STR_NOCASESENSEBASIC (2) = not case sensitive, using a basic/faster comparison
;                                         Constants are defined in Constants.au3
;                  $iOccurance          - [optional] 0 - Only the first occurrence is replaced or 1 - all occurrences are replaced (default)
; Return values .: Success - Returns the number of occurrences found
;                  Failure - Returns -1 and sets @error to non-zero
;                  |@error = 1 - File is read-only
;                  |@error = 2 - Unable to open the file
;                  |@error = 3 - Unable to write to the file
; Author ........: Kurt (aka /dev/null) and JdeB
; Modified ......: guinness - Re-wrote the function entirely for improvements in readability.
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _ReplaceStringInFile($sFilePath, $sSearchString, $sReplaceString, $iCaseSensitive = Default, $iOccurance = Default)
    If StringInStr(FileGetAttrib($sFilePath), "R") Then Return SetError(1, 0, -1)

    ; Open the file for reading.
    Local $hFileOpen = FileOpen($sFilePath, $FO_READ)
    If $hFileOpen = -1 Then Return SetError(2, 0, -1)

    ; Read the contents of the file and store in a variable
    Local $sFileRead = FileRead($hFileOpen)
    FileClose($hFileOpen) ; Close the open file after reading

    ; Retrieve the file encoding
    Local $iFileEncoding = FileGetEncoding($sFilePath)
    ; Open the file for writing and set the overwrite flag.
    $hFileOpen = FileOpen($sFilePath, $iFileEncoding + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, -1)

    ; Set the default parameters
    If $iCaseSensitive = Default Then $iCaseSensitive = $STR_NOCASESENSE
    If $iOccurance = Default Then $iOccurance = 1

    ; Replace strings
    $sFileRead = StringReplace($sFileRead, $sSearchString, $sReplaceString, 1 - $iOccurance, $iCaseSensitive)
    Local $iReturn = @extended

    ; Write to the open file
    FileWrite($hFileOpen, $sFileRead)
    FileClose($hFileOpen) ; Close the open file after writing
    Return $iReturn
EndFunc   ;==>_ReplaceStringInFile