WebView2AutoIt - AutoIt WebView2 Component (COM Interop)

ioa747 · March 25

On 3/22/2026 at 4:55 PM, argumentum said:

..scaling 175%

I managed it as (-4 = Per Monitor V2)

argumentum · March 25

...
$g_iSetWidth = Default
$g_iMaxWidth = 400
$g_iSetHeight = Default
$g_iMaxHeight = 800
...
                Case StringInStr($sCmd, "/SetWidth:")
                    $g_iSetWidth = Int(StringReplace($sCmd, "/SetWidth:", ""))
                Case StringInStr($sCmd, "/SetHeight:")
                    $g_iSetHeight = Int(StringReplace($sCmd, "/SetHeight:", ""))

...
        ; Constraints
        If $iW > $g_iMaxWidth Then $iW = $g_iMaxWidth
        If $iH > $g_iMaxHeight Then $iH = $g_iMaxHeight
        If Not IsKeyword($g_iSetWidth) Then $iW = $g_iSetWidth
        If Not IsKeyword($g_iSetHeight) Then $iH = $g_iSetHeight
        If $iW < 150 Then $iW = 150
        If $iH < 50 Then $iH = 50
...

..that way if the user want to set the size for themselves, they can.

Edited March 25 by argumentum

mLipok · March 26

please post entire reproducer with comments in code

ioa747 · March 26

14 minutes ago, mLipok said:

please post entire reproducer with comments in code

what is it referring to?
all have comments, be more specific

ioa747 · Wednesday at 08:29 AM

Modern Sidebar UI

Injects a high-performance, Chromium-based Sidebar into a Win32 GUI using WebView2.
This method bypasses GDI/Win32 rendering limitations, allowing for full CSS3 animations,
Vector (SVG) icons, and 100% Color Emoji support.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "NetWebView2Lib.au3"

Global $g_idMemo

_Example()

;---------------------------------------------------------------------------------------
Func _Example()
    Local $hGui = GUICreate("Modern Sidebar UI", 550, 410)
    GUISetBkColor(0x252526) ; Dark Background

    $g_idMemo = GUICtrlCreateEdit("", 160, 10, 370, 390, $WS_VSCROLL, 0)
    GUICtrlSetFont(-1, 11, 400, 0, "Courier New")
    GUICtrlSetColor(-1, 0xF0F0F0)
    GUICtrlSetBkColor(-1, 0x333333)

    ; We create ONE WebView2 for the entire sidebar
    Local $oWebV2M = _NetWebView2_CreateManager()
    Local $oBridge = _NetWebView2_GetBridge($oWebV2M, "JS_Events_")

    ; Initialize on the left side (0, 0, 140, 410)
    _NetWebView2_Initialize($oWebV2M, $hGui, @ScriptDir & "\UserData", 0, 0, 140, 410, True)

    ; Constructing the HTML with all the buttons
    Local $sHTML = _GenerateSidebarHTML()
    _NetWebView2_NavigateToString($oWebV2M, $sHTML)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    _NetWebView2_CleanUp($oWebV2M, $oBridge)
EndFunc   ;==>_Example
;---------------------------------------------------------------------------------------
Func _GenerateSidebarHTML() ; The function that creates the "Menu"
    Local $sCSS = "body { margin: 0; background: #252526; font-family: 'Segoe UI', sans-serif; overflow: hidden; padding: 10px; }" & _
            ".btn { " & _
            "  width: 100%; padding: 12px; margin-bottom: 8px; border: none; border-radius: 6px; " & _
            "  background: #333; color: white; text-align: left; cursor: pointer; font-size: 15px; " & _
            "  transition: 0.2s; display: flex; align-items: center; " & _
            "} " & _
            ".btn:hover { background: #444; transform: translateX(5px); } " & _
            ".btn span { margin-right: 10px; font-size: 18px; }"

    Local $sHTML = "<html><head><style>" & $sCSS & "</style></head><body>"

    Local $aLabels[7] = ["🏆 Trophy", "🎯 Target", "⚠️ Warning", "😎 Cool", "👉 Select", "🌏 World", "🚧 Work"]

    For $i = 0 To 6
        $sHTML &= "<button class='btn' onclick='window.chrome.webview.postMessage(""BTN_CLICKED:" & $i & """)'>" & _
                "<span>" & StringLeft($aLabels[$i], 2) & "</span>" & StringTrimLeft($aLabels[$i], 2) & "</button>"
    Next

    $sHTML &= "</body></html>"
    Return $sHTML
EndFunc   ;==>_GenerateSidebarHTML
;---------------------------------------------------------------------------------------
Volatile Func JS_Events_OnMessageReceived($oWebV2M, $hGui, $sMessage) ; The Bridge that "catches" clicks
    If StringLeft($sMessage, 12) = "BTN_CLICKED:" Then
        Local $sIndex = StringTrimLeft($sMessage, 12)
        ; Here you can call any AutoIt function
        ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        MemoWrite("Index button pressed: " & $sIndex)
    EndIf
EndFunc   ;==>JS_Events_OnMessageReceived
;---------------------------------------------------------------------------------------
Func MemoWrite($sMessage) ; Write a line to the memo control
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite
;---------------------------------------------------------------------------------------

Please, every comment is appreciated!
leave your comments and experiences here!
Thank you very much

Edited Wednesday at 10:08 AM by ioa747

mLipok · Wednesday at 08:32 AM

Commit to github.com as new example
then I take it there and check

ioa747 · Wednesday at 09:06 AM

32 minutes ago, mLipok said:

Commit to github.com as new example

Done https://github.com/ioa747/NetWebView2Lib/blob/main/examples/021-ModernSidebarUI.au3

mLipok · Wednesday at 12:42 PM

Works well

Andreik · Wednesday at 01:06 PM

@ioa747 I like the idea of web based UI. Is there any other prerequisites for this to work. I ask because I have a bunch of stuffs installed on my PC and it was fairly simple to register the components and run the sample code provided and everything works properly. To deploy an application are there any other prerequisites?

ioa747 · Wednesday at 01:19 PM

📦 Deployment & Installation

Extract the NetWebView2Lib folder to a permanent location.

Clean & Prepare (Essential Step):
If you have a previous version installed, it is highly recommended to run the included \bin\RegCleaner.au3 before registering the new version.
This ensures that any stale registry entries from previous builds are purged, preventing "Object action failed" errors and GUID conflicts.

Registration:
Run \bin\Register_web2.au3 to register the library.
This script verifies the WebView2 Runtime presence and registers NetWebView2Lib.dll for COM Interop on both 32-bit and 64-bit architectures.

Uninstallation:
To remove the library from your system, simply run \bin\Unregister.au3.

Run Examples:
Execute any script in the \Example\* folder to see the bridge in action.

🛠 Prerequisites

.NET Framework 4.8 or higher.
Microsoft Edge WebView2 Runtime version 128.0.2739.15 or higher.

https://github.com/ioa747/NetWebView2Lib

Edited Wednesday at 01:24 PM by ioa747

Sign In

WebView2AutoIt - AutoIt WebView2 Component (COM Interop)

Recommended Posts

ioa747

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

ioa747

mLipok

ioa747

Posted Images

argumentum

mLipok

ioa747

ioa747

Modern Sidebar UI

mLipok

ioa747

mLipok

Andreik

ioa747

Create an account or sign in to comment

Create an account

Sign in

Browse

AutoIt Resources

Release

Beta