Set BK Color normal

[Reinhardt1julian]

I want some buttons to change color to red on the click of another button. and wenn you click on the button again, it becomes "normal button color" (clBtnFace). I know that i change it to red with "GUICtrlSetBkColor($Button2ausw, 0xFF0000)" my problem is, how do i set it back to default?

[guinness]

Here:

#include <WinAPI.au3>
#include <WindowsConstants.au3>

; Default grey colour.
ConsoleWrite(_WinAPI_GetSysColor($COLOR_MENU) & @CRLF)

[Reinhardt1julian]

Thanks. But either I'm too stupid to use it, or it won't work. But if i say

GUICtrlSetBkColor($Button2, _WinAPI_GetSysColor($COLOR_MENU))

the button stays red. The exact same with

GUICtrlSetBkColor($Button2, 16777215)
;and
GUICtrlSetBkColor($Button2, 0x16777215)

[guinness]

Can you provide a small re-producer so I don't have to code from scratch on usage OR try using $COLOR_BTNFACE instead.

[Reinhardt1julian]

Won't work. So here's my test file:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $on = false
$Form1 = GUICreate("Form1", 332, 245, 317, 159)
$Button1 = GUICtrlCreateButton("Button1", 32, 32, 81, 49)
$Button2 = GUICtrlCreateButton("Button2", 152, 32, 121, 57)
$Button3 = GUICtrlCreateButton("A", 64, 152, 209, 73)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button3
            If $on = false then
                GUICtrlSetBkColor($Button1, 0xFF0000)
                GUICtrlSetBkColor($Button2, 0xFF0000)
                GUICtrlSetData($Button3, "B")
                $on = true
            ElseIf $on = true Then
                GUICtrlSetBkColor($Button1, 16777215)
                GUICtrlSetBkColor($Button2, 16777215)
                GUICtrlSetData($Button3, "A")
                $on = false
            Else
            EndIf
    EndSwitch
WEnd

[guinness]

I don't see the usage of _WinAPI_GetSysColor?

[guinness]

This works:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $on = false
$Form1 = GUICreate("Form1", 332, 245, 317, 159)
$Button1 = GUICtrlCreateButton("Button1", 32, 32, 81, 49)
$Button2 = GUICtrlCreateButton("Button2", 152, 32, 121, 57)
$Button3 = GUICtrlCreateButton("A", 64, 152, 209, 73)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button3
            If $on = false then
                GUICtrlSetBkColor($Button1, 0xFF0000)
                GUICtrlSetBkColor($Button2, 0xFF0000)
                GUICtrlSetData($Button3, "B")
                $on = true
            ElseIf $on = true Then
                GUICtrlSetBkColor($Button1, _WinAPI_GetSysColor( $COLOR_BTNFACE))
                GUICtrlSetBkColor($Button2, _WinAPI_GetSysColor( $COLOR_BTNFACE))
                GUICtrlSetData($Button3, "A")
                $on = false
            Else
            EndIf
    EndSwitch
WEnd

Edited June 2, 2013 by guinness

[Reinhardt1julian]

For me the buttons turn blueish..

[guinness]

Personally they look flat, but that's a bug deep in the AutoIt GUI code that won't be fixed anytime soon. Look at the help file for _WinAPI_GetSysColor and play around with the index constants until you get the colour you expect.

[Reinhardt1julian]

Thanks I think the problem is, that a button is not a solid color. It is darker at the bottom.

[guinness]

It's shadowed, I think that's the point you're making. I would advise against colouring buttons as it looks...well...tacky/awful in a GUI. 

[Melba23]

Reinhardt1julian,

As guinness has already mentioned, I would strongly avoid colouring buttons.  There is a  bug #376 deep within the AutoIt GUI code and it is not going to be fixed any time soon as it would mean rewriting the whole core.  Stick with boring old plain buttons would be my advice.

M23

[AZJIO]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

