Chilkat.au3 UDF

[mLipok]

This is modest beginning for UDF Chilkat component:
https://www.chilkatsoft.com/downloads_ActiveX.asp

Some of AcitveX object bundled into this component (dll file) are Free (you can verify it here), some other are commercial.

You can downolad this UDF here:

; #INDEX# ========================================================================
; Title .........: Chilkat.au3
; AutoIt Version : 3.3.10.2++
; Language ......: English
; Description ...: A collection of Function for use with Chilkat component
; Author ........: mLipok
; Modified ......:
; URL ...........: https://www.chilkatsoft.com/refdoc/activex.asp
; URL ...........: https://www.chilkatsoft.com/downloads_ActiveX.asp
; Date ..........: 2017/02/01
; Version .......: 0.1.1 BETA - Work in progress
; ================================================================================

#cs
    2017/02/01
    .   First official version - mLipok

#ce

http://www.chilkatforum.com/questions/1306/is-the-chilkat-upload-component-freeware

 

Examples:
 

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
;~ #AutoIt3Wrapper_Run_Debug_Mode=Y
#Tidy_Parameters=/sort_funcs /reel

#include <Array.au3>
#include <StringConstants.au3>
#include "Chilkat.au3"

_Example()
Func _Example()
    _ErrorLog_ChilkatWrapper(ConsoleWrite)
    _Chilkat_StartUp(@ScriptDir & '\ChilkatAx-9.5.0-win32.dll')
    _Chilkat_DllVersion($CHILKATOBJ_VERSION_950)

    Local $oGLOBAL = _Chilkat_GLOBAL_ObjCreate()
    If @error Then MsgBox($MB_ICONERROR, 'GLOBAL Declartion', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

    _Chilkat_GLOBAL_UnlockBundle($oGLOBAL, "Anything for 30-day trial")
    If @error Then MsgBox($MB_ICONERROR, 'UnlockBundle', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

    ; Just comment / uncomment one of this followin Examples functions:

;~  _Example_12_JsonObject_PrettyPrint()
;~  _Example_13_JsonObject_IterateMembers()
;~  _Example_14_JsonObject_CreateDocument()
;~  _Example_15_CSV_ColumnNames()
;~  _Example_16_CSV_ToArray()
    _Example_17_CSV_ToArray('(?i).*?Pierwszy.*?Urz.*?Skarb.*?', '(?i).*Katowice.*?')

EndFunc   ;==>_Example

Func _Example_12_JsonObject_PrettyPrint()
    _Log_ChilkatExample('_Example_12_JsonObject_PrettyPrint')
    ; https://www.example-code.com/vbscript/json_pretty_print.asp
    Local $oJSON = _Chilkat_JSON_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    Local $sJSON_String = "{""name"": ""donut"",""image"":{""fname"": ""donut.jpg"",""w"": 200,""h"": 200},""thumbnail"":{""fname"": ""donutThumb.jpg"",""w"": 32,""h"": 32}}"

    Local $iSuccess = $oJSON.Load($sJSON_String)
    If ($iSuccess <> 1) Then
        ConsoleWrite($oJSON.LastErrorText & @CRLF)
        Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)
    EndIf

    ;  To pretty-print, set the EmitCompact property equal to 0
    $oJSON.EmitCompact = 0

    ;  If bare-LF line endings are desired, turn off EmitCrLf
    ;  Otherwise CRLF line endings are emitted.
    $oJSON.EmitCrLf = 0

    ;  Emit the formatted JSON:
    ConsoleWrite($oJSON.Emit() & @CRLF)
EndFunc   ;==>_Example_12_JsonObject_PrettyPrint

Func _Example_13_JsonObject_IterateMembers()
    _Log_ChilkatExample('_Example_13_JsonObject_IterateMembers')
    ; https://www.example-code.com/vbscript/json_iterate_members.asp
    Local $oJSON = _Chilkat_JSON_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    Local $sJSON_String = "{ ""id"": 1, ""name"": ""A green door"", ""tags"": [""home"", ""green""], ""price"": 125 }"

    Local $iSuccess = $oJSON.Load($sJSON_String)
    If ($iSuccess <> 1) Then
        ConsoleWrite($oJSON.LastErrorText & @CRLF)
        Return SetError($CHILKAT_ERR_LOAD, @extended, $CHILKAT_RET_FAILURE)
    EndIf

    Local $sName = '', $sValue = ''
    Local $iNumMembers = $oJSON.Size, $iValue = 0

    For $iMember_idx = 0 To $iNumMembers - 1
        $sName = $oJSON.NameAt($iMember_idx)
        $sValue = $oJSON.StringAt($iMember_idx)
        ConsoleWrite($sName & ": " & $sValue & @CRLF)

        $iValue = $oJSON.IntAt($iMember_idx)
        ConsoleWrite($sName & " as integer: " & $iValue & @CRLF)
    Next
EndFunc   ;==>_Example_13_JsonObject_IterateMembers

Func _Example_14_JsonObject_CreateDocument()
    _Log_ChilkatExample('_Example_14_JsonObject_CreateDocument')
    ; https://www.example-code.com/vbscript/create_json.asp
    Local $oJSON = _Chilkat_JSON_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    Local $iSuccess
    $iSuccess = $oJSON.AddStringAt(-1, "Title", "Pan's Labyrinth")
    ConsoleWrite("- $iSuccess=" & $iSuccess & @CRLF)
    $iSuccess = $oJSON.AddStringAt(-1, "Director", "Guillermo del Toro")
    ConsoleWrite("- $iSuccess=" & $iSuccess & @CRLF)
    $iSuccess = $oJSON.AddStringAt(-1, "Original_Title", "El laberinto del fauno")
    ConsoleWrite("- $iSuccess=" & $iSuccess & @CRLF)
    $iSuccess = $oJSON.AddIntAt(-1, "Year_Released", 2006)
    ConsoleWrite("- $iSuccess=" & $iSuccess & @CRLF)
    $oJSON.EmitCompact = 0
    ConsoleWrite($oJSON.Emit() & @CRLF)
EndFunc   ;==>_Example_14_JsonObject_CreateDocument

Func _Example_15_CSV_ColumnNames()
    _Log_ChilkatExample('_Example_15_CSV_ColumnNames')
    ; https://www.example-code.com/vbscript/csv_columnNames.asp

    Local $sURL = 'http://www.chilkatsoft.com/testData/sample.csv'
    InetGet($sURL, @ScriptDir & '\sample.csv')

    Local $oCSV = _Chilkat_CSV_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    ;  Prior to loading the CSV file, indicate that the 1st row
    ;  should be treated as column names:
    $oCSV.HasColumnNames = 1

    ; Load the $oCSV records from the file:
    Local $iSuccess = $oCSV.LoadFile(@ScriptDir & "\sample.csv")
    If ($iSuccess <> 1) Then
        ConsoleWrite($oCSV.LastErrorText & @CRLF)
        Return SetError($CHILKAT_ERR_LOADFILE, @extended, $CHILKAT_RET_FAILURE)
    EndIf

    Local $iIndex = 0
    Local $sColName = ''

    ; Display the column names:
    For $iCol_idx = 0 To $oCSV.NumColumns - 1
        $sColName = $oCSV.GetColumnName($iCol_idx)
        ConsoleWrite($iCol_idx & ": " & $sColName & @CRLF)

        ; The following line demonstrates to to get the column
        ; index given a column name:
        $iIndex = $oCSV.GetIndex($sColName)
        ConsoleWrite($sColName & " is at column index " & $iIndex & @CRLF)
    Next

EndFunc   ;==>_Example_15_CSV_ColumnNames

Func _Example_16_CSV_ToArray()
    _Log_ChilkatExample('_Example_16_CSV_ToArray')

    Local $sURL = 'http://www.chilkatsoft.com/testData/sample.csv'
    InetGet($sURL, @ScriptDir & '\sample.csv')

    Local $oCSV = _Chilkat_CSV_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    ;  Prior to loading the CSV file, indicate that the 1st row
    ;  should be treated as column names:
    $oCSV.HasColumnNames = 1

    ; Load the $oCSV records from the file:
    Local $iSuccess = $oCSV.LoadFile(@ScriptDir & "\sample.csv")
    If ($iSuccess <> 1) Then
        ConsoleWrite($oCSV.LastErrorText & @CRLF)
        Return SetError($CHILKAT_ERR_LOADFILE, @extended, $CHILKAT_RET_FAILURE)
    EndIf

    Local $iNumColumns = $oCSV.NumColumns
    Local $iNumRows = $oCSV.NumRows

    Local $aResult[$iNumRows + 1][$iNumColumns]

    ; First get the column names
    For $iCol_idx = 0 To $iNumColumns - 1
        $aResult[0][$iCol_idx] = $oCSV.GetColumnName($iCol_idx)
    Next

    For $iRow_idx = 0 To $iNumRows - 1
        For $iCol_idx = 0 To $iNumColumns - 1
            $aResult[$iRow_idx + 1][$iCol_idx] = $oCSV.GetCell($iRow_idx, $iCol_idx)
        Next
    Next

    _ArrayDisplay($aResult, '$aResult')

EndFunc   ;==>_Example_16_CSV_ToArray

Func _Example_17_CSV_ToArray($sName_RegExpPattern, $sCity_RegExpPattern)
    _Log_ChilkatExample('_Example_16_CSV_ToArray')
    ; https://www.example-code.com/vbscript/csv_columnNames.asp

    Local $sURL = 'https://epuap.gov.pl/wps/wcm/connect/61e062b9-d981-4526-9f63-c2569263775a/RESP_2016-10-07.csv?MOD=AJPERES'
    InetGet($sURL, @ScriptDir & '\ePUAP.csv')
    ConsoleWrite("- Download completed" & @CRLF)

    Local $oCSV = _Chilkat_CSV_ObjCreate()
    If @error Then Return SetError(@error, @extended, $CHILKAT_RET_FAILURE)

    ;  Prior to loading the CSV file, indicate that the 1st row
    ;  should be treated as column names:
    $oCSV.HasColumnNames = 1

    ; Load the $oCSV records from the file:
    Local $sCSVContent = FileRead(@ScriptDir & "\ePUAP.csv")
    ConsoleWrite("- Load File completed" & @CRLF)
    Local $iSuccess = $oCSV.LoadFromString($sCSVContent)
    If ($iSuccess <> 1) Then
        ConsoleWrite($oCSV.LastErrorText & @CRLF)
        Return SetError($CHILKAT_ERR_LOADFILE, @extended, $CHILKAT_RET_FAILURE)
    EndIf
    ConsoleWrite("- LoadFromString completed" & @CRLF)

    Local $iNumColumns = $oCSV.NumColumns
    Local $iNumRows = $oCSV.NumRows

    Local $aResult[$iNumRows + 1][$iNumColumns]

    ; First get the column names
    For $iCol_idx = 0 To $iNumColumns - 1
        $aResult[0][$iCol_idx] = $oCSV.GetColumnName($iCol_idx)
    Next

    Local $iResult_RowCount = 1 ; First is ColumnName
    For $iRow_idx = 0 To $iNumRows - 1
        If _
                StringRegExp($oCSV.GetCell($iRow_idx, 0), $sName_RegExpPattern, $STR_REGEXPMATCH) _
                And _
                StringRegExp($oCSV.GetCell($iRow_idx, 4), $sCity_RegExpPattern, $STR_REGEXPMATCH) _
                Then
            For $iCol_idx = 0 To $iNumColumns - 1
                $aResult[$iResult_RowCount][$iCol_idx] = $oCSV.GetCell($iRow_idx, $iCol_idx)
            Next
            $iResult_RowCount += 1
        EndIf
    Next

    ; strip array size to Number of founds rows
    ReDim $aResult[$iResult_RowCount][$iNumColumns]

    ConsoleWrite("- Parsing completed" & @CRLF)

    _ArrayDisplay($aResult, '$aResult')

EndFunc   ;==>_Example_17_CSV_ToArray

Func _Log_ChilkatExample($sData)
    ConsoleWrite('>+ ' & $sData & @CRLF)
EndFunc   ;==>_Log_ChilkatExample

 

REMARK:
This UDF is a continuation of this thread:

 

Edited November 13, 2017 by mLipok

[mLipok]

New version:

0.1.2
    2017/02/08
    .   Chnaged: few refactoring - mLipok
    .   Added: Function: _Chilkat_CSV_StringToArray() - mLipok
    .   Added: Function: _Chilkat_JSON_ObjFromString() - mLipok
    .   Added: Function: _Chilkat_JSON_ObjToString() - mLipok
    .   Added: $CHILKATOBJ_API - modes beginning for support to create object for future Chilkat Component version - mLipok

 

[mLipok]

As an example of how to use Chilkat.au3 UDF, you can check  TeamViewer.au3 UDF here:

 

[mLipok]

Example showing how to create CSV file from the scratch:
 

Func _Example_CSV_CreateFile()
    _Log_ChilkatExample('_Example_CSV_CreateFile')

    ;  https://www.example-code.com/vbscript/csv_create.asp
    Local $oCSV = _Chilkat_CSV_ObjCreate()
    If @error Then MsgBox($MB_ICONERROR, 'CSV ObjectCreate', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

    ;  Indicate that the 1st row
    ;  should be treated as column names:
    $oCSV.HasColumnNames = True ;

    Local $bSuccess = $oCSV.SetColumnName(0, "year")
    $bSuccess = $oCSV.SetColumnName(1, "color")
    $bSuccess = $oCSV.SetColumnName(2, "country")
    $bSuccess = $oCSV.SetColumnName(3, "food")

    $bSuccess = $oCSV.SetCell(0, 0, "2001")
    $bSuccess = $oCSV.SetCell(0, 1, "red")
    $bSuccess = $oCSV.SetCell(0, 2, "France")
    $bSuccess = $oCSV.SetCell(0, 3, "cheese")

    $bSuccess = $oCSV.SetCell(1, 0, "2005")
    $bSuccess = $oCSV.SetCell(1, 1, "blue")
    $bSuccess = $oCSV.SetCell(1, 2, "United States")
    $bSuccess = $oCSV.SetCell(1, 3, "hamburger")

    ;  Write the CSV to a string and display:
    Local $sCSV_String ;
    $sCSV_String = $oCSV.SaveToString() ;
    MsgBox(0, '', $sCSV_String)

    ;  Save the CSV to a file:
    $bSuccess = $oCSV.SaveFile("_Example_CSV_CreateFile_Result.csv") ;
    If Not $bSuccess Then ConsoleWrite($oCSV.LastErrorText)

EndFunc   ;==>_Example_CSV_CreateFile

 

[mLipok]

Here is variation about previous example:
 

expandcollapse popup

Func _Example_CSV_CreateFile()
    _Log_ChilkatExample('_Example_CSV_CreateFile')

    ; https://www.example-code.com/vbscript/csv_create.asp

    ;  Indicate that the 1st row
    ;  should be treated as column names:
    __MY_CSV_API(Null)
    __MY_CSV_API("year", "color", "country", "food")
    __MY_CSV_API("2001", "red", "France", "cheese")
    __MY_CSV_API("2005", "blue", "United States", "hamburger")

    Local $oCSV = __MY_CSV_API()

    ;  Write the CSV to a string and display:
    Local $sCSV_String
    $sCSV_String = $oCSV.SaveToString()
    MsgBox(0, '', $sCSV_String)

    ;  Save the CSV to a file:
    Local $bSuccess = $oCSV.SaveFile("_Example_CSV_CreateFile_Result.csv")
    If Not $bSuccess Then ConsoleWrite($oCSV.LastErrorText)

EndFunc   ;==>_Example_CSV_CreateFile

Func __MY_CSV_API($vCol0 = Default, $vCol1 = Default, $vCol2 = Default, $vCol3 = Default)
    Local Static $oCSV = Null

    If $vCol0 = Null Or $oCSV = Null Then ; Create New Object
        $oCSV = _Chilkat_CSV_ObjCreate()
        $oCSV.HasColumnNames = True
    ElseIf $vCol0 = Default And $vCol1 = Default And $vCol2 = Default And $vCol3 = Default Then
        Return $oCSV
    ElseIf $oCSV.NumColumns = 0 Then
        $oCSV.SetColumnName(0, $vCol0)
        $oCSV.SetColumnName(1, $vCol1)
        $oCSV.SetColumnName(2, $vCol2)
        $oCSV.SetColumnName(3, $vCol3)
    Else
        Local $iRow = $oCSV.NumRows
        $oCSV.SetCell($iRow, 0, $vCol0)
        $oCSV.SetCell($iRow, 1, $vCol1)
        $oCSV.SetCell($iRow, 2, $vCol2)
        $oCSV.SetCell($iRow, 3, $vCol3)
    EndIf

EndFunc   ;==>__MY_CSV_API

 

[mLipok]

New version:

0.1.3
    2017/11/12
    .   Added: Function: _Chilkat_ATOM_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_CKSTRING_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_EMAIL_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_IMAP_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_MAILMAN_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_StringBuilder_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_ZIP_ObjCreate() - mLipok
    .   Added: Function: _Chilkat_JSON_StringPretty() - mLipok
    .   Added: New Examples - mLipok

Download location:

 

 

[TheXman]

I noticed that throughout your Chilkat.au3 UDF, you used ObjCreate() functions with class id, interface id, and dll handle as parameters like below:

Local $oObject = ObjCreate( _
        $CHILKATOBJ_API[$__g_iChilkat_DLLVersion][$CHILKATOBJ_NAME_JSON][$CHILKATOBJ_ID_CLSID], _
        $CHILKATOBJ_API[$__g_iChilkat_DLLVersion][$CHILKATOBJ_NAME_JSON][$CHILKATOBJ_ID_IID], _
        $__g_hDll_CHILKAT)

Is that an undocumented implementation of the ObjCreate() function?  I can't find any documentation that references that particular set of parameters for that function.  The only documentation, for the ObjCreate() function, that I have been able to find, lists its parameters as:

ObjCreate ( "classname" [, "servername" [, "username" [, "password"]]] )

I've also looked through AutoIt's version history and found no changes to the ObjCreate() function's parameters.  In any case, I can see where being able to use such an implementation of the function could be very useful if it works the way it appears to.  However, if it is undocumented, I guess it is that way for a reason and would be subject to change without any notice.  That was the first time in 12+ years of using AutoIt that I had ever seen the ObjCreate() function used with those set of parameters.  I found it interesting and thought I would ask.   

When I deploy Chilkat functionality in my scripts, I currently use a Side-by-Side method so I don't have to register the DLL, using regsvr32, on the target machine.  I simply have to deploy the DLL to the script's directory and either supply an external manifest that includes the necessary information or modify the internal manifest with the necessary info.  If the ObjCreate() function, the way you've implemented it, is another method that doesn't require having previously registered the DLL, then the way you've done it is an even easier and cleaner solution.

Edited February 11, 2019 by TheXman

[mLipok]

Look also in my QuickPDF UDF.

This is experimental feature created by @trancexx.

I can try to find A topic where this was described. 

[TheXman]

Very interesting!  I will try to search for it also.  Thanks!

[mLipok]

 

 

[moimon]

Hi. Thanks for this nice UDF.

Sorry because my bad English.

When looking through this library, I see you do not need to register chilkat.dll, but use DllOpen and ObjectCreate with interfaces.
But when I added the chilkat_httprequest function, it seemed that the response was not generated (it was not an object) without registering the dll.
So is it possible to get chilkat_httpresponse without registering the dll?

Thank you.

[mLipok]

Please post examples. 

 

[moimon]

10 hours ago, mLipok said:

Please post examples. 

 

In ChilkatContants.au3, I added:

$CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTP][$CHILKATOBJ_ID_PROGID] = 'Chilkat_9_5_0.Http'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTP][$CHILKATOBJ_ID_CLSID] = '{A74C26D2-2429-4099-8672-2250B15E327F}'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTP][$CHILKATOBJ_ID_IID] = '{C754C4B4-6B0A-4664-ADDD-45467F0BCB7E}'

    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPREQUEST][$CHILKATOBJ_ID_PROGID] = 'Chilkat_9_5_0.HttpRequest'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPREQUEST][$CHILKATOBJ_ID_CLSID] = '{D66A2F08-A267-4593-ACD4-3EF65255E005}'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPREQUEST][$CHILKATOBJ_ID_IID] = '{495F8CD2-9F03-4A83-A9BC-FEEAE2182D9B}'

    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPRESPONSE][$CHILKATOBJ_ID_PROGID] = 'Chilkat_9_5_0.HttpResponse'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPRESPONSE][$CHILKATOBJ_ID_CLSID] = '{65EA825E-648E-4BF0-8AA3-4E7724F75B07}'
    $CHILKATOBJ_API[$CHILKATOBJ_VERSION_950][$CHILKATOBJ_NAME_HTTPRESPONSE][$CHILKATOBJ_ID_IID] = '{C143C715-0FED-4392-B207-1CA3CDF84C88}'

 

