Array Slice UDF

[Decipher]

_ArraySlice() its similar to list[n:n] in Python. I was converting a python script to autoit and was bored afterwords so I decided to create this UDF.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
; #FUNCTION# ====================================================================================================================
; Name...........: _ArraySlice
; Description ...: Returns the specified elements as a zero based array.
; Syntax.........: _ArraySlice(Const ByRef $avArray[, $iStart = 0[, $iEnd = 0[, $iStep = 1]]])
; Parameters ....: $avArray - Array to Slice
;                 $iStart  - [optional] Index of array to start slicing
;                 $iEnd - [optional] Index of array to stop slicing
;                 $iStep    - [optional] Increment can be negative
; Return values .: Success - Array containing the specified portion or slices of the original.
;                 Failure - "", sets @error:
;                 |1 - $avArray is not an array
;                 |2 - $iStart is greater than $iEnd when increment is positive
;                 |3 - $avArray is not an 1 dimensional array
;                 |4 - $iStep is greater than the array
; Author ........: Decipher
; Modified.......:
; Remarks .......:
; Related .......: StringSplit, _ArrayToClip, _ArrayToString
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
#include <Array.au3> ; Needed for _ArrayDisplay only.

Example()

Func Example()

   Local $MyArray[10]
   $MyArray[0] = 9
   $MyArray[1] = "One"
   $MyArray[2] = "Two"
   $MyArray[3] = "Three"
   $MyArray[4] = "Four"
   $MyArray[5] = "Five"
   $MyArray[6] = "Six"
   $MyArray[7] = "Seven"
   $MyArray[8] = "Eight"
   $MyArray[9] = "Nine"

   Local $MyNewArray = _ArraySlice($MyArray, 9, 0, -2)
  _ArrayDisplay($MyNewArray)

   $MyNewArray = _ArraySlice($MyArray, 1)
  _ArrayDisplay($MyNewArray)

   $MyNewArray = _ArraySlice($MyArray, 1, 5)
  _ArrayDisplay($MyNewArray)

   $MyNewArray = _ArraySlice($MyArray, 5)
  _ArrayDisplay($MyNewArray)

   $MyNewArray = _ArraySlice($MyArray, 1, 3, 1)
  _ArrayDisplay($MyNewArray)

EndFunc   ;==>Example

Func _ArraySlice(Const ByRef $avArray, $iStart = 0, $iEnd = 0, $iStep = 1)
   If Not IsArray($avArray) Then Return SetError(1, 0, 0)
   If UBound($avArray, 0) <> 1 Then Return SetError(3, 0, "")

   Local $iNew = 0, $iUBound = UBound($avArray) - 1

   ; Bounds checking
   If $iStep > $iUBound Then Return SetError(4, 0, "")
   If $iEnd < 0 Or $iEnd > $iUBound Or $iEnd <= 0 And $iStep > 0 Then $iEnd = $iUBound
   If $iStart < 0 Then $iStart = 0
   If $iStart > $iEnd And $iStep >= 1 Then Return SetError(2, 0, "")

   Local $aNewArray[$iUBound]

   For $i = $iStart To $iEnd Step $iStep ; Create a new zero based array
      $aNewArray[$iNew] = $avArray[$i]
      $iNew +=1
   Next

   ReDim $aNewArray[$iNew]

   Return $aNewArray
EndFunc   ;==>_ArraySlice

_ArraySlice.au3

Edited May 29, 2012 by Decipher

[Decipher]

I don't mean to bump this thread but really guies no comments whatsoever? I worked hard on this a little negative and positve critism is expected.

[guinness]

I don't mean to bump this thread but really guies no comments whatsoever? I worked hard on this a little negative and positve critism is expected.

My only negative criticism is that you didn't give people a chance to reply. I have many threads in the examples section with no comments as well but I don't mind, especially when you posted this only 8 hours ago.

Edit: Changed last part as it could have been construed as being hostile

Edited May 29, 2012 by guinness

[Decipher]

That was an slightly expected response. The UDF? I'm new to the forums. Hmm.. 8 hours isn't long enough then maybe I overestimated the size of the community.

Edited May 29, 2012 by Decipher

[ProgAndy]

For me you wrote in the middle of the night. How can I respond while I am sleeping?

