Clicking 'OK' on a WebPage that is mostly JavaScript

[monarch684]

I have created a script that automates the inserting of several users into a portal page on a weekly basis.  Use to it took 3.5 hours to do this by hand and then I found AutoIT.  It now takes 10 minutes.  Management loves this new script but now wants to automate the last remaining bit of manual tasks.  Basically what I need to happen is open a popup and click a couple checkboxes and click 'OK.'  The issue I am having is clicking the 'OK' button because it is really not a button.  Here is the section of HTML I am working with.  As a side note I don't not have access to change the HTML.

 

<form class="validateable" id="notifyImportJobForm" novalidate="novalidate" notify-form="true">
    <input name="print" class="custom" id="notifyImportJobFormPrint" type="checkbox" value="true" data-mini="true">
    <label for="notifyImportJobFormPrint">Print</label>
    <input name="email" class="custom" id="notifyImportJobFormEmail" type="checkbox" value="true" data-mini="true">
    <label for="notifyImportJobFormEmail">Email</label>

    <blockquote> 
        <input name="summary" disabled="" class="custom" id="notifyImportJobFormSummary" type="checkbox" value="true" data-mini="true" checkbox-dependant="notifyImportJobFormEmail">
        <label for="notifyImportJobFormSummary">Accounts created: </label>
        <input name="copyMe" disabled="" class="custom" id="notifyImportJobFormCopyMe" type="checkbox" value="true" data-mini="true" checkbox-dependant="notifyImportJobFormEmail">
        <label for="notifyImportJobFormCopyMe">Copy me</label>
    </blockquote>
</form>

<div class="dialog-action-buttons">
    <a href="#" data-role="button" data-inline="true" data-rel="back">Cancel</a>
    <a href="#" data-role="button" data-theme="b" data-inline="true" form-to-submit="notifyImportJobForm" server-operation="notifyImportJob" validate="notifyImportJobForm" close-on-success="true">Ok</a>
</div>

The HTML itself is 2,758 lines of code.  You can see that attached.  If you choose to look at the HTML....well yes I know it sucks.

Here is my actual script:

expandcollapse popup

Global $uname = InputBox("Guest Wifi Admin Username","Please Enter Your Username")
Global $pwd = InputBox("Guest Wifi Admin Password","Please Enter Your Password","Default","*")

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>
#include <File.au3>
#include <IE.au3>

$dir = @WorkingDir



$oFile = $dir & "\users.txt"
$FileOpen = FileRead($dir & "\users.txt")
_FileReadToArray($oFile,$FileOpen,"Default",",")

; Open Web Console and Wait for Load
Global $oIE = _IECreate("https://serverinfo/sponsorportal/PortalSetup.action?portal=2f931fa0-a001-11e4-8926-0050569a0004")

; Click for Certifcate Error
_IELinkClickByText($oIE,"Continue to this website (not recommended).")

; Send Username & Password
$oForm = _IEFormGetObjByName($oIE,"loginForm")
$oUname = _IEFormElementGetObjByName($oForm, "user.username")
$oPwd = _IEFormElementGetObjByName($oForm, "user.password")
_IEFormElementSetValue($oUname, $uname)
_IEFormElementSetValue($oPwd, $pwd)
_IEFormSubmit($oForm)

For $i = 0 to Ubound($FileOpen) - 1
   WinWait("Sponsor Home","Guest Information",3)

   $fname = $FileOpen[$i][0]
   $lname = $FileOpen[$i][1]
   $email = $FileOpen[$i][2]
   $company = $FileOpen[$i][3]
   ;$days = "5"

   ; Fill Out Form
   $oForm = _IEGetObjByID($oIE,"fields_06879dc0-a001-11e4-8926-0050569a0004")
   $oFname = _IEFormElementGetObjByName($oForm, "firstName")
   $oLname = _IEFormElementGetObjByName($oForm, "lastName")
   $oEmail = _IEFormElementGetObjByName($oForm, "emailAddress")
   $oCompany = _IEFormElementGetObjByName($oForm, "company")
   ;$oDays = _IEFormElementGetObjByName($oForm, "days")

   _IEFormElementSetValue($oFname, $fname)
   _IEFormElementSetValue($oLname, $lname)
   _IEFormElementSetValue($oEmail, $email)
   _IEFormElementSetValue($oCompany, $company)
   ;_IEFormElementSetValue($oDays, $days)

   $oSubmit = _IEGetObjByID($oIE,"createButton")
   _IEAction($oSubmit, "click")

   WinWait("Sponsor Home","Account Information",3)

    _IELinkClickByText($oIE, "Notify")

   WinWait("Sponsor Home","Account Information",3)

   $pForm = _IEGetObjByID($oIE,"createKnownAccountNotifyForm")
   $oPrint = _IEFormElementGetObjByName($pForm,"print")
    _IEAction($oPrint,"click")

    _IEFormSubmit($pForm)

    WinWait("Sponsor Home","Account Information",3)

    _IELinkClickByText($oIE, "Create Accounts")
