WebView2AutoIt - AutoIt WebView2 Component (COM Interop)

[bladem2003]

To get the extension manager working, I need the 32-character string.
This string is created in the profile folder after installation, but I need to name the folder accordingly.
How can I calculate this string? Or do I need to rename the folder afterward?

[ioa747]

@bladem2003
in the latest version I have the example WebDemo_v1.4.au3,
which together with _WV2_ExtensionPicker.au3, manages the extensions
I have also updated the related 🧩 How-To Using Extensions in NetWebView2.md, with additional information

Take a look, see how I managed it.

It takes its name from the extension library, which I have named with the format
name_32characterID
Extensions_Lib\DarkReader_eimadpbcbfnmbkopoojfekhnkhdbieeh

Edited January 5 by ioa747

[ioa747]

New Version (1.4.2) has arrived
I updated the first post     

 

🛠️ Migration Note (Important)

Due to changes in the COM Dispatch IDs (DispIds) for better organization, it is  highly recommended  to run the included  RegCleaner.au3  before registering the new version. This ensures that any stale registry entries from previous builds are purged, preventing "Object action failed" errors.

 

[WildByDesign]

This is truly a thing of beauty and magic. Fantastic work with the COM Bridge in C#. This whole project is really coming together so incredibly well. 

Especially with the recent addition of being able to supply a custom user directory. That feature was really important for my usage.

Keep up the great work. You've got so much creativity and ideas.

[mLipok]

A few years ago, when I started switching from IE and MOZ REPL to WebDriver, I decided to create something like BROWSER.au3 - an universal set of function which should help you switching between automation of different web browsing technologies without any effort 

 

I hope to share it soon.

Soon, I mean, first I need to learn how to use the:

$oManager = ObjCreate("NetWebView2.Manager")

in conjunction with my BROWSER.au3.

However, this mean that I plan to create MSEdgeManager_helper.au3 and upload it to:  https://github.com/ioa747/NetWebView2Lib

I'm referring to a UDF with the standard _IE* and _WD_* equivalents.
But that will have to wait until February.

Edited January 6 by mLipok

[mLipok]

Is it possible to use stuff like:

https://gojs.net/latest/download.html
 

to display diagrams in AutoIt GUI of cours with this component ?

or
https://github.com/summerstyle/jsonTreeViewer/blob/master/jsonTreeViewer.js
example:
https://summerstyle.github.io/jsonTreeViewer/
to display formated and colored JSON structure ?


XML is simple:

 

PDF the same:

 

 

I just thinking about UNIVERSAL FILE VIEWER

 

Edited Friday at 10:46 PM by mLipok

[ioa747]

   I'm trying to fit them into my head.    

I made a new example.
https://github.com/ioa747/NetWebView2Lib/tree/main/examples/v1.4.2_jsonTree

 

[mLipok]

This looks awesome.
BIG THANKS

[mLipok]

I did test in 1-BasicDemo.au3

and just wondering why this ActiveX component work with

#AutoIt3Wrapper_UseX64=y

but also with:

#AutoIt3Wrapper_UseX64=n

Until now I thought that the ActiveX component had to be recompiled separately for both architectures as separate DLL files.

Did I miss something ?

Edited 5 hours ago by mLipok

[mLipok]

please take a look on the draft PR

https://github.com/ioa747/NetWebView2Lib/pull/8

 

[ioa747]

3 hours ago, mLipok said:

Until now I thought that the ActiveX component had to be recompiled separately for both architectures as separate DLL files.

To solve the mystery: The main assembly NetWebView2Lib.dll is indeed compiled as 'Any CPU', which allows it to be loaded by both 32-bit and 64-bit processes.

However, for it to work in both modes, two things happen behind the scenes:

Dual Registration: My registration script runs RegAsm.exe from both the Framework (x86) and Framework64 (x64) directories. This creates the necessary COM entries in both registry hives so that AutoIt can 'see' the object regardless of the architecture.

Native Dependencies: The WebView2 component relies on a native binary called WebView2Loader.dll. If you check the runtimes folder in the distribution, you will see separate folders for win-x64 and win-x86. At runtime, the .NET Interop layer automatically detects the architecture of the calling process (your AutoIt script) and loads the matching native loader.

So, by doing a Batch Build and providing the full runtimes structure, I've ensured that the component is 'architecture-aware' even though you only see one main DLL.
 

Spoiler

NETWEBVIEW2LIB\BIN
│   Microsoft.Web.WebView2.Core.dll
│   Microsoft.Web.WebView2.WinForms.dll
│   Microsoft.Web.WebView2.Wpf.dll
│   NetWebView2Lib.dll
│   NetWebView2Lib.tlb
│   Newtonsoft.Json.dll
│   RegCleaner.au3
│   Register_web2.au3
│   Unregister.au3
│   
└───runtimes
    ├───win-x64
    │   └───native
    │           WebView2Loader.dll
    │           
    └───win-x86
        └───native
                WebView2Loader.dll

Register_web2.au3
 

Spoiler

expandcollapse popup

