OutlookEX UDF - Help & Support (IV)

[Simpel]

Grrr, IT in this company makes me crazy.

I'm sitting at the same pc, outlook itself worked like yesterday, I'm running the same test snippet and today sending the mail with _OL_Wrapper_SendMail() returns an error. _OL_ErrorNotify(1) says:

Quote

COM Error Encountered in test7.au3
OutlookEX UDF version = 1.3.6
@AutoItVersion = 3.3.14.2
@AutoItX64 = 1
@Compiled = 0
@OSArch = X64
@OSVersion = WIN_10
Scriptline = 4350
NumberHex = 80070057
Number = -2147024809
WinDescription = Falscher Parameter. (Wrong parameter)
Description = 
Source = 
HelpFile = 
HelpContext = 
LastDllError = 0

I'm not aware of doing or having done anything differently today then yesterday. What could that "wrong parameter" be?

[water]

The sent mail is saved in folder "Sent items"  ("Gesendete Objekte").
You could use the event driven approach described in example script _OL_Example_ItemAdd_Event.au3
The object returned by _OL_Wrapper_SendMail is no longer valid to access the moved sent mail item. That's what causes your problem.
Another approach is to search the Sent Items folder for the sent mail.

[seadoggie01]

I've done something like this before, and if I remember correctly, the sent email object is no longer valid after it has been sent. To solve it, I searched the sent email folder for the subject of the just sent email (I think I specified within the last minute as well) and copied that object instead.

Edit: And now I see there's another page of replies 

Edited July 8, 2022 by seadoggie01

[jiataifeng]

I would like to get all the appointments information from ics files but ics files are hard to parse. Is it possible to parse ics file to xml? Is there a tool can do so? Thanks.

[baconaise]

Good morning,

At work, I frequently use Microsoft Word's Mail Merge (which does not support BCC or attachments) to send emails to a couple hundred people. I aim to use this wonderful UDF to add a BCC email and attachments to these emails. I can get the emails to sit in my outbox by setting Outlook to Work Offline, so I'm trying to put something together that will loop through all the emails in my outbox and give each a BCC address and selected attachments. Below is what I have so far, but I'm not clever enough today to fix the Update_Outbox() function, and I was hoping someone in here was willing to help. I have outlined what I think I should try to do.

expandcollapse popup

