Array Search ...help

[TheBoyeMillar]

I cant seem to get this script to work... I'm tring to find if an IP address has an "ESTABLISHED" connection on a specific port. Here is my code... but it just keeps returning -1

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>

Global $aArray = 0

Local $conex

Global $DOS, $Message = '' ;; added "= ''" for show only.

If FileExists(@Scriptdir & "\string.txt") Then
  FileDelete(@Scriptdir & "\string.txt")
EndIf

$DOS = Run(@ComSpec & " /c netstat -anop TCP", "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
ProcessWaitClose($DOS)
$Message = StdoutRead($DOS)

;MsgBox(0, "Stdout Read:", $Message)

FileWrite(@Scriptdir & "\string.txt", $Message)

_FileWriteToLine(@Scriptdir & "\string.txt",1,"",1)
_FileWriteToLine(@Scriptdir & "\string.txt",1,"",1)
_FileWriteToLine(@Scriptdir & "\string.txt",1,"",1)
_FileWriteToLine(@Scriptdir & "\string.txt",1,"",1)

_FileReadToArray(@Scriptdir & "\string.txt", $aArray, $FRTA_NOCOUNT)


; Search by column (looking in col 2)
Local $iIndex = _ArraySearch($aArray, '"127.0.0.1:49157"')

MsgBox($MB_SYSTEMMODAL, "", "" & $iIndex)

The Array is built from a txt file like below

  TCP    0.0.0.0:135            0.0.0.0:0              LISTENING       880
  TCP    0.0.0.0:445            0.0.0.0:0              LISTENING       4
  TCP    0.0.0.0:49152          0.0.0.0:0              LISTENING       580
  TCP    0.0.0.0:49153          0.0.0.0:0              LISTENING       1068
  TCP    0.0.0.0:49154          0.0.0.0:0              LISTENING       640
  TCP    0.0.0.0:49155          0.0.0.0:0              LISTENING       1124
  TCP    0.0.0.0:49156          0.0.0.0:0              LISTENING       624
  TCP    127.0.0.1:49157        127.0.0.1:49158        ESTABLISHED     3524
  TCP    127.0.0.1:49158        127.0.0.1:49157        ESTABLISHED     3524
  TCP    192.168.0.8:139        0.0.0.0:0              LISTENING       4
  TCP    192.168.0.8:49700      74.125.230.153:80      TIME_WAIT       0
  TCP    192.168.0.8:49745      54.230.2.217:80        TIME_WAIT       0
  TCP    192.168.0.8:49747      54.230.3.74:443        TIME_WAIT       0

 

ANy help is greatly appreciated...

 

[mLipok]

Why you try to find '"127.0.0.1:49157"'

in example:

 

TCP    192.168.0.8:49747      54.230.3.74:443        TIME_WAIT       0

 

there is no " char.

just try to search for '127.0.0.1:49157'

EDIT: btw. what you see in @error ?

Edited September 2, 2014 by mLipok

[BrewManNH]

Change your _ArraySearch to this.

Local $iIndex = _ArraySearch($aArray, "127.0.0.1:49157", Default, Default, 0, 1)

By default, _ArraySearch does a full string search, you're only giving it a partial string to search for and it will not find it unless you tell the function to also do a string-in-string search.

[kylomas]

TheBoyeMillar,

Not exactly what you are asking but may give you some ideas...

expandcollapse popup

#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>
#include <String.au3>
#include <GuiListView.au3>
#include <Process.au3>

#AutoIt3Wrapper_Add_Constants=n

; setup gui
local $states   =   '|CLOSE_WAIT|CLOSED|ESTABLISHED|FIN_WAIT_1|FIN_WAIT_2|LAST_ACK|LISTEN|SYN_RECEIVED|SYN_SEND|TIMED_WAIT'
local $gui010   =   guicreate('',600,500)
local $asize    =   wingetclientsize($gui010)
                    guictrlcreategroup('Filters - Specify Full or Partial Names',5,5,590,70)
                    guictrlsetfont(-1,8,800)
                    guictrlcreatelabel('Local IP',10,25,200,15)
local $localIP  =   guictrlcreateinput('',10,40,130,20)
                    guictrlcreatelabel('Foreign IP',160,25,200,15)
local $foreignIP=   guictrlcreateinput('',160,40,130,20)
                    guictrlcreatelabel('State',310,25,100,15)
local $selstate =   guictrlcreatecombo('',310,40,130,20)
                    guictrlsetdata($selstate,$states)
                    guictrlcreategroup('',-99,-99,1,1)
local $lv010    =   guictrlcreatelistview('Protocol|Local|Foreign|State|PID|Process Name',10,90,580,350)
local $chk010   =   guictrlcreatecheckbox('Auto Update',10,$asize[1]-50,100,20)
local $status   =   guictrlcreatelabel('',200,$asize[1]-50,400,20)
                    guictrlsetcolor(-1,0xff0000)
local $btn010   =   guictrlcreatebutton('Find IP',10,$asize[1]-20,$asize[0]-20,20)
local $ent_DMY  =   guictrlcreatedummy()
                    guisetstate()

Local $aAccelKeys[1][2] = [["{ENTER}", $ent_DMY]]
GUISetAccelerators($aAccelKeys)

while 1
    switch guigetmsg()
        case $gui_event_close
            Exit
        case $ent_DMY, $btn010
            _LV( guictrlread($localIP),guictrlread($foreignIP),guictrlread($selstate) )
        case $chk010
            if guictrlread($chk010) = $gui_checked then
                _LV( guictrlread($localIP),guictrlread($foreignIP),guictrlread($selstate) )
                adlibregister('_AU',5000)
                guictrlsetdata($status,'*** Auto Updating Every 5 seconds ***')
            endif
            if guictrlread($chk010) = $gui_unchecked then
                adlibunregister('_AU')
                guictrlsetdata($status,'')
            endif
            GUICtrlSetState($localIP,$gui_focus)
    EndSwitch
WEnd

func _LV($L, $f, $s)

    local $str

    ; find matching entries
    local $a10 = stringsplit(_get_TCP(),@CRLF,3)
    for $1 = 0 to ubound($a10) - 1
        $a20 = stringsplit(stringstripws($a10[$1],4),' ')
        if ubound($a20) > 3 then
            if stringregexp($a20[3],$l) and stringregexp($a20[4],$f) and stringregexp($a20[5],$s) then $str &= $a10[$1] & @CRLF
        endif
    next

    ; update listview

    $a10 = stringsplit($str,@CRLF,3)
    _guictrllistview_deleteallitems($lv010)

    for $1 = 0 to ubound($a10) - 1

        $a20 = stringsplit(stringstripws($a10[$1],4),' ')
        ;_arraydisplay($a20)
        if ubound($a20) > 6 then
            _GUICtrlListView_AddItem($lv010,$a20[2])
            _GUICtrlListView_AddSubItem($lv010,$1,$a20[3],1)
            _GUICtrlListView_AddSubItem($lv010,$1,$a20[4],2)
            _GUICtrlListView_AddSubItem($lv010,$1,$a20[5],3)
            _GUICtrlListView_AddSubItem($lv010,$1,$a20[6],4)
            _GUICtrlListView_AddSubItem($lv010,$1,_processgetname($a20[6]),5)
        endif
    next

    ; adjust column sizes to greater of header or data length
    local $ghw, $gdw
    for $1 = 0 to _GUICtrlListView_GetColumnCount($lv010) + 1
        _GUICtrlListView_SetColumnWidth($lv010, $1, $LVSCW_AUTOSIZE_USEHEADER)
        $ghw = _GUICtrlListView_GetColumnWidth($lv010, $1)
        _GUICtrlListView_Setcolumnwidth($lv010, $1, $LVSCW_AUTOSIZE)
        $gdw = _GUICtrlListView_GetColumnWidth($lv010, $1)
        if $ghw > $gdw then _GUICtrlListView_Setcolumnwidth($lv010, $1, $ghw)
    next

endfunc

func _get_TCP()

    local $DOS
    $DOS = Run(@ComSpec & " /c netstat -anop TCP", "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    ProcessWaitClose($DOS)
    return StdoutRead($DOS)

endfunc

func _AU()
    _LV( guictrlread($localIP),guictrlread($foreignIP),guictrlread($selstate) )
endfunc

This script post processes netstat output and can be filtered by local ip, foreign ip and state.  There is also an auto updating feature.

kylomas

Edited September 4, 2014 by kylomas