Catching COM errors when assigning a value to chained Object

[donnyh13]

5 minutes ago, mLipok said:

just changed the example a little:

Okay.

But what I was wondering is, $oFake[] and $oTestObject[] are considered Maps in AutoIt's eyes, and thus,

$oFake.FakeObject = 1

Is really creating Map key "FakeObject", and assigning 1 to it.

So when you are doing something like

$oFake.FakeObject.Check2

Is AutoIt still going to assume it is an Object, rather than we are just badly combining vastly different variable types?

[donnyh13]

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler)

Global $oShell = ObjCreate("shell.application") ; Get the Windows Shell Object

Global $oFake = $oShell

$oFake.FakeObject = 1

ConsoleWrite($oFake.FakeObject.Check2 & @CRLF) ; _ComErrorHandler() is fired as this was already fixed in https://www.autoitscript.com/trac/autoit/ticket/3167

$oFake.FakeObject.Check2 = 1 ; _ComErrorHandler() is not fired and AutoIt ends with "Variable must be of type "Object""

Func _ComErrorHandler(ByRef $oError)
        #forceref $oError
        ConsoleWrite("! We intercepted a COM Error" & @CRLF)
EndFunc   ;==>_ComErrorHandler

Something like this?

Edited yesterday at 04:59 PM by donnyh13

[argumentum]

2 minutes ago, donnyh13 said:

Something like this?

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler)

Global $oShell = ObjCreate("shell.application") ; Get the Windows Shell Object

Global $oFake = $oShell

$oFake.FakeObject = 1

ConsoleWrite($oFake.FakeObject.Check2 & @CRLF) ; _ComErrorHandler() is fired as this was already fixed in https://www.autoitscript.com/trac/autoit/ticket/3167

$oFake.FakeObject.Check3 = 1 ; _ComErrorHandler() is not fired and AutoIt ends with "Variable must be of type "Object""

Func _ComErrorHandler(ByRef $oError, $iLine = @ScriptLineNumber)
        #forceref $oError
        ConsoleWrite("@@(" & $iLine & ") : We intercepted a COM Error " & @CRLF)
EndFunc   ;==>_ComErrorHandler

@@(7) : We intercepted a COM Error 
@@(9) : We intercepted a COM Error 

@@(11) : We intercepted a COM Error 
"C:\Share\New AutoIt v3 Script.au3" (11) : ==> Variable must be of type "Object".:
$oFake.FakeObject.Check3 = 1
$oFake.FakeObject^ ERROR

..this is a bit more clear

[argumentum]

...not even a "fake" or copy,
 

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler) ; line 1
Global $oShell = ObjCreate("shell.application") ; line 2
$oShell.FakeObject = 1 ; line 3
$oShell.FakeObject.Check3 = 1 ; line 4
ConsoleWrite("hello" & @CRLF)  ; line 5
Func _ComErrorHandler(ByRef $oError, $iLine = @ScriptLineNumber)
        #forceref $oError
        ConsoleWrite('"' & @ScriptFullPath & '" (' & $iLine & ") : We intercepted a COM Error " & @CRLF)
EndFunc   ;==>_ComErrorHandler

"C:\Share\New AutoIt v3 Script.au3" (3) : We intercepted a COM Error 
"C:\Share\New AutoIt v3 Script.au3" (4) : We intercepted a COM Error 
"C:\Share\New AutoIt v3 Script.au3" (4) : ==> Variable must be of type "Object".:
$oShell.FakeObject.Check3 = 1
$oShell.FakeObject^ ERROR

so, it does catch the error but goes bananas anyways ( pardon the lingo, but "bananas" is what comes to mind )

[argumentum]

..just for 🤷‍♂️

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler) ; line 1
Global $oShell = ObjCreate("shell.application") ; line 2
Execute('$oShell.FakeObject = 1') ; line 3
Execute('$oShell.FakeObject.Check3 = 1') ; line 4
ConsoleWrite("hello" & @CRLF)  ; line 5
Func _ComErrorHandler(ByRef $oError, $iLine = @ScriptLineNumber)
        #forceref $oError
        ConsoleWrite('"' & @ScriptFullPath & '" (' & $iLine & ") : We intercepted a COM Error " & @CRLF)
EndFunc   ;==>_ComErrorHandler

