rtf clipboard text to html

[kisstom]

Hi,

I'm working on a dictionary project, I would like to get formatted text from clipboard, then make a HTML formatted text, for example after copy this text:

test test1 test2

And I want a result like this:

test <b>test1</b> <i>test2</i>

Since ClipGet retrieves text only I have no idea where to start

 

[BrewManNH]

You would need to use one of the _Clipboard_* functions to do this. The standard ClipPut/Get only deals with text, so you need access to the full implementation of the clipboard to do this. Check the help file.

[kisstom]

_clipboard_getdata shows the same text to me, in the options there is text only (others not seems relevant)

[mikell]

The best (and only ?) way I could think of to do that is the super nice _ClipGetHTML.au3 UDF  by Ascend4nt

Here is a sample script to test it, based on Ascend4nt's one

#include <_ClipGetHTML.au3>

$hGUI = GUICreate("", 600, 400, 0, 0)
$iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, 0x200000)    ; $WS_VSCROLL=0x00200000
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()

$sHTMLStrPrev = ""
Do
    $aHTMLData=_ClipGetHTML()
    If Not @error And ($aHTMLData[0]<>$sHTMLStrPrev) Then
        GUICtrlSetData($iMemo,"","")
        $res = StringRegExpReplace(BinaryToString($aHTMLData[0],4), '</?(?|html|body|![^>]+)>', "")
        GUICtrlSetData($iMemo, $res & @CRLF, 1)
        $sHTMLStrPrev=$aHTMLData[0]
    EndIf
Until GUIGetMsg()=-3    ; $GUI_EVENT_CLOSE=-3
GUIDelete($hGUI)

This UDF will achieve 99% of the hard job. Good luck for the remaining 1%  

 

[kisstom]

Thanks, I found that UDF but it's not what I'm looking for, it works only when put text from a browser (HTML formatted already). What I need is text from rtf file.

[mLipok]

Ooo activex com object.

Edited December 17, 2018 by mLipok

[mLipok]

command line:

https://ask.libreoffice.org/en/question/2641/convert-to-command-line-parameter/

or

OOO ActiveX Component:

expandcollapse popup

;~ https://wiki.openoffice.org/wiki/API/Tutorials/PDF_export
;~ http://www.kalitech.fr/clients/doc/VB_APIOOo_en.html

; Error monitoring. This will trap all COM errors while alive.
; This particular object is declared as local, meaning after the function returns it will not exist.
Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

MsgBox(0, '_OOO_ReadRTFText()', _OOO_ReadRTFText())

Func _OOO_ReadRTFText()
    Local $oSM = ObjCreate("com.sun.star.ServiceManager")
    Local $oDesk = $oSM.createInstance("com.sun.star.frame.Desktop")
    Local $aOpenPar
    _OOO_MakePropertyValue($aOpenPar, "ReadOnly", True)
    _OOO_MakePropertyValue($aOpenPar, "Hidden", False)
    Local $sURL
;~  $sURL = "file:///l:/RTF_TEST.RTF"
    $sURL = "file:///l:/___TEMP/RTF_ORG.RTF"
    Local $oDoc = $oDesk.loadComponentFromURL($sURL, "_blank", 0, $aOpenPar)
    Sleep(100)
    Local $aPrintPar[0]
;~  $oDoc.print($aPrintPar)

    Local $aMediaDescriptor
    _OOO_MakePropertyValue($aMediaDescriptor, "FilterName", 'writer_pdf_Export')
    $oDoc.storeToURL($sURL & '.pdf', $aMediaDescriptor)

    $aMediaDescriptor =0
    _OOO_MakePropertyValue($aMediaDescriptor, "FilterName", 'writerglobal8_HTML')
    $oDoc.storeToURL($sURL & '.html', $aMediaDescriptor)

    Return $oDoc.Gettext

EndFunc   ;==>_OOO_ReadRTFText

Func _OOO_MakePropertyValue(ByRef $aParameters, $sName, $sValue)
    Local $aTemp[0]
    Local $oSM = ObjCreate("com.sun.star.ServiceManager")
    Local $oPropertyValue = $oSM.Bridge_GetStruct("com.sun.star.beans.PropertyValue")
    $oPropertyValue.Name = $sName
    $oPropertyValue.Value = $sValue

    if not IsArray($aParameters) then $aParameters = $aTemp

    ReDim  $aParameters[UBound($aParameters)+1]
    $aParameters[UBound($aParameters)-1] = $oPropertyValue

EndFunc   ;==>_OOO_MakePropertyValue


; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

 

Edited December 17, 2018 by mLipok

[kisstom]

Nothing shows up. Do I have to instal liblreoffice? Also I not really want to convert an rtf file, I want to use rtf formatted text from clipboard.

[mLipok]

On 17.12.2018 at 2:08 PM, kisstom said:

to get formatted text from clipboard,

What kind/type of formatted text you have in clipboard ?
And how they was copied to clipboard ?

On 17.12.2018 at 7:32 PM, kisstom said:

it works only when put text from a browser (HTML formatted already). What I need is text from rtf file.

EDITED: This is not always true:  I used this  _ClipGetHTML.au3 UDF  by Ascend4nt to get HTML form EXCEL / OPEN OFFICE CALC - of course with success.
If you open RTF file in OpenOffice/LibreOffice (probably also in MS Word) .... copy content to Clipboard, then you will have 

Did you check it with ClibBoardViewer ?

http://www.freeclipboardviewer.com/

This following screnshot is present what you will have when you  have RTF file content copied by LibreOffice to clipboard.

 

 

14 hours ago, kisstom said:

Do I have to instal liblreoffice?

Yes, eventually OpenOffice.

14 hours ago, kisstom said:

Also I not really want to convert an rtf file, I want to use rtf formatted text from clipboard.

You may use  _ClipGetHTML.au3 UDF  by Ascend4nt to get HTML directly from ClipBord......

or Put ClipBoard to RichEdit, save RichEdit to RTF file , convert them with ActiveX object, as I show to you in my example given to you few post before.

Edited December 18, 2018 by mLipok

[kisstom]

Thank you for your help. I just find another approach. I put my dictionary entries in rtf file then I can use ' search and replace' in Word to format as I want.

I solved a lot of problem with autoit before so my first idea was do it with autoit   But this time Word is easier.