How to get nth line text from a given text with Regexp

[mpower]

 

I used jchd's example to test it

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
msgbox(0,"", $sText)
Local $sLine4 = StringRegExpReplace($sText, "(?:.*\R){3}(.*)(?s).*", "$1")
msgbox(0,"", $sLine4)

But if the 4th line is empty it will return nothing

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
msgbox(0,"", $sText)
Local $sLine4 = StringRegExpReplace($sText, "(?:.*\R){3}(.*)(?s).*", "$1")
msgbox(0,"", $sLine4)

Umm in your example the text: "this is line 4" is actually on line 5.... so it is correct that $Line4 returns an empty result. Because all it returns is the @CRLF char that's on line 4. If you want to see your text "this is line 4" you need to use pattern "(?:.*R){4}(.*)(?s).*"

To demonstrate:

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
msgbox(0,"", $sText)
$linenum = 5
Local $sString = StringRegExpReplace($sText, "(?:.*\R){"&$linenum-1&"}(.*)(?s).*", "$1")
msgbox(0,"", "The text on line " & $linenum & " is: " & $sString)

Edited March 16, 2015 by mpower

[guinness]

I like regular expressions, but I firmly believe it's best to understand how to extract a line using String* functions first and then move on to regular expressions. I am assuming kcvinu knows how to do this? If not then now is the time to learn.

expandcollapse popup

Global Enum Step *2 $EXTRACTLINE_EMPTY, $EXTRACTLINE_INVALIDFORMAT, $EXTRACTLINE_LESSTHANONE, $EXTRACTLINE_OUTOFBOUNDS

Example()

Func Example()
    Local $sText = ''
    For $i = 1 To 10
        $sText &= 'Line ' & $i & ': With some extra characters at the end.' & @CRLF
    Next

    ; Valid examples:
    PrintLine($sText, 10) ; Second to last line
    PrintLine($sText, 1) ; First line
    PrintLine($sText, 11) ; Last line
    PrintLine($sText, Random(2, 9, 1)) ; Random line

    ; @error examples:
    PrintLine(Null, 9) ; Null string
    PrintLine($sText, 'Nine') ; Invalid number
    PrintLine($sText, -100) ; Invalid line number
    PrintLine($sText, 100) ; Out of bounds
EndFunc   ;==>Example

; Not part of the ExtractLine() function
Func PrintLine($sValue, $iLine)
    Local $bIsIncludeEOL = Random(0, 1, 1) = 1
    Local $sLine = ExtractLine($sValue, $iLine, $bIsIncludeEOL)
    ConsoleWrite('Line: ' & $iLine & ', IncludeEOL: ' & $bIsIncludeEOL & ', ' & '@error: ' & @error & ', Extracted: ' & $sLine & @CRLF)
EndFunc   ;==>PrintLine

Func ExtractLine($sValue, $iLine, $bIncludeEOL = False) ; NOTE: This assumes line endings are \r\n, especially if you're using windows.
    If $sValue = Null Or $sValue == '' Then
        Return SetError($EXTRACTLINE_EMPTY, 0, '')
    EndIf
    If IsString($iLine) Then ; Check if the line number is a string
        If Not StringIsDigit($sValue) Then ; The user didn't pass a line number
            Return SetError($EXTRACTLINE_INVALIDFORMAT, 0, '')
        EndIf
        $iLine = Int($iLine) ; Parse as an integer datatype
    EndIf
    
    Local Const $eSTART_LINE = 1
    If $iLine < $eSTART_LINE Then ; Only line numbers 1 and above are supported
        Return SetError($EXTRACTLINE_LESSTHANONE, 0, '')
    EndIf
    If $bIncludeEOL = Default Or Not IsBool($bIncludeEOL) Then ; If include the EOL is default or not a boolean datatype then set as false
        $bIncludeEOL = False
    EndIf

    Local Const $eEOLLENGTH = StringLen(@CRLF) ; Constant for the length of \r\n (which should be 2)

    Local $iBefore = $eSTART_LINE
    If $iLine > $eSTART_LINE Then
        $iBefore = StringInStr($sValue, @CRLF, Default, $iLine - 1) ; Find the @CRLF before
        $iBefore += $eEOLLENGTH ; Optionally include the EOL
    EndIf

    Local $iAfter = StringInStr($sValue, @CRLF, Default, $iLine) ; Find the @CRLF after
    If $iAfter >= $eSTART_LINE Then
        $iAfter += ($bIncludeEOL ? $eEOLLENGTH : 0) ; Optionally include the EOL
    EndIf

    If $iAfter = 0 And $iBefore = $eEOLLENGTH Then
        Return SetError($EXTRACTLINE_OUTOFBOUNDS, 0, '')
    EndIf

    Return StringMid($sValue, $iBefore, $iAfter - $iBefore) ; Get the line using the before index and then calculating the length
