Cannot Open files from array

[bazinguuh]

Hi,

The files in the array cannot be opened. However, if I put the shellexecute outside the for loop, the first file will open when I exit the array.Thanks

expandcollapse popup

#include <File.au3>
#include <Array.au3>

Local $FileList = _FileListToArray("C:\Users\AJ\Desktop\AutoIT Examples", "*.pdf")
If @error = 1 Then
    MsgBox(0, "", "No Folders Found.")
    Exit
EndIf
If @error = 4 Then
    MsgBox(0, "", "No Files Found.")
    Exit
EndIf
_ArrayDisplay($FileList, "$FileList")
$arrLen = _ArrayLength($FileList, 2)


For $i = 1 To $arrLen Step -1
   MsgBox(0,"","Open" & $FileList[$i])
   ShellExecute("C:\Users\AJ\Desktop\AutoIT Examples\" & $FileList[$i])
Next




Func _ArrayLength($aArray, $iType = 1)
    Local $iDim = UBound($aArray, 0)
 
    If $iDim < 0 Or $iDim > 2 Then ; If not a 1D or 2D Array, then return -1 and set @error to non-zero.
        Return SetError(1, 0, -1)
    EndIf
 
    Switch $iType
        Case 2
            If $iDim = 2 Then
                Return UBound($aArray, 2) * UBound($aArray, 1)
            Else
                Return UBound($aArray, 1)
            EndIf
 
        Case 1
            If $iDim = 2 Then
                Return UBound($aArray, 2)
            Else
                Return 1
            EndIf
 
        Case Else
            Return UBound($aArray, 1)
    EndSwitch
EndFunc   ;==>_ArrayLength

[Danyfirex]

try this:

#include <File.au3>
#include <Array.au3>

Local $FileList = _FileListToArray("C:\Users\AJ\Desktop\AutoIT Examples", "*.pdf")
If @error = 1 Then
    MsgBox(0, "", "No Folders Found.")
    Exit
EndIf
If @error = 4 Then
    MsgBox(0, "", "No Files Found.")
    Exit
EndIf
_ArrayDisplay($FileList, "$FileList")
$arrLen = _ArrayLength($FileList, 2)


For $i = 1 To $FileList[0]
   ;
   MsgBox(0,"","Open" & $FileList[$i])
  ShellExecute("C:\Users\AJ\Desktop\AutoIT Examples\" & $FileList[$i])
Next

Regards

Edited June 19, 2013 by Danyfirex

[BrewManNH]

I'd probably write it this way to make it a bit more readable when you have to go back to it in the future.

 

#include <File.au3>
#include <Array.au3>

Local $FileList = _FileListToArray("C:\Users\AJ\Desktop\AutoIT Examples", "*.pdf")
Switch @error
    Case 1
        MsgBox(0, "", "No Folders Found.")
    Case 4
        MsgBox(0, "", "No Files Found.")
    Case Else
        _ArrayDisplay($FileList, "$FileList")
;~      $arrLen = _ArrayLength($FileList, 2) ; no such function in AutoIt's default Array UDFs
        For $i = 1 To $FileList[0]
            MsgBox(0, "", "Open" & $FileList[$i])
            ShellExecute("C:\Users\AJ\Desktop\AutoIT Examples\" & $FileList[$i])
        Next

EndSwitch

I'm not a fan of the way the example was written for _FileListToArray, but it works so that's all that matters.

[guinness]

 

I'm not a fan of the way the example was written for _FileListToArray, but it works so that's all that matters.

 

Re-write it and submit to the help file thread or commit to SVN yourself.

[BrewManNH]

As I stated, it works as-is so that's all that matters.

[guinness]

OK. Well the example is different in the beta version of the help file anyway.