Can ObjCreate be used with a program created in Autoit?

[kokoilie]

I'm using irrlight to display 3D models in a window but I can't create any controls in this window
and I thought I could compile the code and use objcreate () to display the irrlight (3D) part and overlay it with the autoit gui controls

if it won't work is there a way to add gui controls on to the window created by the .dll?

Edited March 5, 2014 by kokoilie

[water]

I have never used it myself but maybe the >Au3Irrlicht UDF is what you are looking for.

[Richard Robertson]

You can't show standard Windows controls on top of a 3D render unless you cache the rendered image and use it as a background.

[kokoilie]

About the Irrlicht UDF that's exactly what i'm using.

How exactly do I cache the render and use it as background? Or more importantly how resource effective this will be?

Edited March 7, 2014 by kokoilie

[Richard Robertson]

I've never used Irrlicht so I'm afraid I don't know. Most 3D systems let you save a render to an image and you can set that to the background.

[kokoilie]

Maybe it will be the same way as to render texture from the camera, but if I can't do it with irrlicht can you tell me about a 3D system that you used or know how to work with?

[Richard Robertson]

Maybe it will be the same way as to render texture from the camera, but if I can't do it with irrlicht can you tell me about a 3D system that you used or know how to work with?

I'm sorry but I have never actually done 3D programming. I know that if you hook in to DirectX or OpenGL directly instead of using a helper library, you can use almost anything as a texture source.

[Werty]

It can be done by punching holes in the Gui like so...

expandcollapse popup

#include "./Bin/au3Irrlicht2.au3"
#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$Gui = GUICreate("AutoIt Window", 800, 600, -1, -1)
HotKeySet("{ESC}", "_exit")

;Embed Irrlicht RenderWindow---------------------------------------------------------------------------------------
_IrrStart($IRR_EDT_opengl, 1024, 768, $IRR_BITS_PER_PIXEL_32, $IRR_windowed, $IRR_SHADOWS, $IRR_capture_EVENTS, $IRR_VERTICAL_SYNC_Off)
_IrrSetWindowCaption( "IrrLicht Window")

    Local $outer_rgn, $inner_rgn, $combined_rgn

    $outer_rgn = _WinAPI_CreateRectRgn(0, 0, 800, 600)
    $inner_rgn = _WinAPI_CreateRectRgn(103, 102, 200, 122)
    $combined_rgn = _WinAPI_CreateRectRgn(0, 0, 0, 0)
    _WinAPI_CombineRgn($combined_rgn, $outer_rgn, $inner_rgn, $RGN_DIFF)
    _WinAPI_DeleteObject($outer_rgn)
    _WinAPI_DeleteObject($inner_rgn)
    _WinAPI_SetWindowRgn(WinGetHandle("IrrLicht Window", ""), $combined_rgn)

GUICtrlCreateButton("Hey", 100, 80, 100, 22)

WinMove("IrrLicht Window", "", -3, -22)
_WinAPI_Setparent(WinGetHandle("IrrLicht Window", ""), $Gui)
WinActivate("AutoIt Window")

GUISetState()
;--------------------------------------------------------------------------------------------------------------------
;add your IrrLicht stuff here.....

WHILE _IrrRunning()

    _IrrBeginScene(128,128,128)
    _IrrDrawScene()
    _IrrEndScene()
    Sleep(5)
WEND

Func _exit()
    _IrrStop()
    Exit
EndFunc ; _exit

[kokoilie]

Thanks Werty, works like a charm.

Never thought I could use that (actually never knew it's an option). Well guess i'm still green and have much to learn.

One more thing... can I put those "punched holes" back or should I try to make the whole gui that way?

[Werty]

It would be easier just making the autoit window wider than the irrlicht window, now that's it's embedded, and then use the extra space for controls like buttons, tabs etc.

Then there's no need to punch holes.

Something like this...

expandcollapse popup

#include "./Bin/au3Irrlicht2.au3"
;#include <Misc.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$Gui = GUICreate("AutoIt Window", 800, 458, -1, -1)
HotKeySet("{ESC}", "_exit")

;Embed Irrlicht RenderWindow---------------------------------------------------------------------------------------
_IrrStart($IRR_EDT_opengl, 640, 480, $IRR_BITS_PER_PIXEL_32, $IRR_windowed, $IRR_SHADOWS, $IRR_capture_EVENTS, $IRR_VERTICAL_SYNC_Off)
_IrrSetWindowCaption( "IrrLicht Window")
_WinAPI_SetWindowRgn(WinGetHandle("IrrLicht Window", ""), _WinAPI_CreateRectRgn(3, 22, 640, 480)) ; Cut off IrrLicht Window Border

GUICtrlCreateButton("Hey1", 680, 40, 100, 22)
GUICtrlCreateButton("Hey2", 680, 80, 100, 22)
GUICtrlCreateButton("Hey3", 680, 120, 100, 22)


WinMove("IrrLicht Window", "", -3, -22)
_WinAPI_Setparent(WinGetHandle("IrrLicht Window", ""), $Gui)
WinActivate("AutoIt Window")

GUISetState()
;--------------------------------------------------------------------------------------------------------------------
;add your IrrLicht stuff here.....

WHILE _IrrRunning()

    _IrrBeginScene(128,128,128)
    _IrrDrawScene()
    _IrrEndScene()
    Sleep(5)


WEND

Func _exit()
    _IrrStop()
    Exit
EndFunc ; _exit

[kokoilie]

Actually now that I started playing with it and reversed the setparrent part so that the gui is child to the irrlicht render
so to hide the controls I don't want to see I just call GUISetState (@SW_HIDE)

Also the way I want to make it I don't even need to make the gui transparent while it's visible 

[Richard Robertson]

That's actually a really interesting way to do that. Not the most efficient, but interesting nonetheless.

[andy2]

It is working at my end too! Thanks for sharing it Werty.

[Luigi]

Wow! This amazing!