Global $bToggle = False
$Form1 = GUICreate("Form1", 332, 245, 317, 159)
$Button1 = GUICtrlCreateButton("Button1", 32, 32, 81, 49)
$Button2 = GUICtrlCreateButton("Button2", 152, 32, 121, 57)
$Button3 = GUICtrlCreateButton("A", 64, 152, 209, 73)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button3
            $bToggle = Not $bToggle
            If $bToggle Then
                GUICtrlSetBkColor($Button1, 0xFF0000)
                GUICtrlSetBkColor($Button2, 0xFF0000)
                GUICtrlSetData($Button3, "B")
            Else
                GUICtrlSetStyle($Button1, $GUI_SS_DEFAULT_BUTTON)
                GUICtrlSetStyle($Button2, $GUI_SS_DEFAULT_BUTTON)
                GUICtrlSetData($Button3, "A")
            EndIf
    EndSwitch
WEnd

[guinness]

Well I learnt something new today AZJIO.

[Reinhardt1julian]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

Global $bToggle = False
$Form1 = GUICreate("Form1", 332, 245, 317, 159)
$Button1 = GUICtrlCreateButton("Button1", 32, 32, 81, 49)
$Button2 = GUICtrlCreateButton("Button2", 152, 32, 121, 57)
$Button3 = GUICtrlCreateButton("A", 64, 152, 209, 73)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button3
            $bToggle = Not $bToggle
            If $bToggle Then
                GUICtrlSetBkColor($Button1, 0xFF0000)
                GUICtrlSetBkColor($Button2, 0xFF0000)
                GUICtrlSetData($Button3, "B")
            Else
                GUICtrlSetStyle($Button1, $GUI_SS_DEFAULT_BUTTON)
                GUICtrlSetStyle($Button2, $GUI_SS_DEFAULT_BUTTON)
                GUICtrlSetData($Button3, "A")
            EndIf
    EndSwitch
WEnd

Thanks A lot!

[lorenkinzel]

M23

Purely curiosity; is there any reason other than appearance that you would strongly avoid colouring buttons?

[guinness]

Yes there is a reason. If you're developing for Windows users, then it's best to stick to what people are familiar with, especially in terms of UI. You don't see Microsoft colouring buttons when a change of state occurs, so it's not recommended that we (AutoIt GUI developers) do as well.

http://msdn.microsoft.com/en-us/library/windows/desktop/aa511453.aspx - An excellent source of what to do and what not to do. This discusses about the use of command buttons, you will notice that buttons are there only to action a click.

[Melba23]

lorenkinzel,

Did you read the Trac report to which I linked? Colouring buttons makes them trap the {ENTER} key - pressing that key will fire a focused coloured button. Here is a recent thread where colouring buttons caused that very problem.

So, yes, there is a very good reason not to colour buttons in AutoIt - although I entirely agree with guinness about it not being standard practice (and I also think it looks terrible).

M23

[lorenkinzel]

M23

I'm definitely not questioning your knowledge, but rather my ability to absorb it.

I did read the trac report & tried all 3 examples with colored & non-colored buttons. At least for me, there was no difference. Xp sp3 & 3.3.8.1.

I tried the same thing at work Windows 7 & 3.3.8.1 with the same results.

Enter fires a focused button & when focused on the input, fires the last button used. Whether or not they are colored.

Now when I see the name Valik in the report & my results disagree, I know immediately that something is wrong with my results.

So what am I missing?

Guinness

Yes, thoes are good reasons. Again, I wasn't questioning advice; just trying to learn more from it.

As for appearance of colored buttons; I've done some that looked really nice (at the time). Looking back, they didn't.

[Melba23]

lorenkinsel,

Run this script, add some text to the input and press {ENTER} - what do you get?

I get the input firing and also one of the buttons depending on which was last pressed, 

{ENTER} will always fire the last-pressed button even if it is not focused

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton_1 = GUICtrlCreateButton("Button 1", 10, 10, 80, 30)
GUICtrlSetBkColor(-1, 0xFFCCCC)

$cButton_2 = GUICtrlCreateButton("Button 2", 100, 10, 80, 30)
GUICtrlSetBkColor(-1, 0xCCFFCC)

$cInput = GUICtrlCreateInput("", 10, 100, 200, 20)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            MsgBox(0, "Hi", "Button 1 pressed")
        Case $cButton_2
            MsgBox(0, "Hi", "Button 2 pressed")
        Case $cInput
            MsgBox(0, "Hi", "Enter pressed in the Input control")
    EndSwitch

WEnd

Now remove the colouring from the buttons and try again - what do you get this time?

I get just the input firing. 

{ENTER} will only fire a button if it is focused.

Clearer now?

M23