#RequireAdmin
#include <MsgBoxConstants.au3>
;~ Register_web2.au3

; === Configuration ===
Local $sDllName = "NetWebView2Lib.dll"
Local $sNet4_x86 = "C:\Windows\Microsoft.NET\Framework\v4.0.30319\RegAsm.exe"
Local $sNet4_x64 = "C:\Windows\Microsoft.NET\Framework64\v4.0.30319\RegAsm.exe"

Local $bSuccess = False
Local $sLog = "Registration Report:" & @CRLF & "--------------------" & @CRLF

; === Check for WebView2 Runtime ===
Local $sWV2Version = WebView2Exist()

If $sWV2Version <> "" Then
    $sLog &= "[+] WebView2 Runtime: Found (" & $sWV2Version & ")" & @CRLF
Else
    Local $sUrl = "https://go.microsoft.com/fwlink/p/?LinkId=2124703"
    $sLog &= "[-] WebView2 Runtime: NOT FOUND" & @CRLF

    ; Ask the user to install
    Local $iAnswer = MsgBox($MB_YESNO + $MB_ICONEXCLAMATION, "Runtime Missing", _
        "The Microsoft Edge WebView2 Runtime is required to run this application." & @CRLF & @CRLF & _
        "Would you like to open the download page now?" & @CRLF & @CRLF & _
        "Note: Please return and click YES after the installation is complete.")

    If $iAnswer = $IDYES Then
        ShellExecute($sUrl)
        ; Wait for user confirmation that installation is done
        MsgBox($MB_ICONINFORMATION, "Waiting", "Click OK once the WebView2 installation is finished to proceed with DLL registration.")
    Else
        $sLog &= "[!] User skipped WebView2 installation. Aborting." & @CRLF
        MsgBox($MB_ICONSTOP, "Aborted", "Registration cannot continue without WebView2 Runtime.")
        Exit ; Stop the script
    EndIf
EndIf

; === Registration 'NetWebView2Lib.dll' COM ===

; Registration for x86 (32-bit)
If FileExists($sNet4_x86) Then
    Local $iExitCode = RunWait('"' & $sNet4_x86 & '" "' & @ScriptDir & '\' & $sDllName & '" /codebase /tlb', @ScriptDir, @SW_HIDE)
    If $iExitCode = 0 Then
        $sLog &= "[+] x86 Registration: SUCCESS" & @CRLF
        $bSuccess = True
    Else
        $sLog &= "[-] x86 Registration: FAILED (Code: " & $iExitCode & ")" & @CRLF
    EndIf
Else
    $sLog &= "[!] x86 RegAsm not found" & @CRLF
EndIf

; Registration for x64 (64-bit)
If FileExists($sNet4_x64) Then
    Local $iExitCode = RunWait('"' & $sNet4_x64 & '" "' & @ScriptDir & '\' & $sDllName & '" /codebase /tlb', @ScriptDir, @SW_HIDE)
    If $iExitCode = 0 Then
        $sLog &= "[+] x64 Registration: SUCCESS" & @CRLF
        $bSuccess = True
    Else
        $sLog &= "[-] x64 Registration: FAILED (Code: " & $iExitCode & ")" & @CRLF
    EndIf
Else
    $sLog &= "[!] x64 RegAsm not found" & @CRLF
EndIf

; === Final Message ===
If $bSuccess Then
    MsgBox($MB_ICONINFORMATION, "Registration Complete", $sLog)
Else
    MsgBox($MB_ICONERROR, "Registration Error", "Library registration failed." & @CRLF & @CRLF & $sLog)
EndIf
;---------------------------------------------------------------------------------------
Func WebView2Exist()
    Local $aKeys[3] = [ _
        "HKLM\SOFTWARE\Microsoft\EdgeUpdate\Clients", _
        "HKLM\SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate\Clients", _
        "HKEY_CURRENT_USER\Software\Microsoft\EdgeUpdate\Clients" _
    ]
    Local $sSubKey, $sName, $sPv, $iIndex

    For $sRootKey In $aKeys
        For $iIndex = 1 To 500
            $sSubKey = RegEnumKey($sRootKey, $iIndex)
            If @error Then ExitLoop ; No more keys
            $sName = RegRead($sRootKey & "\" & $sSubKey, "name")
            If $sName = "Microsoft Edge WebView2 Runtime" Then
                $sPv = RegRead($sRootKey & "\" & $sSubKey, "pv")
                If $sPv <> "" Then Return $sPv ; Found it
            EndIf
        Next
    Next

    Local $sSysPathX86 = @WindowsDir & "\System32\Microsoft-Edge-WebView\EBWebView\x86\EmbeddedBrowserWebView.dll"
    Local $sSysPathX64 = @WindowsDir & "\System32\Microsoft-Edge-WebView\EBWebView\x64\EmbeddedBrowserWebView.dll"

    If FileExists($sSysPathX86) Or FileExists($sSysPathX64) Then
        Return "Detected via System Files"
    EndIf

    Return "" ; Not found
EndFunc
;---------------------------------------------------------------------------------------