AutoItSetOption("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Global $BCC_Address
Global $Email_Attachment
#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <GUIConstants.au3>
#include <OutlookEx_Base.au3>
#include <OutlookEx.au3>

#Region ;GUI
Global $Email_Helper_GUI = GUICreate("", 311, 58)
    GUISetBkColor(0xCCCCCC)
    GUISetFont(14)
    GUISetOnEvent($GUI_EVENT_CLOSE, "Email_Helper_Events")
    GUISetOnEvent($GUI_EVENT_MINIMIZE, "Email_Helper_Events")
    GUISetOnEvent($GUI_EVENT_RESTORE, "Email_Helper_Events")
Global $GUI_Label_BCC = GUICtrlCreateLabel("BCC email:",5,5,90,22)
Global $BCC_Address_Field = GUICtrlCreateInput("",100,5,206,22)
    GUICtrlSetFont(-1,12)
Global $GUI_Select_Attachment_Button = GUICtrlCreateButton("Select Attachment",3,30,150,24)
    GUICtrlSetFont(-1,12)
    GUICtrlSetOnEvent(-1,"Select_Attachment")
Global $GUI_Update_Outbox_Button = GUICtrlCreateButton("Update Outbox",158,30,150,24)
    GUICtrlSetFont(-1,12)
    GUICtrlSetOnEvent(-1, "Update_Outbox")
    GUISetState(@SW_SHOW, $Email_Helper_GUI)
#EndRegion

While 1
   Sleep(10)
WEnd

Func Email_Helper_Events() 
   Select
      Case @GUI_CtrlId = $GUI_EVENT_CLOSE
         Exit
      Case @GUI_CtrlId = $GUI_EVENT_MINIMIZE
      Case @GUI_CtrlId = $GUI_EVENT_RESTORE
   EndSelect
EndFunc

Func Select_Attachment()
    $Email_Attachment = FileOpenDialog("Select Attachment", @MyDocumentsDir,"All (*.*)", BitOR($FD_FILEMUSTEXIST, $FD_MULTISELECT))
    If @error Then ; Display the error message.
        MsgBox($MB_SYSTEMMODAL, "", "No file(s) were selected.")
        FileChangeDir(@ScriptDir) 
    Else
        FileChangeDir(@ScriptDir) 
        MsgBox($MB_SYSTEMMODAL, "", "You chose the following file(s):" & @CRLF & $Email_Attachment)
    EndIf
EndFunc

Func Update_Outbox()
    $BCC_Address = GUICtrlRead($BCC_Address_Field)
    Global $oOL = _OL_Open()                                            ; Connect to Outlook
    Global $Outlook_Outbox = _OL_FolderAccess($oOL, $olFolderOutbox)    ; Access the Outbox
;~  For ???? to ????
;~  ????????????? = _OL_ItemRecipientAdd($oOutlook, $Each_Email_In_Outbox, Default, $olBCC, $BCC_Address)
;~  ????????????? = _OL_ItemAttachmentAdd($oOutlook, $Each_Email_In_Outbox, Default, $Email_Attachment)
;~  Next
;~  MsgBox(1,"OutBox Update Complete", "The OutBox has been updated.")
;~  _OL_Close($oOutlook)
EndFunc

I appreciate any guidance. Thank you.

 

[water]

18 hours ago, jiataifeng said:

I would like to get all the appointments information from ics files but ics files are hard to parse. Is it possible to parse ics file to xml? Is there a tool can do so? Thanks.

You could have a look at function _OLT_iCal_VEvent_Import in my OutlookTools UDF (for download please see my signature below).
You won't get an XML file and the function has its limitation (see the Wiki) but the parsed ICS file gets returned as an array.
Set parameter $iDebug = $iOLT_DebugCreateOff then no Outlook item will be created from the ICS file, just the array will be returned.

[water]

2 hours ago, baconaise said:

At work, I frequently use Microsoft Word's Mail Merge ...

Seems there are tools available to extend the functions of Mail Merge:

• Attachments or Outlook Mail Merge Attachment (OMMA) (sourceforge.net)

Or you could grab the Outlook event to modify a mail before it gets sent.
Please check example script _OL_Example_ItemSend_Event.au3 from the OutlookEX UDF (for download please see my signature).

[baconaise]

3 hours ago, water said:

Seems there are tools available to extend the functions of Mail Merge:

• Attachments or Outlook Mail Merge Attachment (OMMA) (sourceforge.net)

OMMA gave me the idea for this, but neither of those options allow adding a BCC email. Work requires I log the emails I send by BCCing an email address. I am trying to automate both the attachments and the BCCing.

[baconaise]

It appears my current hurdle is _OL_FolderAccess giving the error "Error accessing Outbox. @error = 4, @extended = 1" when I try to run this:

Func Update_Outbox()
    Global $oOL = _OL_Open()                                            
    Global $Outlook_Outbox = _OL_FolderAccess($oOL, $olFolderOutbox)

Which means it can't find $olFolderOutbox.

I thought that part would work because I found $olFolderOutbox in OutlookEX_Base.au3 (which I included in the script). Any idea why it can't find the outbox?

[water]

Your syntax is wrong. Should be: 

Global $Outlook_Outbox = _OL_FolderAccess($oOL, "", $olFolderOutbox)

 

[water]

Another approach:
Wait for emails to be sent by Outlook.

• When the subject starts with the mailberge marker (selected by you) BCC will be set an the attachment will be added.
• Else the mail will just be sent

With this approach there is no need to take Outlook offline.

expandcollapse popup

#include <OutlookEX.au3>

; *****************************************************************************
; Example Script
; Handle Outlook event when a new item is being sent.
; This example script checks for mail items and changes the subject before the mail is
; being sent.
; This script loops until Shift-Alt-E is pressed to exit.
; *****************************************************************************
HotKeySet("+!e", "_Exit") ;Shift-Alt-E to Exit the script
MsgBox(64, "OutlookEX UDF Example Script", "Hotkey to exit the script: 'Shift-Alt-E'!")

Global $oOL = _OL_Open()
Global $oEvent = ObjEvent($oOL, "_oItems_")

Global $sBCC = "Jon.Doe@gmx.com"
Global $sAttachment = @ScriptFullPath
Global $sMarker = "<MailMerge>" ; Marker
While 1
    Sleep(50)
WEnd

; ItemSend event - https://docs.microsoft.com/en-us/office/vba/api/outlook.application.itemsend
Volatile Func _oItems_ItemSend($oItem, $bCancel)
    #forceref $bCancel
    $bCancel = False ; If you do not want to send the item then set $bCancel to True
    If $oItem.Class = $olMail Then
        If StringLeft($oItem.Subject, StringLen($sMarker) = $sMarker Then     ; Marker to identify mail merge mails found?
            $oItem.Subject = StringMid($oItem.Subject, StringLen($sMarker)+1) ; Remove the marker
            _OL_ItemRecipientAdd($oOL, $oItem, Default, $olBCC, $sBCC)        ; Add the BCC recipient
            _OL_ItemAttachmentAdd($oOL, $oItem, Default, $sAttachment)        ; Add the attachment
            $oItem.Save()
        EndIf
    EndIf
EndFunc   ;==>oItems_ItemSend

Func _Exit()
    Exit
EndFunc   ;==>_Exit

 

[baconaise]

I solved all my issues by studying the sample files you included with the thing. I should have read everything before asking a question. What I ended up with was essentially this:

Global $Outlook_Connection = _OL_Open()
Global $Outlook_Outbox = _OL_FolderAccess($Outlook_Connection, "", $olFolderOutbox)
Global $Emails_In_Outlook_Outbox = _OL_ItemFind($Outlook_Connection, $Outlook_Outbox[1], $olMail, "", "", "", "EntryID")

For $iIndex = 1 To $Emails_In_Outlook_Outbox[0][0]
  $Email_In_Focus = $Outlook_Connection.Session.GetItemFromID($Emails_In_Outlook_Outbox[$iIndex][0])
  _OL_ItemRecipientAdd($Outlook_Connection, $Email_In_Focus, Default, $olBCC, $BCC_Address)
  _OL_ItemAttachmentAdd($Outlook_Connection, $Email_In_Focus, Default, $Email_Attachment)
Next

I very much appreciate you making this UDF. This is going to save me upwards of an hour per week.

Edited August 24, 2022 by baconaise
Clarity

[water]

Glad you got your problem solved 😃

[NolleWed]

Hi together,

now I use my script on WIN 8 (Microsoft Office Professional Plus 2013) and it works perfect.

I have to change to WIN 10 (Microsoft 365 Apps for Enterprise) and as I tested the script it don´t work anymore. Can you please help?

I downloaded the actual OutlookEx.au3 (OutlookEX 1.7.0.1) and OutlookEX_GUI.au3 (OutlookEX_GUI 1.4.0.0)

$htmlpfad = "U:\C\CO\@ Order Processing\Team Fixed Line Porting\TKG Team\Prävention\AutoIt\kurzfr. Storno\html-Storno.txt"
Local $datei = FileOpen($htmlpfad, 0)
Local $HTML = FileRead($datei)
FileClose($datei)

$HTMLKDDaten = $HTML
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#Rufnummern#",$alleNummern)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#relevante Nummer#",$relevanteNummer)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#Kundennummer#",$Kundennummer_Wert)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#NameVorname#",$KDNachname_Wert & ", " & $KDVorname_Wert & ", " & $Firmenname_Wert)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#StraßeHausnummer#",$Strasse_Wert & " " & $Hausnr_Wert & " " & $HausnrZusatz_Wert)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#PLZOrt#",$PLZ_Wert & " " & $Ort_Wert)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#EKPabg#",$EKPabg_Wert)
$HTMLKDDaten = StringReplace($HTMLKDDaten,"#CarrierCode#",$CarrierCode_Wert)

$oOutlook = ObjGet("", "Outlook.Application")
        
    if $CarrierEMail = "nicht gefunden" Then
        $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "", "", "Subject=[AutoIT:ZU PRUEFEN] #abw# weiterversorgen #kurzfristiger Storno# " &   $alleNummern & " , " & $relevanteNummer & " , " & $Kundennummer_Wert, "", "SentOnBehalfOfName=ABW-Clearing-D019@telefonica.com")
        $EMail = "ABW-Clearing-D019@telefonica.com"
    Else
        $oItem = _OL_ItemCreate($oOutlook, $olMailItem, "", "", "Subject=#abw# weiterversorgen #kurzfristiger Storno# " & $alleNummern & " , " & $relevanteNummer & " , " & $Kundennummer_Wert, "", "SentOnBehalfOfName=ABW-Clearing-D019@telefonica.com")
        $EMail = $CarrierEMail
    EndIf
    
    $EMailCC = "ABW-Clearing-D019@telefonica.com"
        
    _OL_ItemRecipientAdd($oOutlook, $oItem, Default, $olTo, $EMail) ; Empfänger wird gesetzt
    _OL_ItemRecipientAdd($oOutlook, $oItem, Default, $olCC, $EMailCC) ; CC wird gesetzt
    
    $oItem.display
    $oItem.BodyFormat = $olFormatHTML
    $sBody = $oItem.HTMLBody
    $oItem.HTMLBody = $HTMLKDDaten & $sBody

    $oItem.send

error AutoIt:

"U:\C\CO\@ Order Processing\Team Termination and Cancellation\persönliche Ordner\"Username"\Autoit\ISN AutoIt Studio\Projects\Outlooktest mit DEU.TEFGER.V001584774\Outlooktest_mit_DEU_TEFGER_V001584774.au3" (382) : ==> The requested action with this object has failed.:
$sBody = $oItem.HTMLBody
$sBody = $oItem^ ERROR

 

The creation of the mail works and also the subject is set.

SentOnBehalfOfName does not work: my email-adress is taken instead of ABW-Clearing-D019@telefonica.com
and the whole body is not set (it´s empty)

Edited April 19, 2023 by NolleWed

[water]

Cound you please add

_OL_ErrorNotify(2)

at the top of your script so we get more detailed error information?

[water]

BTW:
SentOnBehalfOfName requires the Displayname not the full Mail-Address. Maybe this is the cause of the problem.

[NolleWed]

22 minutes ago, water said:

BTW:
SentOnBehalfOfName requires the Displayname not the full Mail-Address. Maybe this is the cause of the problem.

this is the Displayname, for WIN8 it works

[NolleWed]

33 minutes ago, water said:

Cound you please add

_OL_ErrorNotify(2)

at the top of your script so we get more detailed error information?

 

 

when I click ok, the body comes:

 

 

then I have to kill the script because with each new click on ok a new mail is created

Edited September 19, 2022 by NolleWed

[water]

Might be caused by a group policy as described here.

[NolleWed]

11 hours ago, water said:

Might be caused by a group policy as described here.

That link doesn´t help me. I still don´t know how to solve the problem.

I don´t know how to do this:

When I use this testscript the body is filled

#include <OutlookEx.au3>
$oOL = _OL_Open()
_OL_Wrapper_SendMail($oOL, "John Doe", "", "", "Testmail", "<b>Test</b>", "", $olFormatHTML, $olImportanceHigh)
_OL_Close($oOL)

When I use this testscrpit I get an error message

#include <OutlookEx.au3>
; Open the connection to Outlook
Global $oOL = _OL_Open()
; Create a mail item and set some properties
Global $oItem = _OL_ItemCreate($oOL, $olMailItem, "*\Outlook-UDF-Test\TargetFolder\Mail", "", _
  "Subject=TestMail", "BodyFormat=" & $olFormatHTML, "HTMLBody=Bodytext in <b>bold</b>.", "SentOnBehalfOfName=Doe Jane")
; Add a recipient and resolve it
_OL_ItemRecipientAdd($oOL, $oItem, Default, $olTo, "Doe John")
; Send the mail
_OL_ItemSend($oOL, $oItem)
If @extended = -2147352567 Then _
  MsgBox(16, "OutlookEX UDF - Example Script", "You don't have permission to send the mail on behalf of the specified person!")
_OL_Close($oOL)

 

Edited September 20, 2022 by NolleWed