chrome driver issue

[Champak]

I have a gui where sometimes I may want to see what is happening with the browser after an initial setup, so there is a checkbox to make the driver headless or not. Problem is I can't get it to work. I've tried a bunch of different things to change from showing the browser to headless.

I've tried calling the setup multiple times with and IF condition

If GUICtrlRead($gURLBrowser) = $GUI_CHECKED Then
                $sDesiredCapabilities = Call(SetupChrome(0))
            EndIf

Func SetupChrome($Headless = 1);Needed to generate the barcodes
    MsgBox(0,0,$Headless)
    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Option('DriverParams', '--verbose --log-path="' & @ScriptDir & '\chrome.log"')
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'chrome')
    _WD_CapabilitiesAdd('w3c', True)
    If $Headless = 1 Then _WD_CapabilitiesAdd('args', '--headless')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesDump(@ScriptLineNumber) ; dump current Capabilities setting to console - only for testing in this demo
    Local $sDesiredCapabilities = _WD_CapabilitiesGet()
    Return $sDesiredCapabilities
EndFunc   ;==>SetupChrome

 

I've tried the following capabilities adds together and separately before calling the browser

_WD_CapabilitiesAdd('--disable-extensions')
                _WD_CapabilitiesAdd('--disable-gpus')
                _WD_CapabilitiesAdd('--headless')
                _WD_CapabilitiesAdd('args', '')

                $sDesiredCapabilities = _WD_CapabilitiesGet()

 

Is what I'm trying to do possible? How?

 

 

[Danp2]

I'm not aware of the ability to change the browser visibility once it has been launched as "headless". However, you can control the visibility of the webdriver console using _WD_ConsoleVisible.

[mLipok]

When you wan to switch from headless to visible then you must close previous browser instance.

https://stackoverflow.com/q/49134440/5314940

 

[Danp2]

You could take a screenshot and display that instead. Would that work for you?

[Champak]

@Danp2, no I don't want to change from headless to displaying while the browser is launched. I want to change it after the $sDesiredCapabilities is set, but before the actual browser launch.

ex. 

Global $sDesiredCapabilities = Call(SetupChrome(1)); at the top of the script

then for a particular function:

_WD_Startup()

$sSession = _WD_CreateSession($sDesiredCapabilities)

......

    _WD_DeleteSession($sSession)
    _WD_Shutdown()

Then a different function starts that I may want to see the browser so

.....show the head

_WD_Startup()

$sSession = _WD_CreateSession($sDesiredCapabilities)

......

    _WD_DeleteSession($sSession)
    _WD_Shutdown()

I don't understand your second post.

@mLipokI don't have a previous browser launched. As it is, I've been testing it just by setting up the initial desired capabilities, and simply trying to change the headless before launching the browser for the first time to see if it would even work and it's not.

like

Global $sDesiredCapabilities = Call(SetupChrome(1))


$sDesiredCapabilities = Call(SetupChrome(0))

_WD_Startup()
$sSession = _WD_CreateSession($sDesiredCapabilities)

...do some stuff

_WD_DeleteSession($sSession)
_WD_Shutdown()

Func SetupChrome($Headless = 1);Needed to generate the barcodes
    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Option('DriverParams', '--verbose --log-path="' & @ScriptDir & '\chrome.log"')
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'chrome')
    _WD_CapabilitiesAdd('w3c', True)
    If $Headless = 1 Then _WD_CapabilitiesAdd('args', '--headless')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesDump(@ScriptLineNumber) ; dump current Capabilities setting to console - only for testing in this demo
    Local $sDesiredCapabilities = _WD_CapabilitiesGet()
    Return $sDesiredCapabilities
EndFunc   ;==>SetupChrome

So when you say close the previous browser instance, it isn't a factor.

 

 

 

[Danp2]

It works as I would expect after eliminating the use of Call(). Run the following and post the results --

#include "wd_helper.au3"
#include "wd_capabilities.au3"

Global $sDesiredCapabilities = SetupChrome(1)
;### Debug CONSOLE ↓↓↓
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sDesiredCapabilities = ' & $sDesiredCapabilities & @CRLF & '>Error code: ' & @error & @CRLF)


$sDesiredCapabilities = SetupChrome(0)
;### Debug CONSOLE ↓↓↓
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $sDesiredCapabilities = ' & $sDesiredCapabilities & @CRLF & '>Error code: ' & @error & @CRLF)


Func SetupChrome($Headless = 1);Needed to generate the barcodes
    _WD_Option('Driver', 'chromedriver.exe')
    _WD_Option('Port', 9515)
    _WD_Option('DriverParams', '--verbose --log-path="' & @ScriptDir & '\chrome.log"')
    _WD_CapabilitiesStartup()
    _WD_CapabilitiesAdd('alwaysMatch', 'chrome')
    _WD_CapabilitiesAdd('w3c', True)
    If $Headless = 1 Then _WD_CapabilitiesAdd('args', '--headless')
    _WD_CapabilitiesAdd('excludeSwitches', 'enable-automation')
    _WD_CapabilitiesDump(@ScriptLineNumber) ; dump current Capabilities setting to console - only for testing in this demo
    Local $sDesiredCapabilities = _WD_CapabilitiesGet()
    Return $sDesiredCapabilities
EndFunc   ;==>SetupChrome

 

[Champak]

That worked, thanks.