FileReadLastChars

[Zedna]

#include <WinAPI.au3>

$text = FileReadLastChars("C:\Program Files\AutoIt3\Include\Array.au3", 1024)
MsgBox(0, 'FileReadLastChars', $text)

Func FileReadLastChars($sFile, $nChars)
    Local $nBytes
    $tBuffer = DLLStructCreate("char["&$nChars&"]")
    $hFile = _WinAPI_CreateFile($sFile, 2, 2) ; open for read
    _WinAPI_SetFilePointer($hFile, -1 * $nChars, 2) ; from end
    _WinAPI_ReadFile($hFile, DLLStructGetPtr($tBuffer), $nChars, $nBytes)
    _WinAPI_CloseHandle($hFile)
    Return DLLStructGetData($tBuffer, 1)
EndFunc

; included as standard UDF since AutoIt 3.2.13.6 version
Func _WinAPI_SetFilePointer($hFile, $iPos, $iMethod = 0)
    $aResult = DllCall( "kernel32.dll", "long", "SetFilePointer", "hwnd", $hFile, "long", $iPos, "long_ptr", 0, "long", $iMethod)
    If @error Then Return SetError(1, 0, -1)
    If $aResult[0] = -1 Then Return SetError(2, 0, -1) ; $INVALID_SET_FILE_POINTER = -1
    Return $aResult[0]
EndFunc ;==>_WinAPI_SetFilePointer

Here is my topic about _WinAPI_SetFilePointer()

 

EDIT: simpler version compatible with latest AutoIt

$text = FileReadLastChars("C:\Program Files\AutoIt3\Include\Array.au3", 1024)
MsgBox(0, 'FileReadLastChars', $text)

Func FileReadLastChars($sFile , $nChars)
    $hFile = FileOpen($sFile, 0) ; open for read
    FileSetPos($hFile, -1 * $nChars, 2) ; from end
    $sRet = FileRead($hFile)
    FileClose($hFile)
    Return $sRet
EndFunc

 

Edited September 29, 2020 by Zedna
added simpler version compatible with latest AutoIt

[LarsJ]

What is the advantage of this rather than using the built-in commands?

[guinness]

Thanks Zedna. Here is a native version...
 

expandcollapse popup

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

Global Enum Step * 2 $FRLC_FILENOTEXISTS, $FRLC_ISNOTDIGIT, $FRLC_OUTOFBOUNDS, $FRLC_ENDOFFILE

Local $sText = FileReadLastChars(@ScriptFullPath, 204)
ConsoleWrite('@error: ' & @error & ', Text: ' & $sText & @CRLF)
MsgBox($MB_SYSTEMMODAL, 'FileReadLastChars', $sText)

Func FileReadLastChars($sFilePath, $iChars) ; Idea by Zedna, created by guinness
    Local $sData = ''
    Local $hFileOpen = FileOpen($sFilePath, $FO_READ)
    If $hFileOpen = -1 Then Return SetError($FRLC_FILENOTEXISTS, 0, $sData) ; If the file doesn't exist or an unexpected error occurred
    If IsString($iChars) Then ; If $iChars happens to be a string
        If Not StringIsDigit($iChars) Then
            FileClose($hFileOpen)
            Return SetError($FRLC_ISNOTDIGIT, 0, $sData) ; If not an string representing an integer then set an @error
        EndIf
        $iChars = Int($iChars) ; Parse as an integer
    EndIf

    If $iChars <= 0 Or $iChars > FileGetSize($sFilePath) Then
        FileClose($hFileOpen)
        Return SetError($FRLC_OUTOFBOUNDS, 0, $sData) ; If less than or equal to zero or greater than the file size
    EndIf

    If FileSetPos($hFileOpen, -1 * $iChars, $FILE_END) Then
        $sData = FileRead($hFileOpen, $iChars) ; Read the file based on the position and number of chars
        If @error Then
            FileClose($hFileOpen)
            Return SetError($FRLC_ENDOFFILE, 0, $sData)
        EndIf
    EndIf

    FileClose($hFileOpen)
    Return $sData
EndFunc   ;==>FileReadLastChars

[iamtheky]

msgbox(0, '' , _FileReadLastChar(@ScriptFullPath , 7))

Func _FileReadLastChar($file , $count)
    $hFile = FileOpen($file)
    $pos = FileSetPos($hFile , $count * -1 , 2)
    $sOut = FileRead($hFile)
    return $sOut
EndFunc

Edited April 2, 2015 by boththose

[Exit]

msgbox(0, '' , _FileReadLastChar(@ScriptFullPath , 7))

Func _FileReadLastChar($file , $count)
  Return StringRight(FileRead($file),$count)
EndFunc

[guinness]

Learn how to error check, especially when you're creating a UDF.

 

msgbox(0, '' , _FileReadLastChar(@ScriptFullPath , 7))

Func _FileReadLastChar($file , $count)
    $hFile = FileOpen($file)
    $pos = FileSetPos($hFile , $count * -1 , 2)
    $sOut = FileRead($hFile)
    return $sOut
EndFunc

This is wrong. Please read the help file again as cleaning up resources is important. Edited April 2, 2015 by guinness

[iamtheky]

Good thing I wasnt making a UDF, and only clearly showing concept.  And it gives the correct answer every time in reasonable tests.  Checks are sure in order for exceeding bounds, and  I'm sure in production they would close the handle.

Exit, 

that is more,    _FileReadTheWholeThing_ThenReturnTheLastChars

Edited April 2, 2015 by boththose

[Zedna]

What is the advantage of this rather than using the built-in commands?

 

My function (using Win32 API) is the only one which works with old AutoIt 3.2.12.1 which is my main AutoIt's version.

Native FileSetPos() function and even _WinAPI_SetFilePointer() were introduced later.

Edited April 2, 2015 by Zedna

[LarsJ]

I understand. So there was a reason to show this example. Fair enough.

[Zedna]

According to FileReadLastChars() in first post here is also derived FileReadFirstChars().

It can be very usefull when you need to read only small part at beginning of big file,

because this function will not read whole content of file into memory, instead only desired small part.

Note: FileSetPos() in this case probably is not needed, because after FileOpen() file pointer should be at position 0 ...

 

compatible with latest AutoIt:

Func FileReadFirstChars($sFile , $nChars)
    $hFile = FileOpen($sFile, 0) ; open for read
    FileSetPos($hFile, 0, 0) ; from begin
    $sRet = FileRead($hFile, $nChars)
    FileClose($hFile)
    Return $sRet
EndFunc

 

compatible with older AutoIt (3.2.12.1):

Func FileReadFirstChars($sFile, $nChars)
    Local $nBytes
    $tBuffer = DLLStructCreate("char["&$nChars&"]")
    $hFile = _WinAPI_CreateFile($sFile, 2, 2) ; open for read
    _WinAPI_SetFilePointer($hFile, 0, 0) ; from begin
    _WinAPI_ReadFile($hFile, DLLStructGetPtr($tBuffer), $nChars, $nBytes)
    _WinAPI_CloseHandle($hFile)
    Return DLLStructGetData($tBuffer, 1)
EndFunc

 

Edited July 28, 2023 by Zedna