In Chilkat.au3, I added: Func _Chilkat_Http_ObjCreate, Func _Chilkat_HttpRequest_ObjCreate and Func _Chilkat_HttpResponse_ObjCreate. They are similar to other _Chilkat_xxx_ObjCreate functions.

 

My HttpRequest Code:

_ErrorLog_ChilkatWrapper(ConsoleWrite)
_Chilkat_StartUp(@ScriptDir & "\Chilkat" & (@AutoItX64 ? '-x64' : '') & ".dll")
_Chilkat_DllVersion($CHILKATOBJ_VERSION_950)

Local $oHttp = _Chilkat_Http_ObjCreate()
If Not IsObj($oHttp) Then Exit MsgBox(4096, 'Err', '_Chilkat_Http_ObjCreate')

Local $oHttpRequest = _Chilkat_HttpRequest_ObjCreate()
If Not IsObj($oHttpRequest) Then Exit MsgBox(4096, 'Err', '_Chilkat_HttpRequest_ObjCreate')

$resp = $oHttp.SynchronousRequest("www.autoitscript.com", 443, True, $oHttpRequest)

$resp is not HttpResponse Object without registering the chilkat/chilkat-x64.dll

Thanks for your help.

[jugador]

@mLipok You are using Chilkat for many years.

I am getting Failed to read beginning of SSL/TLS record when using Chilkat Rest
may be due to I want to access a site which use TLS 1.2 on my window7 machine with no TLS updated patch install.