"C:\Share\New AutoIt v3 Script.au3" (3) : We intercepted a COM Error 
"C:\Share\New AutoIt v3 Script.au3" (4) : We intercepted a COM Error 
hello

 

[donnyh13]

11 minutes ago, argumentum said:

so, it does catch the error but goes

Thanks.

It technically catches the call to

$oShell.FakeObject.Check3 = 1
----------^ Triggers Error
$oShell.FakeObject.Check3 = 1
-------------------^ Bananas

 

1 minute ago, argumentum said:

.just for 🤷‍♂️

Interesting.

[donnyh13]

Hmm maybe I'm wrong. Yes you're right, it does seem to catch it, but still tries completing the operation.

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler) ; line 1
Global $oShell = ObjCreate("shell.application") ; line 2
$oShell.FakeObject = 1 ; line 3
$oShell.FakeObject.Check3() ; line 4
$oShell.FakeObject.Check3 = 1 ; line 5
ConsoleWrite("hello" & @CRLF)  ; line 6
Func _ComErrorHandler(ByRef $oError, $iLine = @ScriptLineNumber)
        #forceref $oError
        ConsoleWrite('"' & @ScriptFullPath & '" (' & $iLine & ") : We intercepted a COM Error " & @CRLF)
EndFunc   ;==>_ComErrorHandler

"C:\Users\Owner\Desktop\New AutoIt v3 Script.au3" (3) : We intercepted a COM Error 
"C:\Users\Owner\Desktop\New AutoIt v3 Script.au3" (4) : We intercepted a COM Error 
"C:\Users\Owner\Desktop\New AutoIt v3 Script.au3" (5) : We intercepted a COM Error 
"C:\Users\Owner\Desktop\New AutoIt v3 Script.au3" (5) : ==> Variable must be of type "Object".:
$oShell.FakeObject.Check3 = 1
$oShell.FakeObject^ ERROR

 

Edited yesterday at 05:39 PM by donnyh13

[mLipok]

more complex example:

expandcollapse popup

#include <AutoItConstants.au3>

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler)

Global $oMAP_object[]
Global $oTestObject1_Shell = ObjCreate("shell.application")
Global $oTestObject2_Map[]
Global $_WatchPoint = @ScriptLineNumber

#Region ; testing FIX https://www.autoitscript.com/trac/autoit/ticket/3167
$_WatchPoint = @ScriptLineNumber
;~ $oTestObject1_Shell.Explore(@ScriptDir) ; works

$_WatchPoint = @ScriptLineNumber
$oTestObject1_Shell.Windows().Item(666).bzzzzzzz ; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167

$_WatchPoint = @ScriptLineNumber
$oTestObject1_Shell.Windows().Item(666).bzzzzzzz = 1 ; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
#EndRegion ; testing https://www.autoitscript.com/trac/autoit/ticket/3167

$_WatchPoint = @ScriptLineNumber
$oMAP_object.Shell = $oTestObject1_Shell

$_WatchPoint = @ScriptLineNumber
$oMAP_object.Shell.Explore(@ScriptDir) ; works

$_WatchPoint = @ScriptLineNumber
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.Shell", VarGetType($oMAP_object.Shell))

$_WatchPoint = @ScriptLineNumber
; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
$oMAP_object.Shell.Fake1(@ScriptDir)
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.Shell.Fake1(@ScriptDir)", '')

$_WatchPoint = @ScriptLineNumber
; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
$oMAP_object.Shell.Fake2 = 2
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.Shell.Fake2 = 2", '')

$_WatchPoint = @ScriptLineNumber
; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.Shell.Fake3", $oMAP_object.Shell.Fake3)

$_WatchPoint = @ScriptLineNumber
$oMAP_object.TestObject2_Map = $oTestObject2_Map
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.TestObject2_Map", VarGetType($oMAP_object.TestObject2_Map))

$_WatchPoint = @ScriptLineNumber
$oMAP_object.TestObject2_Map.Check1 = 1 ; create MAP element called "Check1" with value = 1

$_WatchPoint = @ScriptLineNumber
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.TestObject2_Map.Check1", $oMAP_object.TestObject2_Map.Check1)

$_WatchPoint = @ScriptLineNumber
MsgBox(0, @ScriptLineNumber & " : $oTestObject2_Map.Check1", $oTestObject2_Map.Check1)

$_WatchPoint = @ScriptLineNumber
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.TestObject2_Map.Check1", $oMAP_object.TestObject2_Map.Check1)

