"OrdoWebView2.ocx" WebView2 made simple

[Gianni]

IMPORTANT! Scripts changed! See P.S. 2 below for script-breaking changes.

Although I think the best way to use WebView2 in AutoIt would be to complete and use the work started by @LarsJ in this other @mLipok's topic, now it is possible to use WebView2 in AutoIt in a much simpler way.

This is possible thanks to this ocx control and thanks to @Danyfirex for his decisive contribution.

Now we can easily start embedding one or more WebView2 controls in our GUI in AutoIt. What we need is: the OrdoWebView2.ocx control and the \OrdoRC6 folder. These two are installed together with other programs (in the C:\Program Files (x86)\OrdoWebView2Control folder) by running the OrdoWebView2ActiveXControl.2.0.9.exe program downloadable from this link: https://freeware.ordoconcept.net/OrdoWebview2.php by clicking on "Download OrdoWebView2 SDK" at the bottom of the screen.

Or, more simply, you can find them directly attached to this post by @Danyfirex.

As explained in this post on VBForums (https://www.vbforums.com/showthread.php?899415-OrdoWebview2-ActiveX-WebView2-Browser-Control-(Replacement-of-the-MS-browser-control)&p=5651133&viewfull=1#post5651133):

"On the latest versions of Windows 10 and Windows 11, only the following components are needed:

• OrdoWebView2.ocx
• OrdoRC6 folder and its contents, in the same directory as OrdoWebView2.ocx
• Finally, you need to register OrdoWebView2.ocx by following these three steps:

1. Open a DOS prompt with administrative rights
2. Navigate to the folder containing the OrdoWebView2.ocx file
3. Type and execute the following command: regsvr32.exe OrdoWebView2.ocx

Also:

• Our AutoIt script and the OrdoWebView2.au3 must also be in the same directory along with the above.

I have extracted the essential parts needed to create the WebView2 object from the DanyFirex's original example and grouped them into the OrdoWebView2.au3 UDF so that it can be easily included into a program. This is just a quick draft to get you started, but it can definitely be improved. Suggestions are welcome.

Here are the basic UDF and a very basic example script: Embed 4 WebView2 controls in an AutoIt GUI

More scripts to follow to test the functionality and interaction between OrdoWebView2 and AutoIt. See you later.

P.S.

Here is a reference link to the OrdoWebView2.ocx help (https://freeware.ordoconcept.net/Help/OrdoWebView2/)

P.S. 2

I've modified the listings slightly:

• Renamed the webview2_GUI_Create function to _OrdoWebView2_GUI_Create
• This function now returns an Object variable pointing to the OrdoWebView2 control (previously it returned an array with 2 elements. The first element was the control's object variable and the second element was the handle to the window containing it).
• Added _OrdoWebView2_DisposeAll function to delete all OrdoWebView2 controls created with the previous function which should be used before exiting the program.
• I've updated the examples with the new function names.

I'd like to try creating a function that checks whether OrdoWebView2.ocx is already registered and, if not, registers itself (or something similar). Suggestions are welcome

OrdoWebView2.au3

expandcollapse popup

; From the following POST By DanyFirex:
; https://www.autoitscript.com/forum/topic/204362-microsoft-edge-webview2-embed-web-code-in-your-native-application/page/9/#findComment-1542694

; ... first draft to be continue ...
#include <WindowsStylesConstants.au3>
#include <WinAPI.au3>
; #include <WinAPISysWin.au3>

Global Const $gATL = DllOpen("ATL.DLL")
Global Const $gOleaut32 = DllOpen("oleaut32.dll")
_WinAPI_CoInitialize($COINIT_APARTMENTTHREADED)

AtlAxWinInit()

Global $pProgID = SysAllocString('OrdoWebView2.OrdoWebView')

Func _OrdoWebview2_GUI_Create($w, $h, $x, $y, $hMain, _
        $sEventsPrefix = '', _ ; ......................... The prefix of the functions you define to handle receiving events. The prefix is appended by the Objects event name.
        $sLang = "", _ ; ................................. Language defined by the 2-letter code from ISO 639. If omitted, the chosen language will be that of the user's system.
        $bIsPrivateNavigation = False, _ ; ............... if TRUE the browser goes into private browsing mode. Default value is False
        $sBrowserInstallPath = "", _ ; ................... sets the installation directory of the WebView2 fixed version. Only considered if UseEdgeFixedVersion is TRUE.
        $sUserDataFolder = "", _ ; ....................... defines the user's browsing data directory. If empty, use default user assignment directory. Ignored if IsPrivateNavigation is true
        $sAdditionalBrowserArguments = "", _ ; ........... Allows passing parameters to the Chromium WebView2 browser through command line switches. You can find a list of Chromium Command Line Switches here
        $iAllowSingleSignOnUsingOSPrimaryAccount = 0) ; .. Determines whether to enable single sign on with Azure Active Directory

    Local $hGUI_1 = GUICreate('', $w, $h, $x, $y, $WS_POPUPWINDOW) ; BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
    Local $hResult = AtlAxCreateControl($pProgID, $hGUI_1)
    ; _SysFreeString($pProgID)
    Local $pIUnkown = AtlAxGetControl($hGUI_1)
    ; ConsoleWrite("AtlAxGetControl: " & $pIUnkown & @CRLF)
    _WinAPI_SetParent($hGUI_1, $hMain) ; trap this child gui within the main gui
    GUISetState(@SW_SHOW, $hGUI_1)

    Local $oOrdoWebView2 = ObjCreateInterface($pIUnkown, "{E54909AA-1705-44A9-8235-B24F74366B3F}")
    Local $oOrdoWebViewEvents = ObjEvent($oOrdoWebView2, $sEventsPrefix, "__OrdoWebView")
    ; ConsoleWrite("$oOrdoWebView2: " & IsObj($oOrdoWebView2) & @CRLF)
    ; ConsoleWrite($oOrdoWebView2.GetWebView2Version() & @CRLF)
    ; ConsoleWrite($oOrdoWebView2.GetMostRecentInstallPath() & @CRLF)
    #cs
    $oOrdoWebView2.Anchor = True
    $oOrdoWebView2.Search_URL = "https://search.yahoo.com/search?p=%1"
    $oOrdoWebView2.HomeURL = "http://www.google.com"
    $oOrdoWebView2.SearchEngine = 2
    $oOrdoWebView2.SearchAuto = True
    #ce

    $oOrdoWebView2.UseEdgeFixedVersion = False
    $oOrdoWebView2.InitEx($sLang, $bIsPrivateNavigation, $sBrowserInstallPath, $sUserDataFolder, $sAdditionalBrowserArguments, $iAllowSingleSignOnUsingOSPrimaryAccount)

    While Not $oOrdoWebView2.IsWebViewInit() ;wait initialization otherwise Navigate will fail
        Sleep(100)
    WEnd

    ; Local $aReturn = [$oOrdoWebView2, $hGUI_1]
    ; Return $aReturn ; $oOrdoWebView2

    __KeepTrack($hGUI_1)

    Return $oOrdoWebView2

EndFunc   ;==>_OrdoWebview2_GUI_Create

Func AtlAxCreateControl($pProgID, $HWND)
    Local $aCall = DllCall($gATL, "long", "AtlAxCreateControl", "ptr", $pProgID, "handle", $HWND, "ptr", 0, "ptr", 0)
    If @error Then Return SetError(1, 0, -1)
    Return $aCall[0]
EndFunc   ;==>AtlAxCreateControl

Func AtlAxGetControl($HWND)
    Local $aCall = DllCall($gATL, "long", "AtlAxGetControl", "handle", $HWND, "ptr*", 0)
    If @error Then Return SetError(1, 0, -1)
    Return $aCall[2]
EndFunc   ;==>AtlAxGetControl

Func AtlAxWinInit()
    Local $aCall = DllCall($gATL, "bool", "AtlAxWinInit")
    If @error Then Return SetError(1, 0, -1)
    Return $aCall[0]
EndFunc   ;==>AtlAxWinInit

Func _SysFreeString($pBSTR)
    ; Author: Prog@ndy
    If Not $pBSTR Then Return SetError(2, 0, 0)
    DllCall($gOleaut32, "none", "SysFreeString", "ptr", $pBSTR)
    If @error Then Return SetError(1, 0, 0)
EndFunc   ;==>_SysFreeString

Func SysAllocString($str)
    ; Author: monoceres
    Local $aCall = DllCall($gOleaut32, "ptr", "SysAllocString", "wstr", $str)
    If @error Then Return SetError(1, 0, 0)
    Return $aCall[0]
EndFunc   ;==>SysAllocString


; Delete all Windows containing OrdoWebView2 controls created by _OrdoWebview2_GUI_Create()
Func _OrdoWebView2_DisposeAll()
    __KeepTrack(0, False)
    _SysFreeString($pProgID)
EndFunc   ;==>_OrdoWebView2_DisposeAll

Func __KeepTrack($hWinHandle, $bRetain = True)
    Static Local $aStack[1] = [0]
    If $bRetain Then
        ReDim $aStack[UBound($aStack) + 1]
        $aStack[0] += 1
        $aStack[$aStack[0]] = $hWinHandle
    Else
        For $i = $aStack[0] To 1 Step -1
            GUIDelete($aStack[$i])  ; _WinAPI_DestroyWindow ( $aStack[$i] ) ; Deletes a GUI window and all controls that it contains.
        Next
    EndIf
EndFunc   ;==>__KeepTrack

; this function can be used to get the WinHandle of the window embedding an OrdoWebView2 control
; you can get the PID of the OrdoWebView2 control by reading the BrowserProcessId Property
Func _HWnd_FromPID($PID)
    Local $WinList = WinList()
    For $i = 1 To $WinList[0][0]
        If WinGetProcess($WinList[$i][1]) = $PID Then
            Return HWnd($WinList[$i][1])
        EndIf
    Next
    Return SetError(1, 0, 0)
EndFunc   ;==>_HWnd_FromPID

OrdoWebView2_Demo.au3

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "OrdoWebView2.au3"

Global $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
Global $oWebView1, $oWebView2, $oWebView3, $oWebView4

_TestOrdoWebView()

Func _TestOrdoWebView()
    Local $hMain_GUI = GUICreate("Main GUI", 990, 810, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
    GUISetState(@SW_SHOW, $hMain_GUI)
    Local $hAutoIt_Button_1 = GUICtrlCreateButton("test", 10, 785)

    ; Create 4 WebView2 controls
    $oWebView1 = _OrdoWebview2_GUI_Create(480, 380, 10, 10, $hMain_GUI)
    $oWebView2 = _OrdoWebview2_GUI_Create(480, 380, 500, 10, $hMain_GUI)
    $oWebView3 = _OrdoWebview2_GUI_Create(480, 380, 10, 400, $hMain_GUI)
    $oWebView4 = _OrdoWebview2_GUI_Create(480, 380, 500, 400, $hMain_GUI)

    ; Following JavaScript function attempts to prevent clicked links from opening in a new window.
    ; Instead, they are displayed in the current window.
    ; However, some JavaScript functions can still force the page to open in a new window (sorry).
    ; To make it work, it must be injected into the created WebView controls
    ; and this is done using the "AddScriptToExecuteOnDocumentCreated" method.
    Local $JsCode = "document.addEventListener('click', function(e) {" & _
            "let target = e.target;" & _
            "while (target && target.tagName !== 'A') target = target.parentElement;" & _
            "if (target && target.target === '_blank') {" & _
            "    e.preventDefault();" & _
            "    window.location.href = target.href;" & _
            "}" & _
            "}, true);"

    ; Inject the above JavaScript code into the four created controls.
    $oWebView1.AddScriptToExecuteOnDocumentCreated($JsCode)
    $oWebView2.AddScriptToExecuteOnDocumentCreated($JsCode)
    $oWebView3.AddScriptToExecuteOnDocumentCreated($JsCode)
    $oWebView4.AddScriptToExecuteOnDocumentCreated($JsCode)

    ; Navigate to web pages for each browser
    $oWebView1.Navigate("https://www.kevs3d.co.uk/dev/js1kdragons/") ; "https://www.youtube.com/watch?v=-3fcwda1U8k"))
    $oWebView2.Navigate("https://gridstackjs.com/demo/anijs.html") ; "https://retejs.org/")
    $oWebView3.Navigate("https://www.youtube.com/watch?v=ojBYW3ycVTE")
    $oWebView4.Navigate("https://freeware.ordoconcept.net/OrdoWebview2.php") ; "https://freeware.ordoconcept.net/Help/OrdoWebView2/"

    ; Main loop
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $hAutoIt_Button_1 ; just a test
                MsgBox(0, 'AutoIt', 'Hi')
        EndSwitch
    WEnd

    ; End of main loop, clear everything before exiting.
    ; Deletes all embedded windows and all
    ; OrdoWebView2 controls that those contains.
    _OrdoWebView2_DisposeAll()

    GUIDelete($hMain_GUI) ; Delete main GUI

EndFunc   ;==>_TestOrdoWebView

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

 

Edited October 21 by Gianni
script-breaking changes

[SOLVE-SMART]

Thanks @Gianni 👌 for you pretty good summary of the topic, the findings and the links.
I didn't test it yet, but I will definitely.

💡 One little (but important) hint:
Please be aware of the license of the ActiveX OrdoWebView2 Control. It's not a big deal, because it's very open and friendly regarding reusability. But still, keep in mind the licenses of third-party tools (as always).

Best regards
Sven

Edited April 25 by SOLVE-SMART

[Nine]

Thanks for sharing.  I tried to register the ocx but I am getting the following error :

Any idea ?  NVM, you need to run it as admin.  That's all.

ps. works great !

Edited April 25 by Nine

[SOLVE-SMART]

Sadly I get this error:

#cs
main.au3 (34) : ==> COM Error intercepted !
    err.number is:      0x00000001
    err.windescription: Failed to create object
    err.description is:     
    err.source is:      
    err.helpfile is:    
    err.helpcontext is:     
    err.lastdllerror is:    0
    err.scriptline is:  34
    err.retcode is:     0x00000000
#ce

; line 34 is:
Local $oOrdoWebView2 = ObjCreateInterface($pIUnkown, "{E54909AA-1705-44A9-8235-B24F74366B3F}")

I checked my registry for that "E54909AA-1705-44A9-8235-B24F74366B3F" IID (CLSID), but no such entry available 😔 .
I used .\OrdoWebView\OrdoRC6\RegisterRC6inPlace.vbs and .\OrdoWebView\OrdoRC6\RegisterRC6WidgetsInPlace.vbs (from the 7z archive of Danyfirex's post) to register the RC6*.dll's. I did not register .\OrdoWebView\OrdoWebView2.ocx and startet the OrdoWebView2_Demo.au3 (which is called main.au3 in my case).

👉 I use x64 Win10 (latest version, german system) and AutoIt v3.3.16.1.

Several errors appear in the console output, starting with the one above.
When I try to register the *.ocx file by regsvr32 C:\...\OrdoWebView\OrdoWebView2.ocx I get an access denied hint. I run the cmd.exe as admin, but still access denied.

I really do not want to install OrdoWebView2 SDK (OrdoWebView2ActiveXControl.2.0.9.exe), but maybe I have to?

Any suggestions are welcome - thanks.

Best regards
Sven

Edited April 25 by SOLVE-SMART

[Nine]

Idk if this will make any difference, but when I registered the ocx I was inside the folder where it was located (instead of entering the full path).

ps. i did not install the SDK.  Just the .7z of Dany

pps. you need to run it x86, it does not work x64

Edited April 25 by Nine

[SOLVE-SMART]

13 minutes ago, Nine said:

Idk if this will make any difference, but when I registered the ocx I was inside the folder where it was located (instead of entering the full path).

It is a difference - it works 😆 .
Thank you @Nine. I don't get it why it works in that way, but now I can see the four WebView instances in the AutoIt GUI.

Now I can start with some experiments 🎉 .

Best regards
Sven

[SOLVE-SMART]

Did you @Nine run the *.vbs scripts in the .\OrdoWebView\OrdoRC6 folder? Are they needed to be executed?
 

[Nine]

Nope, followed the instructions from @Gianni to the letter... 

[Gianni]

Indeed, no need to register anything other than OrdoWebView2.ocx
You just need a folder containing the files as shown in the figure below

\MYFOLDER
    |   OrdoWebView2.ocx
    |   OrdoWebView2.au3
    |   OrdoWebView2_Demo.au3
    |
    \---OrdoRC6
            cairo_sqlite.dll
            DirectCOM.dll
            RC6.dll
            RC6Widgets.dll
            RegisterRC6inPlace.vbs
            RegisterRC6WidgetsInPlace.vbs
            WebView2Loader.dll
           _Library-Licenses.txt
           _Version-History.txt

(You can find the necessary files in the 7z file in @Danyfirex's post as indicated in first post above)

As @Ninedid, I also did the following:

• created a folder containing necessary files as above
• opened a DOS prompt with administrative rights;
• placed the current directory where the OrdoWebView2.ocx file is located
• I typed the following command:   regsvr32 .\OrdoWebView2.ocx
• I received the popup message with the message "DllRegisterServer in .\OrdoWebView2.ocx succeeded"
• That's it,

then running the OrdoWebView2_Demo.au3 file everything worked fine

thanks all for the feedbacks

Edited April 25 by Gianni

[SOLVE-SMART]

Okay fine, nice.

Now the Events are interesting (for me). Especially "JSAsyncResult", like you already wrote in the VB forum @Gianni.
It should be possibile to interact with html elements based on JS events/interactions/modifications, am I right?

This will be really nice, because I would not need a AutoIt WebServer anymore to have nice looking UIs with a AutoIt backend 😀 .

Best regards
Sven

[SOLVE-SMART]

Everytime I would use OrdoWebView in a different project (folder) with different name, I have to regsvr32 .\OrdoWebView2.ocx from the cmd.exe (as admin) again. This is quite annoying. I guess I will make a init routine to do this automatically in case the path is not registered yet.

----------------------

I realized that not all files in OrdoRC6 are necessary (at least not right now for the demo).
My folder structure (template) looks like this at the moment.

Spoiler

autoit-webview
|   .gitignore
|   .prettierrc.json
|   LICENSE.md
|   package.json
|   README.md
|
+---build
|       .gitkeep
|
+---lib
|   |   draft-udf.au3 (previously OrdoWebView2_Demo.au3)
|   |
|   \---OrdoWebView2
|       |   license.md
|       |   OrdoWebView2.ocx
|       |
|       \---OrdoRC6
|               cairo_sqlite.dll
|               DirectCOM.dll
|               RC6.dll
|               third-party-licenses.md
|               WebView2Loader.dll
|
\---src
    |   main.au3
    |
    +---handler
    |       .gitkeep
    |
    +---maps
    |       .gitkeep
    |
    \---utils
            .gitkeep

 

Btw: Ignore the ".gitkeep" files.

----------------------

Anyhow, I am curious how far we as community can and will go with OrdoWebView2 😀 .

Best regards
Sven

Edited April 25 by SOLVE-SMART

[Nine]

Maybe remove .\  As far as I tested it, I can use the ocx everywhere like this :

#include <WindowsConstants.au3>
#include "..\OrdoWebView\OrdoWebView2.au3"

Works everywhere, even on full path...

[Gianni]

A first attempt at interaction between AutoIt and OrdoWebView2
it seems to me that some small anomalies occur (but maybe it's me who doesn't use them correctly), such as: the value of an AutoIt variable set by reading the value of a property of a browser object is not immediately available in AutoIt, but delays must be inserted before reading its value.
However, I have set 3 callback functions related to the following events: "navigation completed"; "zoom change" and "asynchronous JS result".
In particular, this last event should be executed only if you use the execution of a javascript script using the RunJsAsync() method. well, although I have not used that method in the AutoIt script but have only used the RunJs() method, I see that the JSAsyncResult callback function is occasionally executed anyway (?).
Well, this test script uses a web page that contains a "label" where the text changes to "I'm not a robot" only when the three red cubes have been clicked. (You could use this as a sort of graphical "CAPTCHA"). You can rotate the cube by dragging with the mouse so that any red cubes that are "on the back" come to the forefront so that you can click them.
The interaction with AutoIt consists of reading the value of that JS field to check when it changes to "I'm not a robot" and acting accordingly in AutoIt.
It seems to work, but I think I still need to dig deeper into this functionality.
The zoom change event is executed when the browser zoom is changed. To change the zoom you can hold down the "ctrl" key on the keyboard and simultaneously rotate the mouse wheel up or down. To reset the zoom to 100% press "ctrl" and zero on the numpad.
Here is the "experiment".

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "OrdoWebView2.au3"

Global $bReloaded = False ; to be used in NavigationCompleted callback function

_TestOrdoWebView()

Func _TestOrdoWebView()

    Local $hMain_GUI = GUICreate("Main GUI", 500, 520, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS, $WS_CLIPCHILDREN))
    Local $hButton1 = GUICtrlCreateButton("I give up", 10, 495, 480, 20)

    GUISetState(@SW_SHOW, $hMain_GUI)

    Local $oEBWebView1 = _OrdoWebView2_GUI_Create(480, 480, 10, 10, $hMain_GUI, "_OrdoWebView_") ; 6° parameter: Events Callback funcion name prefix

    ; a javascript function to be injected in Document for a later use from AutoIt via .RunJs or .RunJsAsync
    $oEBWebView1.AddScriptToExecuteOnDocumentCreated("function getQSValue(qsExpr){return document.getElementById((qsExpr)).innerHTML}")
    ; Load web page
    $oEBWebView1.Navigate("https://shzlw.github.io/design/I-am-not-a-robot.html")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $hButton1
                MsgBox(0, 'AutoIt', "Test failed. Goodbye")
                ExitLoop
        EndSwitch

        If $oEBWebView1.RunJs("getQSValue", "label") = "I'm not a robot" Then
            MsgBox(0, 'AutoIt', "Great! You are not a robot. Welcome human!")
            $oEBWebView1.Reload

            Do
                ConsoleWrite('.')
            Until $bReloaded
            $bReloaded = False
            ; if there is not this MsgBox to produce a long delay sometimes the reload is executed twice
            MsgBox(0, 'AutoIt', "Play again")
        EndIf

    WEnd
    _ordoWebView2_DisposeAll()
    GUIDelete($hMain_GUI)
EndFunc   ;==>_TestOrdoWebView

; --- CallBack functions ---
Volatile Func _OrdoWebView_NavigationCompleted($IsSuccess, $WebErrorStatus)
    ConsoleWrite("_OrdoWebView_NavigationCompleted" & @CRLF)
    $bReloaded = True
EndFunc   ;==>_OrdoWebView_NavigationCompleted

Volatile Func _OrdoWebView_ZoomChanged($iValue)
    ConsoleWrite("New Zoom Value is : " & $iValue & @CRLF)
    TrayTip("Zoom changed", "New zoom value is: " & $iValue, 3, 17)
EndFunc   ;==>_OrdoWebView_ZoomChanged

Volatile Func _OrdoWebView_JSAsyncResult($vResult, $vToken, $sErrString)
    ConsoleWrite("Javascript result: " & $vResult & @CRLF & $vToken & @CRLF & $sErrString & @CRLF)
EndFunc   ;==>_OrdoWebView_JSAsyncResult

 

Edited October 21 by Gianni

[mcgrews3]

Quick note to folks that this is 32-bit and if running 64-bit AutoIt then it won't work.  Any chance we can get an x64 version of this for use in x64 context?

[argumentum]

11 minutes ago, mcgrews3 said:

Quick note to folks that this is 32-bit and if running 64-bit AutoIt then it won't work.  Any chance we can get an x64 version of this for use in x64 context?

"OrdoWebview2 is an ActiveX control (32bits ocx) developed to replace the aging VB6 webview control based on a deprecated Internet Explorer !"
You'd have to take the complain to the coder of the OCX 🤷‍♂️

[Parsix]

how to prevent open link in new window ?

[Gianni]

On 10/18/2025 at 10:10 PM, Parsix said:

how to prevent open link in new window ?

Browser behavior is determined by the web page's source (html and javascript).
For example, if the target="_blank" attribute is specified in an HTML <A> anchor tag, the link to which it points opens in a new window.
Therefore, to change the page's behavior, it would be necessary to modify the page's source.
However, it is possible to use a javascript function to intercept clicks on the <A> tag and modify its default behavior, forcing the new page to open in the same window instead of a new one.
To do this, you need to inject the javascript function into the web page, for example, using the ".AddScriptToExecuteOnDocumentCreated" method.
I modified the example script in the first post, which now also includes the above.
I found the JavaScript snippet used on the web and it attempts to prevent clicked links from opening in a new window (it can probably be improved). Instead, they are displayed in the current window.
However, some JavaScript functions can still force the page to open in a new window (sorry).
As mentioned, for this to work, it must be injected into the created OrdoWebView2 controls, and this is done using the "AddScriptToExecuteOnDocumentCreated" method.
See the example in the first post

P.S. (since I also modified OrdoWebView2.au3 in the first post, you must use that new file as well).

I hope this helps.