when use @trancexx WinHTTP I add this line for TLS 1.2 support

;~ WinHttp SetOption to use SECURE PROTOCOL TLS1.1 or TLS1.2
_WinHttpSetOption($__HttpOpen, _
$WINHTTP_OPTION_SECURE_PROTOCOLS, _
BitOR($WINHTTP_FLAG_SECURE_PROTOCOL_TLS1_1, $WINHTTP_FLAG_SECURE_PROTOCOL_TLS1_2))

So want to ask you what the alternative of the above line in Chilkat?
and is WebSocket possible on window7 using Chilkat?

[mLipok]

I'm on vacation.

Ask me next week.

Then I be able to take a look.

Edited July 27, 2021 by mLipok

[mLipok]

Today I was shocked.

Chilkat began to officially support AutoIt - through the examples on this page:

http://www.example-code.com/

https://www.example-code.com/autoit/

And I am impressed.

Good work Chilkat team 👍


btw.
And it really isn't an expensive component at all. I can recommend it with a clear conscience.

There are tons of API and technologies that you can use with this component:

Spoiler

Web API Categories ASN.1 Amazon EC2 Amazon Glacier Amazon S3 Amazon S3 (new) Amazon SES Amazon SNS Amazon SQS Async Azure Cloud Storage Azure Service Bus Azure Table Service Base64 Bounced Email Box CAdES CSR CSV Certificates Compression DKIM / DomainKey DSA Diffie-Hellman Digital Signatures Dropbox Dynamics CRM EBICS ECC Ed25519 Email Object Encryption FTP FileAccess Firebase GMail REST API GMail SMTP/IMAP/POP Geolocation Google APIs Google Calendar Google Cloud SQL Google Cloud Storage Google Drive Google Photos Google Sheets Google Tasks Gzip HTML-to-XML/Text HTTP

