[SOLVED] Need som help with superhidden

[Borje]

Hi

I have this little script and that works perfect in windows XP but now I has go to Windows 7 and now that not update the explorer

what is the problem in the code?

 

expandcollapse popup

$RegKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced"
If RegRead($RegKey, "ShowSuperHidden") Then

SplashTextOn("","Not schow Superhidden","200","30","-1","-1",35,"Verdana","10","400")
sleep(500)
    RegWrite($RegKey, "ShowSuperHidden", "REG_DWORD", 0)
Else
    
    SplashTextOn("","Show Superhidden","200","30","-1","-1",35,"Verdana","10","400")
    RegWrite($RegKey, "ShowSuperHidden", "REG_DWORD", 1)
    sleep(500)
EndIf

UpdateExplorer()

Func UpdateExplorer()
    $WinExpListArr = _ExplWinGetList()
    If IsArray($WinExpListArr) Then
        For $iWin = 1 To $WinExpListArr[0]
            $GetWinState = WinGetState($WinExpListArr[$iWin])
            $Hwnd = WinGetHandle($WinExpListArr[$iWin])
            DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
        Next
    EndIf
    
    Opt("WinTitleMatchMode", 4)
    $Hwnd = WinGetHandle("classname=Progman")
    DllCall("user32.dll", "long", "SendMessage", "hwnd", $hWnd, "int", 0x111, "int", 28931, "int", 0)
EndFunc

Func _ExplWinGetList()
    Opt("WinTitleMatchMode", 4)
    $WinList = WinList("classname=CabinetWClass")
    If IsArray($WinList) Then
        Local $WinListArr[$WinList[0][0]+1]
        For $iW = 1 To $WinList[0][0]
            $WinListArr[$iW] = $WinList[$iW][0]
        Next
        $WinListArr[0] = $WinList[0][0]
        Return $WinListArr
    Else
        Return ""
    EndIf
EndFunc

 

Edited December 20, 2018 by Borje

[careca]

Permissions could be one problem, try #requireadmin

[Borje]

Hi careca

I have already test that but that is not works..

[JLogan3o13]

@Borje "It doesn't work" doesn't help anyone. What errors are you getting, or what are you expecting to happen and what happens instead. Instead of simply posting code with "it's broke" and asking folks to guess, help us help you. See the link in my signature on what we need from you in order to assist.

[Nine]

regread has changed in x64 vs x86, try this :

Global $sHKLM32 = @AutoItX64 = 1 ? "HKLM\SOFTWARE\WOW6432NODE" : "HKLM\SOFTWARE"
Global $sHKLM64 = @AutoItX64 = 1 ? "HKLM\SOFTWARE" : "HKLM64\SOFTWARE"

Global $sHKLM = @OSarch = "X64" ? $sHKLM64 : $sHKLM32

add the rest of the key after...in your case it is HKCU tho !

Edited December 20, 2018 by Nine

[careca]

Consider this

If RegRead($RegKey, "ShowSuperHidden") Then

Could you try this way?

If RegRead($RegKey, "ShowSuperHidden") = 0 Then

I think that maybe because this is not a matter of true or false, the result was always 1 to me, but this way the value is retrieved correctly.

[Nine]

5 minutes ago, careca said:

the result was always 1 to me,

mine is at 0 

[orbs]

@Borje, the identification for Windows Explorer windows is different for different operating systems. i stumbled upon this while writing this little app:

from which you can copy this function:

Func _Update_Explorer() ; ref: https://www.autoitscript.com/forum/topic/95139-update-refresh-windows-explorer/
    Local $bOld = Opt("WinSearchChildren", True)
    Local $a = WinList("[CLASS:SHELLDLL_DefView]")
    For $i = 0 To UBound($a) - 1
        DllCall("user32.dll", "long", "SendMessage", "hwnd", $a[$i][1], "int", 0x111, "int", 28931, "int", 0)
    Next
    Opt("WinSearchChildren", $bOld)
EndFunc   ;==>_Update_Explorer

 

Edited December 20, 2018 by orbs

[Borje]

Hi Orbs

Thank you I have test this example you give me and it works perfect, the problem was update explorer after the registry settings was made, but now I understand

that is differnt based on the operating system.