reading binary file to array

[FMS]

Hello,

I'm trying to read a binary file to an array but couln't get it to work.
Also I coul not find any help in the forum around this subject whish was helpfull.

Is there any way it could be done?

I tried a lot of ways but maybe somebody know's the right way?

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <File.au3>
#include <Array.au3>
#include <AutoItConstants.au3>

Local $in=FileOpen("TEST_labels.idx1-ubyte",16) ; 16+0=Read binary
Local $data = FileRead($in)
Local $FileArray = BinaryToString($data,4)
;~ $FileArray = StringSplit($BinarydData, @CRLF, 1+2)
;~ Local $FileArray = StringRegExp($BinarydData, "[^\r\n]+", 3)
FileClose($in)
_ArrayDisplay($FileArray,"$FileArray","",32)
MsgBox($MB_SYSTEMMODAL, "", "$FileArray = " & $FileArray )

 

TEST_labels.idx1-ubyte

Edited February 14, 2018 by FMS

[BrewManNH]

What do you expect the array to look like? Also, BinaryToString returns a string, not an array.

[FMS]

yeah sorry @BrewManNH
I was fideling around whit the code to first just read the file.
Whish I dint get to work
What i want in the end is an array whit 10.000 numbers in it.

[BrewManNH]

You can take something like this script and modify to your needs.

#include <Constants.au3>
#include <Array.au3>
#include <StringConstants.au3>

Example()

Func Example()
    ; Create a random string of lower-case ASCII characters.
    Local $sString = ''
    For $i = 1 To 1000
        $sString &= Chr(Random(97, 122, 1))
    Next

    ; Split the string to 2 characters per line.
    ChrsPerLine($sString, 2)
    $array = StringSplit($sString, @CRLF, $STR_ENTIRESPLIT)

    ; Display the split string.
    _ArrayDisplay($array)
EndFunc   ;==>Example

Func ChrsPerLine(ByRef $sData, $iChrsPerLine = 4096) ; Default is 4096 characters per line.
    $iChrsPerLine = Int($iChrsPerLine)
    If $iChrsPerLine <= 0 Then $iChrsPerLine = 4096

    Local $sTemp = ''
    While StringLen($sData) > $iChrsPerLine
        $sTemp &= StringLeft($sData, $iChrsPerLine) & @CRLF
        $sData = StringTrimLeft($sData, $iChrsPerLine)
    WEnd

    If StringLen($sData) Then
        $sTemp &= $sData & @CRLF
    EndIf
    $sData = $sTemp
EndFunc   ;==>ChrsPerLine

*Note: script slightly modified from this post.

 

[kylomas]

FMS,

Try this...

#include <Array.au3>

$sfile = FileRead(@ScriptDir & '\TEST_labels.idx1-ubyte')

Local $afile = StringRegExp($sfile, '\d{2}', 3)

_ArrayDisplay($afile)

kylomas

[BrewManNH]

That wouldn't work in his case, the "numbers" are in Hex..

[mLipok]

13 hours ago, FMS said:

yeah sorry @BrewManNH
I was fideling around whit the code to first just read the file.
Whish I dint get to work
What i want in the end is an array whit 10.000 numbers in it.

if you need BinaryArray to store in SQL or to work with some PDF API you should look for this :

FileOpen(...$FO_BINARY....
FileRead(..
FileClose(...

 

 

Edited February 15, 2018 by mLipok

[kylomas]

FMS,

I inspected your file with notepad++ and don't find any "hex" numbers, just decimal.  Unless it is just a coincidence the the 10,007 numbers do not contain A-F.

Did you try my code?

Try this...

#include <Array.au3>

$sfile = FileRead(@ScriptDir & '\TEST_labels.idx1-ubyte')

Local $afile = StringRegExp($sfile, '.{2}', 3)

local $afile2[ubound($afile)][2]

for $1 = 0 to ubound($afile) - 1
    $afile2[$1][0] = $afile[$1]
    $afile2[$1][1] = hex($afile[$1],4)
Next

_ArrayDisplay($afile2)

kylomas

Edited February 15, 2018 by kylomas

[jchd]

Try this:

#include <File.au3>
#include <Array.au3>
#include <AutoItConstants.au3>

Local $in=FileOpen("TEST_labels.idx1-ubyte", 16) ; 16+0=Read binary
Local $data = FileRead($in)
FileClose($in)
Local $iSize = BinaryLen($data)
Local $aByte[$iSize]
For $i = 0 To $iSize - 1
    $aByte[$i] = Int(BinaryMid($data, $i + 1, 1))
Next
_ArrayDisplay($aByte, "$FileArray", "", 32)