Printing RichEdit

[RoyGlanfield]

I have been experimenting with printing RichEdit formatted text.

I use AutoIt script to produce a preview and send it to the chosen printer.

Everything has been tested on an XP computer with an Epson printer.

expandcollapse popup

;==============================================================================================
;--Name ---------  _RTF_Print
;--Description --- Print from RichEdit control
;--Parameters -----$hPrintDc  =   Printer's device context
;-------------------$hwnd      =  handle of the RichEdit control
;-------------------$DocTitle  =   printer's job title
;-------------------$LeftMinMrgn  =   Minimum margin on the left
;-------------------$TopMinMrgn  =   Minimum margin on the Top
;-------------------$RightMinMrgn  =   Minimum margin on the Right
;-------------------$BottomMinMrgn  =   Minimum margin on the Bottom
;--Return values -- Success -  'Sent to the printer.'
;-------------------Failure - 'Printing aborted.'
;--Remarks ------Orientation, paper size, number of copies, and which printer
;---------------------are set when the Printer's device context is generated
;-------------------Unexpected results may be caused by
;------------------------ single line/paragaph orphin tags in the rtf
;--Author -------- RoyGlanfield
;==============================================================================================
Func _RTF_Print($hPrintDc, $hwnd, $DocTitle, $LeftMinMrgn = 1, $TopMinMrgn = 1, $RightMinMrgn = 1, $BottomMinMrgn = 1)
    ;-----------convert the margins 0.1 inches to twips
    ;$TopMinMarg = $TopMinMarg * 144;--------eg 10*144 = 1440 which 1 inch
    ;$LeftMinMarg = $LeftMinMarg * 144;--------eg 10*144 = 1440 which 1 inch
    ;$PageMinMarg = $PageMinMarg * 144;--------eg 10*144 = 1440 which 1 inch
    ;$BottomMinMarg = $BottomMinMarg * 144;--------eg 10*144 = 1440 which 1 inch
    ;-----------convert the margins 1 cm to twips
    $TopMinMrgn = $TopMinMrgn * 567;--------eg 2.539cm * 567= ~1440 which 1 inch
    $LeftMinMrgn = $LeftMinMrgn * 567;--------eg 2.539cm * 567 = ~1440 which 1 inch
    $RightMinMrgn = $RightMinMrgn * 567;--------eg 2.539cm * 567 = ~1440 which 1 inch
    $BottomMinMrgn = $BottomMinMrgn * 567;-------eg 2.539cm * 567 = ~1440 which 1 inch

    ;$hPrintDc ;--------Divice Context handle-----------
    ;----dots per inch depends on the printer quality setting-------X and Y can be different!
    $dotInchX = _WinAPI_GetDeviceCaps($hPrintDc, 88);-----Const LOGPIXELSX = 88
    $dotInchY = _WinAPI_GetDeviceCaps($hPrintDc, 90);-----Const LOGPIXELSY = 90
    ;----printer dots per inch
    ;--------get the printable area  [Page] and paper area [Paper]
    $PageW = _WinAPI_GetDeviceCaps($hPrintDc, 8);-----Const HORZRES= 8
    $PageH = _WinAPI_GetDeviceCaps($hPrintDc, 10);-----Const VERTRES = 10
    $PaperW = _WinAPI_GetDeviceCaps($hPrintDc, 110) ;-----Const PHYSICALWIDTH = 110
    $PaperH = _WinAPI_GetDeviceCaps($hPrintDc, 111) ;-----Const PHYSICALHEIGHT = 111

    ;----none printable margins
    $OffSetX = _WinAPI_GetDeviceCaps($hPrintDc, 112) ;-----Const PHYSICALOFFSETX = 112
    $OffSetY = _WinAPI_GetDeviceCaps($hPrintDc, 113);-----Const PHYSICALOFFSETY = 113
    $RightMrgn = $PaperW - $PageW - $OffSetX
    $BottomMrgn = $PaperH - $PageH - $OffSetY

    ;----conversion factors to use later-----------
    $TwipsInchX = $dotInchX / 1440;-----convert dots to twips [per inch]
    $TwipsInchY = $dotInchY / 1440;-----convert dots to twips [per inch]
    ;--------convert all measurments to twips
    $OffSetX = $OffSetX / $TwipsInchX ;-----convert Left dots to twips
    $OffSetY = $OffSetY / $TwipsInchY ;-----convert Left dots to twips
    $PageW = $PageW / $TwipsInchX ;-----convert Right dots to twips
    $PageH = $PageH / $TwipsInchY ;-----convert Right dots to twips
    $PaperW = $PaperW / $TwipsInchX ;-----convert Paper Width dots to twips
    $PaperH = $PaperH / $TwipsInchY ;-----convert Paper Width dots to twips

    ;----------Set the margins and keep everything in the printable area
    $Left1 = $LeftMinMrgn - $OffSetX
    If $Left1 < 0 Then $Left1 = 0;-----dont print before printable area starts

    $Top1 = $TopMinMrgn - $OffSetY
    If $Top1 < 0 Then $Top1 = 0;-----dont print before printable area starts

    $Right1 = $RightMinMrgn - $RightMrgn
    If $Right1 < 0 Then $Right1 = 0;-----dont print after printable area ends
    ;$Right1 = $PaperW - $Right1 - $OffSetX
    $Right1 = $PageW - $Right1 ;+$Left1;- $OffSetX

    $Bottom1 = $BottomMinMrgn - $BottomMrgn
    If $Bottom1 < 0 Then $Bottom1 = 0;-----dont print after printable area ends
    $Bottom1 = $PageH - $Bottom1;+$Top1

    $z = _SendMessage($hwnd, $EM_SETTARGETDEVICE, 0);---0=wrap----anything else is 1 char per page!!!!!
    If $z = 0 Then Return 'Cant find RichEdit Control'

    If _GUICtrlRichEdit_GetTextLength($hwnd) < 1 Then Return 'Nothing to Print.'
    ;---------must have a selection on the richEdit control---------------
    _SendMessage($hwnd, $EM_SETSEL, 0, -1);--ok----select all

    $pgTags = "int Left1;int Top1;int Right1;int Bottom1;int Left2;int Top2;int Right2;int Bottom2;"
    $rgTags = "LONG cpMin;LONG cpMax"
    $dcHTags = "HANDLE hdc;HANDLE hdcTarget;"
    ;------------create a structure for the printed page
    $strcPg = DllStructCreate($dcHTags & $pgTags & $rgTags)
    DllStructSetData($strcPg, "hdc", $hPrintDc);-------------printer
    DllStructSetData($strcPg, "Left1", $Left1);-----twip--------printer
    DllStructSetData($strcPg, "Right1", $Right1);-----twip--------printer
    DllStructSetData($strcPg, "Top1", $Top1);-----twip--------printer
    DllStructSetData($strcPg, "Bottom1", $Bottom1);-----twip--------printer
    ;-----next 7 lines seem to have, no effect or crash printer jobs queue---why???
    ;--------"HANDLE hdc;" is the printer------- before conecting printer to rtf???
    ;--------"HANDLE hdcTarget;" is the target RichEdit control that has the rtf ????
    ;DllStructSetData($strcPg,"hdcTarget",$hPrintDc);---------------richEdit scource???
    ;DllStructSetData($strcPg,"Left2",$Left1/$dotInchX*96/3);---------------------richEdit scource???
    ;DllStructSetData($strcPg,"Top2",$Top1/$dotInchX*96/3);-----------------------richEdit scource???
    ;DllStructSetData($strcPg,"Right2",$Page1/$dotInchX*96/3);-----twip------richEdit scource???
    ;DllStructSetData($strcPg,"Bottom2",$Bottom1/$dotInchX*96/3);----twip-----richEdit scource???
    ;---------get the pointer to all that will be printed??? {I think????????}
    $a = DllStructGetPtr($strcPg) + DllStructGetSize(DllStructCreate($dcHTags & $pgTags))
    ;-----------use this pointer-----------
    _SendMessage($hwnd, $EM_EXGETSEL, 0, $a)
    ;-----------find the last char of the document to be printed
    $cpMax = DllStructGetData($strcPg, "cpMax")
    ;-----------set the 1st page start char-----------
    $cpMin = 0
    $cpMin2 = -1
    ;-----------------------------------------------------------------------------------
    ;--------create a Document structure for the print job title
    $strDocNm = DllStructCreate("char DocName[" & StringLen($DocTitle & Chr(0)) & "]")
    DllStructSetData($strDocNm, "DocName", $DocTitle & Chr(0))
    $strDoc = DllStructCreate("int Size;ptr DocName;ptr Output;ptr Datatype;dword Type")
    DllStructSetData($strDoc, "Size", DllStructGetSize($strDoc))
    ;---------------insert the document name structure into the document structure
    DllStructSetData($strDoc, "DocName", DllStructGetPtr($strDocNm))
    DllCall("gdi32.dll", "long", "StartDoc", "hwnd", $hPrintDc, "ptr", DllStructGetPtr($strDoc))
    ;-----------------------------------------------------------------------------------
    ;-----------make a loop to format each printed page and exit when-----------
    ;-----$cpMin reaches the $cpMax
    ;-----$cpMin is less than 0---{I have seen -1 but I forget when}---
    ;----ALSO-- ExitLoop if $cpMin = $cpMin 2---if it stops finding the start of next page
    While $cpMax > $cpMin And $cpMin > -1
        ;-----------start a new page-----------
        $StartPage = DllCall("Gdi32.dll", "int", "StartPage", "HANDLE", $hPrintDc)
        ;-----------increment page the count-----------
        ;-----------if not done now it will exit the loop before counting the last page
        ;       ;-----------get the 1st char of the next page, {but how does it work ???}
        $cpMin2 = $cpMin
        $cpMin = _SendMessage($hwnd, $EM_FORMATRANGE, True, DllStructGetPtr($strcPg))
        ;----ExitLoop when $cpMin = $cpMin 2---just in case it stops finding the start of next page
        If $cpMin2 = $cpMin Then ExitLoop;---get out of loop before more pages are added
        ;       ;-----------set the next page start char-----------
        DllStructSetData($strcPg, "cpMin", $cpMin)
        ;------this sends it to the printer
        $EndPage = DllCall("Gdi32.dll", "int", "EndPage", "HANDLE", $hPrintDc)
        ;-----------end the page and loop again for the next page until the end of document
    WEnd
    _SendMessage($hwnd, $EM_FORMATRANGE, False, 0)
    If $EndPage[0] > 0 Then
        $r = 'Sent to the printer.'
        DllCall("Gdi32.dll", "int", "EndDoc", "HANDLE", $hPrintDc)
    Else
        $r = 'Printing aborted.'
        DllCall("Gdi32.dll", "int", "AbortDoc", "HANDLE", $hPrintDc)
    EndIf
    Return $r
EndFunc   ;==>_RTF_Print
;==============================================================================================

Please see the zip file for a working example and a test .rtf file.

I think there should be a better way of producing the preview.

I would like your comments.

ToAutoIT.zip

[taietel]

Thanks for sharing, RoyGlanfield. I've tested on Windows7/x86 with no problems!

taietel

[edit] printers: FoxitPDF, Lexmark Z600 and 2600 series.

[edit again] Tried PrintNow directly and the application crashes. If I set printer, pages etc. first, it's ok.

[edit again] Solved: add this line:

$dcc =_GetDC_PrinterNoDialog()

just before line 170.

Edited April 14, 2011 by taietel

[mLipok]

Awesome.

It works on AutoIt 3.3.10.2

 

EDIT:
Look at my modification "RTF Printer"

Edited May 26, 2017 by mLipok
Link was broken