Read of an AD attribute of Octet String syntax

[Valnurat]

How do you read AD attribute: thumbnailPhoto and show the picture? It is a syntax of octet string.

I have no code for this.

[water]

Maybe this and the following posts help:

 

[Valnurat]

I read it and I could see some code to retrive data, but how do I show the picture?

 

#include <AD.au3>
#include <File.au3>

_AD_Open()
If @error Then Exit
$ThumbNailPhoto = _AD_GetObjectAttribute(@UserName, "thumbnailPhoto")
If @error Then $ThumbNailPhoto = ""
_AD_Close()

 

[water]

No idea
But there are a lot of C# or PowerShell examples available on the web. Maybe one of them fits your needs.

[spudw2k]

From what I was reading, the file format is jpg, so I would think it would be possible to either write to a file and/or use GDI+ to display it...but I also don't have the know-how to create a script (to do the GDI+ part at least.)

[Subz]

Probably not required but thought I'd share my solution.

#include <AD.au3>
Opt('ExpandVarStrings', 1)
_ADO_USERIMAGE()
Func _ADO_USERIMAGE()
    Local $oADO_USERIMAGE, $hOPN_THUMBNAIL
    Local $sPIC_USERIMAGE = '@AppDataDir@\Microsoft\Windows\AccountPictures\UserTile.jpg'
    _AD_Open()
        $oADO_USERIMAGE = _AD_GetObjectAttribute(@UserName, 'thumbnailPhoto')
            If @error Then Exit
        $hOPN_THUMBNAIL = FileOpen($sPIC_USERIMAGE, 26)
        FileWrite($hOPN_THUMBNAIL, $oADO_USERIMAGE)
        FileClose($hOPN_THUMBNAIL)
    _AD_Close()
EndFunc

 

Edited January 18, 2017 by Subz
Updated Code

[water]

Great solution

[Valnurat]

Sorry for my very late reply, but how do I use that function?

[water]

Subz's function grabs the thumbnailPhoto property and writes it to "@AppDataDir@\Microsoft\Windows\AccountPictures\UserTile.jpg".

No parameters needed. Just call the function.

[Valnurat]

No "usertitle.jpg" file is created in "@AppDataDir@\Microsoft\Windows\AccountPictures"

 

Is this correct:
"@AppDataDir@" ?

[Valnurat]

aha.

 

Local $sPIC_USERIMAGE = @AppDataDir & '\Microsoft\Windows\AccountPictures\UserTile.jpg'

[Subz]

Sorry forgot to put in 

Opt('ExpandVarStrings', 1) which allows you to use @AppDataDir in a string like "@AppDataDir@\Microsoft\Windows\AccountPictures\UserTile.jpg".

[Valnurat]

Check.

It works now.

Is only possible to save this to a file? It can't be save in memory to show in GUICtrlCreatePic?

Thank you.

[Subz]

You probably could using GDI+ but haven't tried myself, you can use GuiCtrlCreatePic("@AppDataDir@\Microsoft\Windows\AccountPictures\UserTile.jpg", ....)

[Valnurat]

Yes, but I would like, if possible, to "save" the picture in the RAM and then use the RAM as the source.

Is that possible?

[Subz]

Using the _GDIPlus_BitmapCreateFromMemory example works for me.

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <AD.au3>

Example()

Func Example()
    _GDIPlus_Startup() ;initialize GDI+
    Local Const $iWidth = 300, $iHeight = 300, $iBgColor = 0xFFE8FF ;$iBgColor format RRGGBB

    Local $hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
    GUISetBkColor($iBgColor, $hGUI) ;set GUI background color
    GUISetState(@SW_SHOW)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;create a graphics object from a window handle
    Local $hBitmap = _GDIPlus_BitmapCreateFromMemory(_ADO_USERIMAGE()) ;load binary saved GIF image and convert it to GDI+ bitmap format
    Local $iW = _GDIPlus_ImageGetWidth($hBitmap), $iH = _GDIPlus_ImageGetHeight($hBitmap)
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, ($iWidth - $iW) / 2, ($iHeight - $iH) / 2) ;display image in GUI

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;cleanup GDI+ resources
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _ADO_USERIMAGE()
    _AD_Open()
        Local $oADO_USERIMAGE = _AD_GetObjectAttribute(@UserName, 'thumbnailPhoto')
            If @error Then Exit
    _AD_Close()
    Return $oADO_USERIMAGE
EndFunc

 

[Valnurat]

Good lord.

 

Thank you.