This UDF surely can be useful, but why are you creating a string and split it again? Since you already have a loop, you could just fill a new array directly.

[Decipher]

For me you wrote in the middle of the night. How can I respond while I am sleeping?

This UDF surely can be useful, but why are you creating a string and split it again? Since you already have a loop, you could just fill a new array directly.

Thanks, I'll rewrite it. You did respond didn't you? I didn't think of just creating another array instead of the stringsplit. I was going for what was simplicit and effective for me at the time. I just thought to share it.

[guinness]

Change

$sDelim = "-[Index|Delim]-"

to

$sDelim = Chr(01)

due to the fact if someone has the string '-[index|Delim]-' will yield incorrect results.

[Decipher]

Change

$sDelim = "-[Index|Delim]-"

to

$sDelim = Chr(01)

due to the fact if someone has the string '-[index|Delim]-' will yield incorrect results.

Thanks, would you directly create a new array that would require more code or use the array to stingsplit method?

Advantages/Dis...

[guinness]

I would create a new array myself, but then I haven't done any speed tests on whether this would increase the execution time.

[ProgAndy]

Thanks, I'll rewrite it. You did respond didn't you? I didn't think of just creating another array instead of the stringsplit. I was going for what was simplicit and effective for me at the time. I just thought to share it.

I'm awake now Yes, it seems to be a simple method, but using arrays directly is not more effort and keeps the variable types intact (e.g. a HWnd is not converted to a string)

Local $aResult[$iEnd-$iStart+1]
    ; Combine
    For $i = $iStart To $iEnd Step $iStep
        $aResult[$i-$iStart] = $avArray[$i]
    Next
    Return $aResult

Edited May 29, 2012 by ProgAndy

[Decipher]

I'm awake now Yes, it seems to be a simple method, but using arrays directly is not more effort and keeps the variable types intact (e.g. a HWnd is not converted to a string)

Local $aResult[$iEnd-$iStart+1]
    ; Combine
    For $i = $iStart To $iEnd Step $iStep
        $aResult[$i-$iStart] = $avArray[$i]
    Next
    Return $aResult

You make a great point. I'm working on it currently. Edited May 29, 2012 by Decipher

[Decipher]

I wonder if using redim to increase the array size by one each iteration could possibly be a bad techinque?

Func _ArraySlice(Const ByRef $avArray, $iStart = 0, $iEnd = 0, $iStep = 1)
   If Not IsArray($avArray) Then Return SetError(1, 0, 0)
   If UBound($avArray, 0) <> 1 Then Return SetError(3, 0, "")
   Local $iNew = 1, $iUBound = UBound($avArray) - 1
   ; Bounds checking
   If $iStep > $iUBound Then Return SetError(4, 0, "")
   If $iEnd < 0 Or $iEnd > $iUBound Or $iEnd <= 0 And $iStep > 0 Then $iEnd = $iUBound
   If $iStart < 0 Then $iStart = 0
   If $iStart > $iEnd And $iStep >= 1 Then Return SetError(2, 0, "")
   Local $aNewArray[$iNew]
   For $i = $iStart To $iEnd Step $iStep
   $aNewArray[$iNew-1] = $avArray[$i]
   $iNew +=1
   ReDim $aNewArray[$iNew]
   Next
   ReDim $aNewArray[$iNew-1]
   Return $aNewArray
EndFunc   ;==>_ArraySlice

Edited May 29, 2012 by Decipher

[Melba23]

Decipher,

I wonder if using redim to increase the array size my one each iteration could possibly be a bad techinque?

Yes, ReDim is one of the slowest Array functions.

You might want to look at the tip I gave at the bottom of this tutorial to see how you might do it more efficiently.

M23

[Decipher]

Decipher,

Yes, ReDim is one of the slowest Array functions.

You might want to look at the tip I gave at the bottom of this tutorial to see how you might do it more efficiently.

M23

Updated.

Edited May 29, 2012 by Decipher

[Deye]

This is a good function ,liked

one question : how can I make the new array include array[0] = count 
or add "count" to any array  ..

Thanks

 

EDIT: resolved to using:

_ArrayInsert($aNewArray, 0, UBound($aNewArray))

 

Edited February 10, 2017 by Deye