Next

The section of code I am having issue with is this:

$pForm = _IEGetObjByID($oIE,"createKnownAccountNotifyForm")
$oPrint = _IEFormElementGetObjByName($pForm,"print")
_IEAction($oPrint,"click")
_IEFormSubmit($pForm)

Any help with this section would be greatly appreciated.  I have hit a brick wall and cannot figure out how to get this section to work.

 

Thank you in advanced

portal.html

[Radiance]

Did you try this: (from the helpfile of _IEAction(), 2nd example):

; Same as Example 1, except instead of using click, give the element focus
; and then use ControlSend to send Enter.

 

Edited November 10, 2015 by Radiance

[mLipok]

Did you try:

Local $oPrint = _IEGetObjById($oIE, "createKnownAccountNotifyFormPrint")

??

 

Edit:
But maybe you want to do this:

_IEFormElementCheckBoxSelect($pForm,1,"",1,"byIndex")

 

Edited November 10, 2015 by mLipok
added $oIE as first param .... :)

[monarch684]

I tried this:

$pForm = _IEGetObjByID($oIE,"createKnownAccountNotifyForm")
$oPrint = _IEFormElementGetObjByName($pForm,"print")
_IEAction($oPrint,"click")
hWnd = _IEPropertyGet($oIE, "hwnd")
_IEAction($oForm, "focus")
ControlSend($hWnd, "", "[CLASS:Internet Explorer_Server; INSTANCE:8]", "{Enter}")

It checks the Print checkbox but the errors out.

[mLipok]

What do you want to do, Click or Check Checkbox ?
Did you try:

_IEFormElementCheckBoxSelect($pForm,1,"",1,"byIndex")

 

??

 

[monarch684]

I can check the checkbox.  I need to be able to click 'OK'

[mLipok]

like this:

Local $oTags_coll = _IETagNameGetCollection($oIE, "a")
For $oTag_enum in $oTags_coll
    if StringInStr($oTag_enum.outerhtml,'server-operation="createKnownNotify"') then
        $oTag_enum.click
        ExitLoop
    EndIf
Next

 

[monarch684]

I added that bit of code and it finished with no error but did not click 'OK'

[mLipok]

I'm using this test script:

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

Local $oIE = _IECreate()
_IENavigate($oIE ,'C:\Users\user\Downloads\portal.html')

Local $oTags_coll = _IETagNameGetCollection($oIE, "a")
For $oTag_enum in $oTags_coll
    if StringInStr($oTag_enum.outerhtml,'server-operation="createKnownNotify"') then
        ConsoleWrite($oTag_enum.outerhtml & @CRLF)
        $oTag_enum.innertext = 'Ok test 1'
        $oTag_enum.click
        ConsoleWrite(@ScriptLineNumber & @CRLF)
        ExitLoop
    EndIf
Next

 

Question: do this script changes correctly element ?

 

 

[monarch684]

Unsure what you mean.

Question: do this script changes correctly element ?

[monarch684]

This worked as far as changing the button to say something else, but did not click.

Local $oTags_coll = _IETagNameGetCollection($oIE, "a")
   For $oTag_enum in $oTags_coll

       if StringInStr($oTag_enum.outerhtml,'server-operation="createKnownNotify"') then
           ConsoleWrite($oTag_enum.outerhtml & @CRLF)
           $oTag_enum.innertext = 'Ok'
           $oTag_enum.click
           ConsoleWrite(@ScriptLineNumber & @CRLF)
           ExitLoop

       EndIf
   Next

Here was the output:

<a class="ui-btn ui-btn-up-b ui-shadow ui-btn-corner-all ui-btn-inline" href="#" data-role="button" data-theme="b" data-inline="true" data-corners="true" data-shadow="true" data-iconshadow="true" data-wrapperEls="span" form-to-submit="createKnownAccountNotifyForm" server-operation="createKnownNotify" validate="createKnownAccountNotifyForm" close-on-success="true"><span class="ui-btn-inner"><span class="ui-btn-text">Ok</span></span></a>
72

 

Edited November 16, 2015 by monarch684
For to add output.

[mLipok]

Is this exactly the same Element which you want to click ?

[monarch684]

Yes that is correct.

[monarch684]

Yay.....this works.

Local $oTags_coll = _IETagNameGetCollection($oIE, "a")
   For $oTag_enum in $oTags_coll

       if StringInStr($oTag_enum.outerhtml,'server-operation="createKnownNotify"') then
           ConsoleWrite($oTag_enum.outerhtml & @CRLF)
           $oTag_enum.innertext = 'Ok'
           _IEAction($oTag_enum, "click")
           ExitLoop

       EndIf
   Next

 

[mLipok]