Disable Button when List View Indices are not selected

[maniootek]

I would like to disable button (make it gray) when none of indices are selected from ListView. Any idea?

 

my code:

#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
$gui = GUICreate("mygui", 200,200)
$idListview = GUICtrlCreateListView("Name|Surname", 10, 10, 180, 100)
GUICtrlCreateListViewItem("John|Oconnor", $idListview)
GUICtrlCreateListViewItem("Ken|Block", $idListview)
$button = GUICtrlCreateButton("Button", 50, 120, 100, 50)
GUISetState(@SW_SHOW, $gui)
While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
       Case $GUI_EVENT_CLOSE
           Exit
   EndSwitch
WEnd

Edited December 14, 2014 by maniootek

[mLipok]

Cześć / Hi.

Please use code tags.

Read "How to post code on the forum"

EDIT:

and Tidy your code.

Edited December 13, 2014 by mLipok

[mLipok]

something like this?

#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
$gui = GUICreate("mygui", 200, 200)
$idListview = GUICtrlCreateListView("Name|Surname", 10, 10, 180, 100)
$h_idListview = ControlGetHandle($gui, '', $idListview)
$iSelectedCount = 0
$iLastSelectedCount = 0
GUICtrlCreateListViewItem("John|Oconnor", $idListview)
GUICtrlCreateListViewItem("Ken|Block", $idListview)
$button = GUICtrlCreateButton("Button", 50, 120, 100, 50)
GUISetState(@SW_SHOW, $gui)

GUICtrlSetState($button, $GUI_DISABLE)
While 1
    $nMsg = GUIGetMsg()
    $iSelectedCount = _GUICtrlListView_GetSelectedCount($h_idListview)

    If $iLastSelectedCount <> $iSelectedCount Then
        If $iSelectedCount Then
            GUICtrlSetState($button, $GUI_ENABLE)
        Else
            GUICtrlSetState($button, $GUI_DISABLE)
        EndIf
        $iLastSelectedCount = $iSelectedCount
    EndIf

    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[maniootek]

thanks for both advices