changing colors

[gcue 10]

hello

i have an existing listview which accepts drop files.  from the files dropped, i am trying to identify duplicate files by highlighting the duplicate files by the same color.  however, id like to add more colors to be able to provide a wider range of files supported.  The method i am using works but not efficient at all.  any ideas on a more efficient method?

what i have works but is very inefficient and limited to 3 colors:

expandcollapse popup

$orange_used = False
    $green_used = False
    $blue_used = False

    For $x = 1 To UBound($listview_array) - 1
;~      $listview_ctrl_id = $listview_array[$x][0]
;~      $file_path = $listview_array[$x][1]
        $sha1_checksum = $listview_array[$x][2]
        $color_assigned = $listview_array[$x][3]
        
        If $color_assigned <> "" Then ContinueLoop

        $search = _ArrayFindAll($listview_array, $sha1_checksum, 0, 0, 0, 0, 2)

        If @error Then ContinueLoop

        If UBound($search) > 1 Then
;~          Debug($search)
            If $orange_used = False Then
                For $y = 0 To UBound($search) - 1
                    $orange_used = True
                    $listview_array[$search[$y]][3] = "ORANGE"
                    GUICtrlSetBkColor($listview_array[$search[$y]][0], 0xFF5733) ;ORANGE
                Next
                ContinueLoop
            EndIf

            If $green_used = False Then
                For $y = 0 To UBound($search) - 1
                    $green_used = True
                    $listview_array[$search[$y]][3] = "GREEN"
                    GUICtrlSetBkColor($listview_array[$search[$y]][0], 0x00FF00) ;GREEN
                Next
                ContinueLoop
            EndIf

            If $blue_used = False Then
                For $y = 0 To UBound($search) - 1
                    $blue_used = True
                    $listview_array[$search[$y]][3] = "BLUE"
                    GUICtrlSetBkColor($listview_array[$search[$y]][0], 0x5DADE2) ;BLUE
                Next
                ContinueLoop
            EndIf
;~          Debug($listview_array)
        EndIf
    Next

thank you in advance!

[careca 277]

you could have a random color generator.

[gcue 10]

How would the color generator automatically work with the script?  Ideally I would like to have a long list of approved (by me) because some colors make text hard to read

[Nine 1,365]

something like this maybe :

Global Const $aColor[] = [0xFF5733, 0x00FF00, 0x5DADE2, 0x101010]   ; a long list of approved colors (do not use 0x000000)
Global $iPtr = 0

For $x = 1 To UBound($listview_array) - 1
;~      $listview_ctrl_id = $listview_array[$x][0]
;~      $file_path = $listview_array[$x][1]
  $sha1_checksum = $listview_array[$x][2]
  $color_assigned = $listview_array[$x][3]

  If $color_assigned Then ContinueLoop

  $search = _ArrayFindAll($listview_array, $sha1_checksum, 0, 0, 0, 0, 2)

  If @error Or UBound($search) = 1 Then ContinueLoop
  If $iPtr = UBound($aColor) Then Exit MsgBox(0, "", "Increase number of colors")

  For $y = 0 To UBound($search) - 1
    $listview_array[$search[$y]][3] = $aColor[$iPtr]
    GUICtrlSetBkColor($listview_array[$search[$y]][0], $aColor[$iPtr])
  Next
  $iPtr += 1
Next

untested...

[gcue 10]

works amazing!! thank you!!

happy fathers day!

[gcue 10]

Also forgot to mention how much I loved the idea of the message indicating the need for more colors

Thanks again

[careca 277]

I was thinking about a random thing, more like this:

"0x" & Hex(Random(1, 255, 1) & Random(1, 255, 1) & Random(1, 255, 1), 6)&@CRLF)

but if pre-setting the colors works for you, it works for me.