$_WatchPoint = @ScriptLineNumber
$oMAP_object.FakeObject1 = 1 ; create MAP element called "FakeObject" with value = 1

$_WatchPoint = @ScriptLineNumber
; in the following line _ComErrorHandler() IS NOT FIRED although it has already been fixed in https://www.autoitscript.com/trac/autoit/ticket/3167 = IMHO this is AutoIt issue
;  ... but maybe it is intentional to not FIRE _ComErrorHandler() as $oMAP_object.FakeObject1 is treated as MAP ELEMENT thus Check2 is also treated as MAP element and thus can be created on the fly
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.FakeObject1.Check2", "Result=" & $oMAP_object.FakeObject1.Check2)

$_WatchPoint = @ScriptLineNumber
; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
MsgBox(0, @ScriptLineNumber & " : $oCOM_ErrorHandler.FakeObject1.Check3", $oCOM_ErrorHandler.FakeObject1.Check3)

$_WatchPoint = @ScriptLineNumber
; in the following line _ComErrorHandler() IS FIRED but AutoIt ends with (Variable must be of type "Object") = IMHO this is AutoIt issue
;  ... this is the case @donnyh13 reported at the begining = IMHO this is AutoIt issue
$oCOM_ErrorHandler.FakeObject2.Check4 = 1
MsgBox(0, @ScriptLineNumber & " : $oCOM_ErrorHandler.FakeObject2.Check4", "")

$_WatchPoint = @ScriptLineNumber
; _ComErrorHandler() IS FIRED and AutoIt PROPERLY continue processing next line - due COM ERROR HANDLER was used and FIXED in #3167
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.FakeObject3.Check5", $oMAP_object.FakeObject3.Check5)

$_WatchPoint = @ScriptLineNumber
; in the following line _ComErrorHandler() IS NOT FIRED and AutoIt ends with (Variable must be of type "Object") = IMHO this is AutoIt issue
;  ... this is the case @donnyh13 reported at the begining = IMHO this is AutoIt issue
$oMAP_object.FakeMapElement.Check6 = 1
MsgBox(0, @ScriptLineNumber & " : $oMAP_object.FakeMapElement.Check6", "")

Func _ComErrorHandler(ByRef $oError)
    #forceref $oError
    ConsoleWrite("! We intercepted a COM Error : Last @ScriptLineNumber (WatchPoint) =" & $_WatchPoint & @CRLF)
EndFunc   ;==>_ComErrorHandler

#REMARK =>  .Check2 needs To be explained
#REMARK =>  both .Check4 and .Check6 should fires _ComErrorHandler() and show the console message also AutoIt should not ends With: Variable must be of type "Object"

 

Edited yesterday at 07:00 PM by mLipok

[argumentum]

Maybe Execute() has a 

Execute() {
    try {
    } 
    catch () {
    }
}

and that save us from the oops 🤔

But at least we have a way around it while it gets fixed

[argumentum]

@mLipok, I added a comment to the trac to hint JPM because they may not read the forum posts and just go by the trac entries.

[argumentum]

Global $oCOM_ErrorHandler = ObjEvent("AutoIt.Error", _ComErrorHandler) ; line 1
Global $oShell = ObjCreate("shell.application") ; line 2
;~ If IsObj($oObject) Then would be advisable everywhere
$oShell.FakeObject = 1 ; line 4
Execute('$oShell.FakeObject.Check3 = 1') ; line 5 ; this is "saved" from crashing
;~ $oShell.FakeObject.Check3 = 1 ; line 6 ; this is will "oops"
$oFakeObject = $oShell.FakeObject ; line 7 ; flatten it first..
$oFakeObject.Check3 = 1 ; line 8 ; ..then call it, to overcome the current AutoIt3 behaviour
ConsoleWrite("hello" & @CRLF)  ; line 9
Func _ComErrorHandler(ByRef $oError, $iLine = @ScriptLineNumber)
        #forceref $oError
        ConsoleWrite('"' & @ScriptFullPath & '" (' & $iLine & ") : We intercepted a COM Error " & @CRLF)
EndFunc   ;==>_ComErrorHandler

..had to do stuff like this working with $oIE

[donnyh13]

Unfortunately that looks like it will have to be my go-to method as well 😕 , the neat-freak in me is crying a little.

Thanks for the input everyone!