Find string pair and write to file

[blackandwhite]

hello all!

have this code example:

href="/site/create/time=12">String</a><div class="bp"></div></div></div><div><h3 class="bq">main site </h3><ul class="br"><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/54769time=12">site2</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/64889time=12">site3</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/66595time=12">site4</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/31461time=12">site5</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li>

need get this:

/site/151919 site1
/site/54769 site2
/site/64889 site3
/site/66595 site4
/site/31461 site5

I tried with that code:

#Include <Array.au3>
#Include <String.au3>
#include <File.au3>
Local $Text = FileRead("example.txt")

Global $left1 = '<li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="'
Global $right1 = 'time=12">'

Global $left2 = 'time=12">'
Global $right2 = '</a></td>'

$source1 = _StringBetween($Text, $left1,$right1)
$source2 = _StringBetween($Text, $left2,$right2)

For $i = 0 To UBound($source1) - 1
        $source1[$i] = $source1[$i] & " " & $source2[$i]
Next

_FileWriteFromArray('output.txt', $source1)

But getting:

/site/151919 String</a><div class="bp"></div></div></div><div><h3 class="bq">main site </h3><ul class="br"><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1
/site/54769 site2
/site/64889 site3
/site/66595 site4
/site/31461 site5

also tried to use stringregexp, but it too hard for begiiner with bad english like me

any solutions?

[mLipok]

Some example to work with...

#include <IE.au3>


_Example()
Func _Example()
    Local $sHTML = '<table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/54769time=12">site2</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/64889time=12">site3</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/66595time=12">site4</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/31461time=12">site5</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table>'

    Local $oIE = _IECreate()
    _IEDocWriteHTML($oIE,$sHTML)
    $oTags_coll = _IETagNameGetCollection($oIE,'a')

    For $oTag_enum In $oTags_coll
        ConsoleWrite($oTag_enum.href & ' ' & $oTag_enum.innertext & @CRLF )
    Next
EndFunc

 

[blackandwhite]

tnx for answer, but no solutions without using IE.au3? need to work without IE.au3

[mLipok]

like this:

#include <array.au3>
#include <StringConstants.au3>

_Example()
Func _Example()
    Local $sHTML = '<table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/54769time=12">site2</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/64889time=12">site3</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/66595time=12">site4</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/31461time=12">site5</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table>'
    Local $aHTML_Parsed = StringRegExp($sHTML, '(?i)<a.*?href="(.*?)">(.*?)<', $STR_REGEXPARRAYGLOBALFULLMATCH)
    If Not @error Then
        _ArrayDisplay($aHTML_Parsed, '$aHTML_Parsed')
        For $iOuter_idx = 0 To UBound($aHTML_Parsed) -1
            _ArrayDisplay($aHTML_Parsed[$iOuter_idx],'$aHTML_Parsed[$iOuter_idx]')
        Next
    EndIf
EndFunc   ;==>_Example

??

 

[blackandwhite]

it's so close, but how to write this 

/site/151919 site1
/site/54769 site2
/site/64889 site3
/site/66595 site4
/site/31461 site5

to file? Can't modify your source for my need

Edited January 1, 2016 by blackandwhite

[mLipok]

hm....

#include <array.au3>
#include <StringConstants.au3>

_Example()
Func _Example()
    Local Enum $eFullMatch ,$eHref, $eText
    Local $sHTML = '<table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/54769time=12">site2</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/64889time=12">site3</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/66595time=12">site4</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/31461time=12">site5</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table>'
    Local $aInner
    Local $aHTML_Parsed = StringRegExp($sHTML, '(?i)<a.*?href="(.*?)">(.*?)<', $STR_REGEXPARRAYGLOBALFULLMATCH)
    If Not @error Then
        _ArrayDisplay($aHTML_Parsed, '$aHTML_Parsed')
        For $iOuter_idx = 0 To UBound($aHTML_Parsed) -1
            $aInner = $aHTML_Parsed[$iOuter_idx]
            ConsoleWrite($aInner[$eHref] & ' ' & $aInner[$eText] & ' ' & @CRLF)
        Next
    EndIf
EndFunc   ;==>_Example

Now you must only use:

FileOpen(...
FileWrite(...
FileClose(...

You should do it yourself as this is the easiest part of this job.

mLipok

Edited January 1, 2016 by mLipok

[blackandwhite]

yes I got this  Thank you very much! 

[mikell]

Easier...

Local $sHTML = '<table class="n bs"><tbody><tr><td class="u"><a href="/site/151919time=12">site1</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/54769time=12">site2</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/64889time=12">site3</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/66595time=12">site4</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table></li><li class="bj"><table class="n bs"><tbody><tr><td class="u"><a href="/site/31461time=12">site5</a></td><td class="o"><span class="bt bu">0</span></td></tr></tbody></table>'

Local $s = StringRegExpReplace(StringRegExpReplace($sHTML, _ 
        '(?s).*?href="(.*?)time=\d+">(.*?)<', "$1  $2" & @crlf), '\R.*$', "")
Msgbox(0,"", $s)

 

[computergroove]

Curious why you need it to work without IE.au3

[mLipok]

For example, I have hundreds thousands of html pages with official notices of tenders, this is a packed 3 GB of data stored on my disc.
Analysis via IE is too slow...
 

Edited January 1, 2016 by mLipok
wording