_ArraySort is Not working correctly ?

[fraizor]

Hello Everyone 

I have a strange issue  ...

The json generated array is not getting sorted properly for some reason 

 

#include <json.au3>
#include <Array.au3>


Dim $Chart[0][2] ; Array size of 2 columns


$object = json_decode(FileRead("Test.json")) ;for local testing
$Coins = json_get($object, '.data')


for $i = 0 to UBound($Coins) -1
    $name = json_get($object, '.data[' & $i & '].name' )
    $change_1h = json_get($object, '.data[' & $i & '].quote.USD.percent_change_1h')

    _ArrayAdd($Chart,$name & "|" & number($change_1h,3) )
Next


_ArraySort($Chart, 1, Default, Default, 1)
_ArrayDisplay($Chart)

 

_ArraySort  is sorting the array like this (wrong): 

 

 

However if i click on the "Col 1" header it will be sorted correctly:

 

 

 

How can i make _ArraySort  sort them like clicking on "Col 1" does ? 

 

PS: i tried using the function "Number()" when i add the value to the array , but same result ..

Thanks in advance 

Test.json

Edited April 22, 2024 by fraizor

[water]

This code returns a String as AutoIt internally converts your number to a String again to be able to concatenate them.

$name & "|" & number($change_1h,3)

Call _ArrayAdd twice to fill the two columns.

See the help file for details: "String datatype elements are sorted alphabetically and number datatype elements are sorted numerically - it is important to ensure that elements are of the correct datatype before sorting."

[fraizor]

4 minutes ago, water said:

This code returns a String as AutoIt internally converts your number to a String again to be able to concatenate them.

$name & "|" & number($change_1h,3)

Call _ArrayAdd twice to fill the two columns.

See the help file for details: "String datatype elements are sorted alphabetically and number datatype elements are sorted numerically - it is important to ensure that elements are of the correct datatype before sorting."

@waterThank you for your response 
i tried to Call _ArrayAdd twice, but it created spaces in the array ...

 

_ArrayAdd($Chart,$name)
    _ArrayAdd($Chart, $change_1h,1 )

Still after adding each value alone it is still not sorting properly  ..




 

[ioa747]

#include "json.au3"
#include <Array.au3>


Dim $Chart[0][5] ; Array size of 2 columns


$object = json_decode(FileRead("Test.json")) ;for local testing
$Coins = json_get($object, '.data')


for $i = 0 to UBound($Coins) -1
    $name = json_get($object, '.data[' & $i & '].name' )
    $change_1h = json_get($object, '.data[' & $i & '].quote.USD.percent_change_1h')

    _ArrayAdd($Chart,$name & "|" & number($change_1h,3) )

    $Chart[$i][2] = VarGetType ( $Chart[$i][1] )
    $Chart[$i][3] = number($change_1h,3)
    $Chart[$i][4] = VarGetType ( $Chart[$i][3] )
Next


_ArraySort($Chart, 1, Default, Default, 3)
_ArrayDisplay($Chart)

 

Edited April 22, 2024 by ioa747
corection _ArraySort($Chart, 1, Default, Default, 3)

[water]

I see. Then I suggest:

Global $iRow 

; Loop starts here
  $iRow = _ArrayAdd($Chart,$name)
  $Chart[$iRow][1] = number($change_1h,3)

 

[fraizor]

Amazing 
thank you @water 
thank you @ioa747

[Nine]

Streamlined :

#include "C:\Apps\AutoIt\JSON\json.au3"
#include <Array.au3>

$object = json_decode(FileRead("Test.json")) ;for local testing
$Coins = json_get($object, '.data')

Local $Chart[UBound($Coins)][2]

for $i = 0 to UBound($Coins) -1
    $Chart[$i][0] = json_get($object, '.data[' & $i & '].name' )
    $Chart[$i][1] = Number(json_get($object, '.data[' & $i & '].quote.USD.percent_change_1h'), 3)
Next

_ArraySort($Chart, 3, Default, Default, 1)
_ArrayDisplay($Chart)