I've not be able to get either the xpath, or css Selector path to work consistently with $_WD_LOCATOR_ByXPath

[Dmp]

Hello,

I have an web page icon that needs to clicked on in order to turn on certain functionality on the page, however, I've not be able to get either the xpath, or css Selector path to work consistently with $_WD_LOCATOR_ByXPath; mostly the automation does not click on the icon.  Oddly enough, I am not having this issue w/ other objects on the page.  I'm wondering if this more of a Web Driver configuration issue, such as how I have $sDesiredCapabilities defined... this is not a public site; it's private and requires a username/password.  This is my code as of this point; I have comments related to the out-put pane feedback from each attempted $_WD_LOCATOR_ByXPath:

; Visibilty Page; Click Auto-refresh & the Forklift icon:
;;;;;;;;;;;;;;;;;;;;;;;;;;;
If WinActive("Visibility - Google Chrome","") Then
    ; MsgBox($MB_SYSTEMMODAL, "ACTIVATE", "Visibilty Page Active", 5)
    Sleep(4000)

    ; Click on the Vehicle icon
    ; Below code applys to the icon when it is not active:

    ; Previously worked, but no more.
    ; Output pane states__WD_Post ==> Element interaction issue: {"value":{"error":"element click intercepted","message":"element click intercepted: Element \u003Cdiv class=\"icon VEHICLE-icon\">\u003C/div> is not clickable at point (1465, 831).
    Global $sVhlElement = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//div[@class='icon VEHICLE-icon']")

    ;SelectorsHub xpath; output pane states  __WD_Post ==> Element interaction issue: {"value":{"error":"element click intercepted","message":"element click intercepted: Element \u003Cdiv class=\"icon VEHICLE-icon\">\u003C/div> is not clickable at point (1481, 830).
    ; Global $sVhlElement = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//div[@title='Show Vehicle']//div")

    ; tried using contains per "BigDaddyO" suggestion; output pane states nSyntaxError: Failed to execute.
    ; Global $sVhlElement = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//div[contains@class='leaflet-marker-pane']//div[22]) and contains (@title='Show Vehicle')")

    ; ChroPath xpath; output pane states Element interaction issue: {"value":{"error":"element click intercepted","message":"element click intercepted..."
    ; Global $sVhlElement = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//body/div[@id='app']/div[@id='container']/div[@id='main-map-wrapper']/div[@id='main-map']/div[2]/div[4]/div[3]/div[2]/div[1]")

    _WD_ElementAction($sSession, $sVhlElement, 'click'); Click Vehicle icon

 

Can anyone explain what is meant by " __WD_Post ==> Element interaction issue: {"value":{"error":"element click intercepted","message":"element click intercepted: Element \u003Cdiv class=\"icon VEHICLE-icon\">\u003C/div> is not clickable at point (1465, 831)..."?  This is the output from the SciTE out-put pane.

I can provide screen shots of inspecting via ChroPath and SelectorsHub is need be.

 

[Danp2]

1 hour ago, Dmp said:

If WinActive("Visibility - Google Chrome","") Then

Not sure if this is part of your problem, but what happens when Chrome isn't the topmost window? This entire section of code will be skipped, right?

Quote

Can anyone explain what is meant by " __WD_Post ==> Element interaction issue: {"value":{"error":"element click intercepted","message":"element click intercepted: Element \u003Cdiv class=\"icon VEHICLE-icon\">\u003C/div> is not clickable at point (1465, 831)

Best guess would be that the element is partially hidden by another element. Are you sure that the Div element is the correct element to be clicked?

Quote

I've not be able to get either the xpath, or css Selector path to work consistently with $_WD_LOCATOR_ByXPath

I assume that you didn't actually try to use a CSS selector with $_WD_LOCATOR_ByXPath, correct? 😉

[mLipok]

 

2 hours ago, Dmp said:

div> is not clickable at point (1465, 831

1.
Headless mode ?

 

2.

Element can be hidden, inactive etc...
so try to use

_WD_WaitElement($sSession, $_WD_LOCATOR_ByXPath, "//div[@class='icon VEHICLE-icon']",Default,Default, BitOR($_WD_OPTION_Visible, $_WD_OPTION_Enabled))

instead

_WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//div[@class='icon VEHICLE-icon']")

 

Edited December 14, 2021 by mLipok

[Dmp]

Thank you both for your feedback... has been informative and helpful.

I removed the If WinActive condition for the Visibility page, but it did not appear to make a difference; still had the "element click intercepted","message..."

I did try CSS selector with $_WD_LOCATOR_ByXPath from SlectoresHub; the ChroPath values were of no use. Interestingly, both the SelectorsHub values end w/ "...div" undefined. I have attached an image of the output from inspecting the icon.

I implemented MPVs's  proposed: _WD_WaitElement and changed the order of the icons being clicked, which may have had something to do w/ Danp2's comment "Best guess would be that the element is partially hidden by another element."  As a result, the icon is now responding to the click action command.

I still feel that I need to take a more robust measure to address this issue; I'm wondering if my definition for  $sDesiredCapabilities is insufficient:

$sDesiredCapabilities = '{"capabilities": {"alwaysMatch": {"goog:chromeOptions": {"w3c": true, "args":["start-maximized","disable-infobars"], "excludeSwitches": [ "enable-automation"]}}}}'

I also tried:

sDesiredCapabilities = '{"capabilities": {"alwaysMatch": {"goog:chromeOptions": {"w3c": true, "excludeSwitches": [ "enable-automation"], "useAutomationExtension": false }}}}'

 

[Dmp]

[Danp2]

3 minutes ago, Dmp said:

I did try CSS selector with $_WD_LOCATOR_ByXPath

If you are using a CSS selector, then use $_WD_LOCATOR_ByCSSSelector instead of $_WD_LOCATOR_ByXPath.

FWIW, I doubt that changing your Capabilities string will help with this.

[mLipok]

2 hours ago, Danp2 said:

I doubt that changing your Capabilities string will help with this.

It may vary... it depends on browser and if he use Headless or not.
This is something similar that I ask you few days ago (maybe even few weeks ago).

@Dmp give it a try with this following SetupChrome function:

expandcollapse popup

Func _MY__WD_SetupChrome($b_Headless = False, $s_Download_dir = '', $_WD_DEBUG_LEVEL = Default, $s_Log_FileFullPath = Null)
    If $_WD_DEBUG_LEVEL = Default Then
        $_WD_DEBUG = $_WD_DEBUG_Error
        If Not @Compiled Then $_WD_DEBUG = $_WD_DEBUG_Info
    EndIf

    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)

    #  !!! WARRNING !!!   AS DEFAULT DO NOT USE '--log-path=' BECAUSE OF   GDPR / RODO law rules
    If $s_Log_FileFullPath = Default Then
        Local $s_Default_Log_File = @ScriptDir & '\Log\' & @YEAR & @MON & @MDAY & '-' & @HOUR & @MIN & @SEC & ' WebDriver - Chrome - Testing.log'
        _WD_Option('DriverParams', '--log-path=' & '"' & $s_Default_Log_File & '"')
    EndIf

    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch')
    _WD_CapabilitiesAdd('acceptInsecureCerts', True)

    _WD_CapabilitiesAdd('firstMatch', 'chrome')
    _WD_CapabilitiesAdd('browserName', 'chrome')
    _WD_CapabilitiesAdd('w3c', True)
    _WD_CapabilitiesAdd('args', 'user-data-dir', 'C:\Users\' & @UserName & '\AppData\Local\Google\Chrome\User Data\Default')
    _WD_CapabilitiesAdd('args', 'user-agent', 'Mozilla/5.0 (Windows NT 10.0; Win' & StringReplace(@OSArch, 'X', '') & '; ' & @CPUArch & ') AppleWebKit/537.36 (KHTML, like Gecko) Chrome/' & _WD_GetBrowserVersion('chrome') & ' Safari/537.36')
    _WD_CapabilitiesAdd('args', '--profile-directory', Default)
    _WD_CapabilitiesAdd('args', 'start-maximized')
    _WD_CapabilitiesAdd('args', 'disable-infobars')
    _WD_CapabilitiesAdd('args', '--no-sandbox')
    _WD_CapabilitiesAdd('args', '--disable-blink-features=AutomationControlled')
    _WD_CapabilitiesAdd('args', '--disable-web-security')
    _WD_CapabilitiesAdd('args', '--allow-running-insecure-content') ; https://stackoverflow.com/a/60409220
    _WD_CapabilitiesAdd('args', '--ignore-certificate-errors') ; https://stackoverflow.com/a/60409220
    If $b_Headless Then _
            _WD_CapabilitiesAdd('args', '--headless')
    If $s_Download_dir Then _
            _WD_CapabilitiesAdd('prefs', 'download.default_directory', $s_Download_dir)
    _WD_CapabilitiesAdd('excludeSwitches', 'disable-popup-blocking') ; https://help.applitools.com/hc/en-us/articles/360007189411--Chrome-is-being-controlled-by-automated-test-software-notification
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesAdd('excludeSwitches', 'load-extension')

    _WD_CapabilitiesDump(@ScriptLineNumber & ' TESTING')
    Local $s_Capabilities = _WD_CapabilitiesGet()

    Local $WD_SESSION = __MY__WD_Startup($s_Capabilities)
    Return SetError(@error, @extended, $WD_SESSION)
EndFunc   ;==>_MY__WD_SetupChrome

 

Edited December 15, 2021 by mLipok

[mLipok]

btw.
take a look also here:

It can be possible that you have an issue with ZOOM ratio, so try to use :
 

Func _WD_GetDevicePixelRatio($sSession)
    Local Const $sFuncName = "_WD_devicePixelRatio"
    Local $sResponse = _WD_ExecuteScript($sSession, "return window.devicePixelRatio", Default, Default)
    If @error <> $_WD_ERROR_Success Then _
            Return SetError(__WD_Error($sFuncName, $_WD_ERROR_Exception), "")

    Local $oJSON = Json_Decode($sResponse)
    Local $iResult = Json_Get($oJSON, "[value]")
    Return SetError($_WD_ERROR_Success, 0, $iResult)
EndFunc   ;==>_WD_GetDevicePixelRatio

if it is = 1 or not .

 

Edited December 18, 2021 by mLipok