Assign value within multidimensional arrays doesn't work

[AlexIsProgramming]

Hello guys,

i've got a problem assigning a single value within a multidimensional array. I want to change the subarray value in $array_1[2] from 4 to 9. Can anyone tell me where is my fallacy is?

#include <Array.au3>

Local $array_1[3] = [1,2]
Local $array_2[3] = [4,5,6]

$array_1[2] =$array_2

_ArrayDisplay($array_1)
_ArrayDisplay($array_1[2])
($array_1[2])[0] = 9
_ArrayDisplay($array_1[2])

 

[water]

It doesn't work this way, IIRC.
You have to extract the subarray, modify it and then upate the array with the modified subarray.
See this wiki tutorial for details.

[AlexIsProgramming]

To clarify, I don't want to change the value in $array_2. I want to change the value stored in $array_1. $array_2 is just for building up the 'working array'.

I can't use the normal way like this:

#include <Array.au3>

Local $array_1[3][3] = [[1],[2],[4,5,6]]
;~ Local $array_2[3] = [4,5,6]

;~ $array_1[2] =$array_2

_ArrayDisplay($array_1)
$array_1[2][0] = 9
_ArrayDisplay($array_1)

In my programm $array_1 holds all GUICTRL-ID's and at some point I want to change the assignd value. I know Arrays in Arrays is hard work, but so far the benefits are worth it.

The question is, why can i only read the value but not change it. Is there really no way other than extract and write again?

[AlexIsProgramming]

25 minutes ago, water said:

It doesn't work this way, IIRC.
You have to extract the subarray, modify it and then upate the array with the modified subarray.
See this wiki tutorial for details.

If the only way to change the value 'extract, modify, update' is, this would be my workaround. But this can't the solution right?

#include <Array.au3>

Local $array_1[3] = [1,2]
Local $array_2[3] = [4,5,6]

$array_1[2] =$array_2

_ArrayDisplay($array_1)
_ArrayDisplay($array_1[2])

$array_1[2] = ChangeArrayInArray($array_1[2],0,9)

_ArrayDisplay($array_1[2])


Func ChangeArrayInArray($_array, $_row, $_value)
   Local $arr[0]
   For $i = 0 To Ubound($_array)-1 Step +1
      If $i = $_row Then
         _ArrayAdd($arr,$_value)
      Else
         _ArrayAdd($arr,$_array[$i])
      EndIf
   Next
   Return $arr
EndFunc

 

[Malkey]

Here's another way.

#include <Array.au3>

Local $array_1[3] = [1, 2]
Local $array_2[3] = [4, 5, 6]

$array_1[2] = $array_2

_ArrayDisplay($array_1)
_ArrayDisplay($array_1[2])

ChangeArrayInArray($array_1[2], 0, 9)

ConsoleWrite(($array_1[2])[0] & @CRLF)  ; Returns 9
_ArrayDisplay($array_1[2])


Func ChangeArrayInArray(ByRef $_array, $_row, $_value)
    Local $arr = $_array
    $arr[$_row] = $_value
    $_array = $arr
EndFunc   ;==>ChangeArrayInArray

 

[Nine]

No need to local copy the array (for large array it will slow down the process), since it is ByRef, just use :

Func ChangeArrayInArray(ByRef $_array, $_row, $_value)
    $_array[$_row] = $_value
EndFunc   ;==>ChangeArrayInArray

 

[Malkey]

@Nine
You're right. The parameter, ByRef $_array, is the local copy of the array, $array_1[2] in the function. There is no need to create another array in the function.

[AlexIsProgramming]

2 hours ago, Nine said:

No need to local copy the array (for large array it will slow down the process), since it is ByRef, just use :

Func ChangeArrayInArray(ByRef $_array, $_row, $_value)
    $_array[$_row] = $_value
EndFunc   ;==>ChangeArrayInArray

 

That's far better than my solution 😂 Thank you all for your help!