Using AutoIT with PDFCreator Version 2.0

[ijourneaux]

I have several Autotit scripts that print documents to PDFCreator (1.7.3). THis has worked very well but I am concerned with  the long term viability of the apps since PDFCreator is now several versions beyond  1.7.3.  Unfortuantely the dialog box for the new version of PDF creator  doesn't seem to work well with AutoIT. Has anyone been able to get this to work  or come up with a way to control PDFCreater version 2.+ via COM?

Thanks

[mLipok]

 

 

some reference and examples for PDFCreator 2.x.x

  Reveal hidden contents

http://www.pdfforge.org/pdfcreator/manual/com-interface
http://www.pdfforge.org/pdfcreator/manual/queue >> PDFCreatorBeta.JobQueue
http://www.pdfforge.org/pdfcreator/manual/printjob
http://www.pdfforge.org/pdfcreator/manual/outputfiles
http://www.pdfforge.org/pdfcreator/manual/com-interface-settings
http://www.pdfforge.org/pdfcreator/manual/printers
http://www.pdfforge.org/pdfcreator/manual/pdfcreator >> PDFCreatorBeta.PDFCreator   /    PDFCreatorBeta.PDFCreatorObj

 

or:

http://docs.pdfforge.org/pdfcreator/2.1/en/com-interface/reference/
http://docs.pdfforge.org/pdfcreator/2.1/en/com-interface/user-manual/

example
http://community.spiceworks.com/topic/886838-pdfcreator-com-v2-1-vbscript-running-as-service-failing

 

http://docs.pdfforge.org/pdfcreator/latest/en/pdfcreator/com-interface/

 

Edited February 9, 2016 by mLipok

[mLipok]

Here is working exmple:

expandcollapse popup

#include <AutoItConstants.au3>
; http://docs.pdfforge.org/pdfcreator/latest/en/pdfcreator/com-interface/user-manual/basics/convert-single-file/
;~ "c:\Program Files\PDFCreator\COM Scripts\JS Scripts\Basics\TestPage2JPG.js"

_Example()
Func _Example()


    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent('AutoIt.Error', '_ErrFunc')

    Local $oPDFCreatorQueue = ObjCreate('PDFCreator.JobQueue')
    $oPDFCreatorQueue.Initialize()

    Local $sTXT_FileFullPath = @ScriptDir & '\PDFCreator_test.txt'
    FileWrite($sTXT_FileFullPath,'Testing PDFCreator')
    ConsoleWrite('PRINT: ' & $sTXT_FileFullPath  & @CRLF)
    ShellExecute($sTXT_FileFullPath,'', @ScriptDir, $SHEX_PRINT)


    Local $sPDF_FileFullPath = @ScriptDir & '\TestPage.pdf'


    ConsoleWrite('WaitForJob' & @CRLF)
    If Not $oPDFCreatorQueue.WaitForJob(10) Then
        ConsoleWrite('The print job did not reach the queue within 1 seconds' & @CRLF)
    EndIf


    ConsoleWrite('$oPDFCreatorQueue.Count=' & $oPDFCreatorQueue.Count & @CRLF)
    Local $oJob = Null
    If $oPDFCreatorQueue.Count = 0 Then
        Return SetError(1)
    Else
        $oJob = $oPDFCreatorQueue.NextJob
    EndIf


;~  $oJob.SetProfileByGuid('JpegGuid')
    $oJob.SetProfileByGuid('PdfaGuid')
    $oJob.ConvertTo($sPDF_FileFullPath)
    If Not $oJob.IsFinished Or Not $oJob.IsSuccessful Then
        ConsoleWrite('Could not convert the file: ' & $sPDF_FileFullPath & @CRLF)
    Else
        ConsoleWrite('Job finished successfully' & @CRLF)
    EndIf

    $oPDFCreatorQueue.ReleaseCom()
    $oPDFCreatorQueue = Null

EndFunc    ;==>_Example


; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & ' (' & $oError.scriptline & ') : ==> COM Error intercepted !' & @CRLF & _
            @TAB & 'err.number is: ' & @TAB & @TAB & '0x' & Hex($oError.number) & @CRLF & _
            @TAB & 'err.windescription:' & @TAB & $oError.windescription & @CRLF & _
            @TAB & 'err.description is: ' & @TAB & $oError.description & @CRLF & _
            @TAB & 'err.source is: ' & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & 'err.helpfile is: ' & @TAB & $oError.helpfile & @CRLF & _
            @TAB & 'err.helpcontext is: ' & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & 'err.lastdllerror is: ' & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & 'err.scriptline is: ' & @TAB & $oError.scriptline & @CRLF & _
            @TAB & 'err.retcode is: ' & @TAB & '0x' & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc    ;==>_ErrFunc

 

[ijourneaux]

Fabulous Guys. This is a great starting point.

[mLipok]

So rolled up their sleeves, and work ... and share the results.

Edited February 9, 2016 by mLipok