EndFunc   ;==>ExtractLine

Edited March 17, 2015 by guinness

[kcvinu]

@guinnes, At first, i have used string operations to extract a specific line. like;

Local Window_Text = ControlGetText($SciTE_Title, "S", 350)
Local $Line_Number = ControlCommand($SciTE_Title, "S", 350,"GetCurrentLine"," ")
Local $String_Array = StringSplit($Window_Text,@CRLF)
Local CurrentLine_Text = $Sring_Array[$CurrentLine_Number]

[guinness]

In the latest version of AutoIt (beta) my version is memory efficient. Plus, StringSplit() is just a wrapper around the string functions. As I said if you understand what I wrote then we're all good, otherwise you still have a lot of learning to do given the posts I have seen in the examples.

Edited March 17, 2015 by guinness

[guinness]

@guinnes, At first, i have used string operations to extract a specific line. like;

Local Window_Text = ControlGetText($SciTE_Title, "S", 350)
Local $Line_Number = ControlCommand($SciTE_Title, "S", 350,"GetCurrentLine"," ")
Local $String_Array = StringSplit($Window_Text,@CRLF)
Local CurrentLine_Text = $Sring_Array[$CurrentLine_Number]

That StringSplit() line is wrong, as r and n are separate characters and as the help file says, you should use $STR_ENTIRESPLIT if you want it to be treated as a whole and not individually.

[kcvinu]

@guinnes, Thank you for the suggestions. And i downloaded your code. Let me read and learn it. I hope i can ask you if any doubt arosed. 

[guinness]

Okay. But since you wanted a regular expression version best use that. I was only providing an alternative approach using native string functions.

[kcvinu]

@guinness, i don't have any predeterminations that regexp is my choice. I thought that regexp is the speedest method. That's all.

[AspirinJunkie]

RegEx are funny but this solution with native String functions is significantly faster: 

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
Global $n = 4

msgbox(0,"",StringStripCR(StringMid($sText, StringInStr($sText, @LF, 1, $n), StringInStr($sText, @LF, 1, $n+1) - StringInStr($sText, @LF, 1, $n))))

Edit: Hm no - i'm wrong - not significantly faster - but quite similar.

If you repeat it the RegEx-solution should be faster (because of the RegEx-caching from AutoIt).

If you do it one time - the string-solution should be faster.

Edited March 17, 2015 by AspirinJunkie

[jchd]

 

If you do it one time - the string-solution should be faster.

If invoked only once, the speed difference is dramatically close to zero

[AspirinJunkie]

hehe ;-)

[kcvinu]

@guinnes, 

What i have understand from your code is that, find the @CRLF position before the given line number, then find the next @CRLF position. The string we wanted to get is in between these two positions. Am i right ?

But, i can't understand what do you mean by this

"$iAfter += ($bIncludeEOL ? $eEOLLENGTH : 0)" What is the "?" mark and ":" mark means ?

[guinness]

@guinnes, 

What i have understand from your code is that, find the @CRLF position before the given line number, then find the next @CRLF position. The string we wanted to get is in between these two positions. Am i right ?

Yes.

As for your other question search the help file for ternary.