HTTP Misc IMAP JSON JSON Web Encryption (JWE) JSON Web Signatures (JWS) JSON Web Token (JWT) Java KeyStore (JKS) MHT / HTML Email MIME MS Storage Providers Microsoft Graph NTLM OAuth1 OAuth2 OIDC Office365 OneDrive OpenSSL Outlook Outlook Calendar Outlook Contact PDF Signatures PEM PFX/P12 PKCS11 POP3 PRNG REST REST Misc RSA SCP SCard SFTP SMTP SSH SSH Key SSH Tunnel ScMinidriver SharePoint Socket/SSL/TLS Spider Stream Tar Archive Upload WebSocket XAdES XML XML Digital Signatures XMP Zip curl

 

 

 

 

Edited June 3, 2022 by mLipok

[mLipok]

For me recently the most important part are:

EMAIL / SMTP / IMAP related stuff:
https://www.example-code.com/autoit/emailObj.asp
https://www.example-code.com/autoit/smtp.asp
https://www.example-code.com/autoit/imap.asp
https://www.example-code.com/autoit/gmail_smtp_imap_pop.asp

Certificates related stuff - including PDF signing
https://www.example-code.com/autoit/scard.asp
https://www.example-code.com/autoit/pdf_signatures.asp
https://www.example-code.com/autoit/cert.asp
https://www.example-code.com/autoit/xades.asp
https://www.example-code.com/autoit/sig.asp

Google API / Sheets related stuff:
https://www.example-code.com/autoit/googleapi.asp
https://www.example-code.com/autoit/googleSheets.asp


But previously I used general AcitveX/VBScript examples:
https://www.example-code.com/vbscript/default.asp

Edited June 3, 2022 by mLipok