stdoutread not picking up error

[Jewtus]

I'm trying to run a command line to create a network shared folder and make sure that I don't get an access denied error. When I use the following:

$pid = RunWait('"' & @ComSpec & '" /c net share SharedFolder="C:\TEST" /grant:everyone,FULL', '', @SW_HIDE, $STDOUT_CHILD)
    $sOutput = StdoutRead($pid)
    MsgBox(0, "", $sOutput)

It runs but a blank msgbox shows up and the following is written to the SCITE console:

System error 5 has occurred.

Access is denied.

Why isn't this being captured? Is there any way of telling if the command executed correctly?

[mLipok]

Try this:
 

#RequireAdmin

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

_Example()
Func _Example()
    Local $iPID = RunWait('"' & @ComSpec & '" /c net share SharedFolder="C:\TEST" /grant:everyone,FULL', '', @SW_HIDE, $STDOUT_CHILD)
    Local $sOutput = ''
    
    While 1
        $sOutput &= StdoutRead($iPID)
        ; Exit the loop if the process closes or StdoutRead returns an error.
        If @error Then ExitLoop
        Sleep(10)
    WEnd
    MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)
    
EndFunc

 

Edited October 28, 2016 by mLipok
script fix :)

[AutoBert]

@mLipok: there is also a handle to $STDERR_CHILD needed.

#RequireAdmin
_Example()
Func _Example()
    Local $pid = RunWait('"' & @ComSpec & '" /c net share SharedFolder="C:\TEST" /grant:everyone,FULL', '', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)

    While 1
        $sOutput = StdoutRead($iPID)
        ; Exit the loop if the process closes or StdoutRead returns an error.
        If @error Then ExitLoop
        Sleep(10)
    WEnd
    MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)
    
EndFunc

 

Edited October 28, 2016 by AutoBert

[mLipok]

look in my edit:  script fix

[Jewtus]

I tried to run both examples, but I still get a blank msgbox. Its weird because I use the exact same function elsewhere and I get the readout, but it doesn't capture this error.

 

I actually really only care to capture the failures (if it is successful I just want the script to continue).

[Jos]

RunWait?  guys come-on

[mLipok]

[Jewtus]

I assume it should have been Run instead of RunWait?

I tried just run and still I get the empty msgbox. I thought that maybe the stdoutread was getting wiped out when it errors so I even tried using a temp string but still no luck:

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

_Example()
Func _Example()
    Local $pid = Run('"' & @ComSpec & '" /c net share SharedFolder="C:\TEST" /grant:everyone,FULL', '', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
    local $sOutput
    While 1
        $sTemp = StdoutRead($pid)
        ; Exit the loop if the process closes or StdoutRead returns an error.
        If @error Then
            ExitLoop
        Else
            $sOutput=$sTemp
        EndIf
        Sleep(10)
    WEnd
    MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)

EndFunc

 

[Jos]

There is a reason why we have these nice examples in the helpfile.
You aren't reading the STDERR so don't get the error: Quick and dirty fix:

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

_Example()
Func _Example()
    Local $pid = Run('"' & @ComSpec & '" /c net share SharedFolder="C:\TEST" /grant:everyone,FULL', '', @SW_HIDE, $STDOUT_CHILD + $STDERR_CHILD)
    local $sOutput
    While 1
        $sTemp = StdoutRead($pid)
        $sTemp &= StderrRead($pid)
        ; Exit the loop if the process closes or StdoutRead returns an error.
        If @error Then
            ExitLoop
        Else
            $sOutput&=$sTemp
        EndIf
        Sleep(10)
    WEnd
    MsgBox($MB_SYSTEMMODAL, "Stdout Read:", $sOutput)

EndFunc

 

[Jewtus]

Ohhhhhh that makes sense. I didn't realize they worked separately. That makes WAY more sense. Thanks @Jos!