Example _GUICtrlListView_MapIndexToID() and _GUICtrlListView_MapIDToIndex()

[mLipok]

I was wondering if is there a way to set up user ID for ListView Item ?
Or the ItemID is set automatically by WinAPI and check them ?
 

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iID, $idListview

    GUICreate("ListView Map ID To Index", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Add column
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Show ID for item 2
    $iID = _GUICtrlListView_MapIndexToID($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Index to ID: " & $iID)
    MsgBox($MB_SYSTEMMODAL, "Information", "ID to Index: " & _GUICtrlListView_MapIDToIndex($idListview, $iID))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

MSDN references:
https://learn.microsoft.com/en-us/windows/win32/controls/lvm-mapidtoindex

https://learn.microsoft.com/en-us/windows/win32/controls/lvm-mapindextoid

https://learn.microsoft.com/en-us/windows/win32/api/mmc/nf-mmc-icomponent-getdisplayinfo
 

Quote

List-view controls internally track items by index. This can present problems because indexes can change during the control's lifetime.

The list-view control can tag an item with an ID when the item is created. You can use this ID to guarantee uniqueness during the lifetime of the list-view control.

To uniquely identify an item, take the index that is returned from a call such as IComponent::GetDisplayInfo and call LVM_MAPINDEXTOID. The return value is a unique ID.

 

[mLipok]

Hm... here is my partial solution to explain this problem

expandcollapse popup

#Region ; *** Dynamically added Include files ***
#include <ColorConstants.au3>                                ; added:05/09/26 05:11:48
#EndRegion ; *** Dynamically added Include files ***
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $iID, $idListview

    GUICreate("ListView Map ID To Index", 500, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 494, 268, -1, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState(@SW_SHOW)

    GUIRegisterMsg($WM_NOTIFY, MY_WM_NOTIFY)

    ; Add column
    _GUICtrlListView_AddColumn($idListview, "Items name/text", 100)
    _GUICtrlListView_AddColumn($idListview, "ItemIndex (current row index)", 100)
    _GUICtrlListView_AddColumn($idListview, "ItemID (creation order index)", 100)

    _GUICtrlListView_SetColumnWidth($idListview, 0, $LVSCW_AUTOSIZE_USEHEADER)
    _GUICtrlListView_SetColumnWidth($idListview, 1, $LVSCW_AUTOSIZE_USEHEADER)
    _GUICtrlListView_SetColumnWidth($idListview, 2, $LVSCW_AUTOSIZE_USEHEADER)

    ; Add items
    _GUICtrlListView_InsertItem($idListview, "Item 1", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 2", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 3", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 4", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 5", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 6", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 7", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 8", 0)
    _GUICtrlListView_InsertItem($idListview, "Item 9", 0)

    ; show all Item's ID
    For $IDX = 0 To _GUICtrlListView_GetItemCount($idListview) - 1
        $iID = _GUICtrlListView_MapIndexToID($idListview, $IDX)
        _GUICtrlListView_AddSubItem($idListview, $IDX, $iID, 2)
    Next

    ; Show ID for item 2
    $iID = _GUICtrlListView_MapIndexToID($idListview, 2)
    MsgBox($MB_SYSTEMMODAL, "Information", "Index to ID: " & $iID)
    MsgBox($MB_SYSTEMMODAL, "Information", "ID to Index: " & _GUICtrlListView_MapIDToIndex($idListview, $iID))

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'before deleting "Item 8"' & @CRLF & 'Note "Item 7" Index and ID' & @CRLF & 'also other lower ListView items (rows)')
    _GUICtrlListView_DeleteItem($idListview , 1)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'afer deleting "Item 8"' & @CRLF & 'Note "Item 7" : The index has changed, but the ID has not' & @CRLF & 'also other lower ListView items (rows)')

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()

EndFunc   ;==>Example

Func MY_WM_NOTIFY($hWnd, $msg, $wParam, $lParam) ; https://learn.microsoft.com/en-us/windows/win32/controls/wm-notify
    #forceref $hWnd, $msg, $wParam, $lParam
    Local Static $clrRed = _WinAPI_SwitchColor($COLOR_RED)
    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw

    If $tItem.Code <> $NM_CUSTOMDRAW Then Return $GUI_RUNDEFMSG
    Local $dwDrawStage = $tItem.dwDrawStage

    If $dwDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
    If $dwDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
    If $tItem.iSubitem <> 1 Then Return $GUI_RUNDEFMSG

    Local $dwItemSpec = $tItem.dwItemSpec
    Local $hDC = $tItem.hdc ; Device context
    Local $s_Text = $dwItemSpec
    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
    _WinAPI_SetTextColor($hDC, $clrRed)
    _WinAPI_DrawText($hDC, $s_Text, $tRect, $DT_LEFT)

    Return $CDRF_SKIPDEFAULT
EndFunc   ;==>MY_WM_NOTIFY

My issue with this scirpt is that my intention was to automatically update values in "ItemIndex (current row index)" column after 

_GUICtrlListView_DeleteItem($idListview , 1)

but I'm still not feeling too confident with this whole WM_NOTIFY stuff, and I did something else wrong there.
Any help with WM_NOTIFY here would be welcome.

Edited Saturday at 03:44 AM by mLipok

[mLipok]

I did it

expandcollapse popup

#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Global Enum $__Example_LVColumn_Name, $__Example_LVColumn_ItemIndex, $__Example_LVColumn_ItemID
Example()

Func Example()
    Local $iID, $idListview

    GUICreate("ListView Map ID To Index", 530, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 524, 268, -1, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    GUISetState(@SW_SHOW)

    GUIRegisterMsg($WM_NOTIFY, MY_WM_NOTIFY)

    ; Add column
    _GUICtrlListView_AddColumn($idListview, "Item (row name given by user)", 100) ; $__Example_LVColumn_Name
    _GUICtrlListView_AddColumn($idListview, "ItemIndex (current row index)", 100) ; $__Example_LVColumn_ItemIndex
    _GUICtrlListView_AddColumn($idListview, "ItemID (creation order index)", 100) ; $__Example_LVColumn_ItemID

    _GUICtrlListView_SetColumnWidth($idListview, $__Example_LVColumn_Name, $LVSCW_AUTOSIZE_USEHEADER)
    _GUICtrlListView_SetColumnWidth($idListview, $__Example_LVColumn_ItemIndex, $LVSCW_AUTOSIZE_USEHEADER)
    _GUICtrlListView_SetColumnWidth($idListview, $__Example_LVColumn_ItemID, $LVSCW_AUTOSIZE_USEHEADER)

    ; Add items - always as first item - it creates "Revert Order" last element on top - as ItemIndex 0
    For $i = 1 To 9
        _GUICtrlListView_InsertItem($idListview, "Item " & $i, 0)
    Next

    ; Show ID for item 2
    Local $i_CheckItem = 2
    $iID = _GUICtrlListView_MapIndexToID($idListview, $i_CheckItem)
    Local $s_Info = _
            "Index " & $i_CheckItem & " to ID: " & $iID & @CRLF & _
            "ID " & $iID & " to Index: " & _GUICtrlListView_MapIDToIndex($idListview, $iID)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, $s_Info)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, _
            'Before deleting "Item 8"' & @CRLF & _
            'Note "Item 7" Index and ID' & @CRLF & _
            'also other lower ListView items (rows)' _
            )
    _GUICtrlListView_DeleteItem($idListview, 1)
    _GUICtrlListView_RedrawItems($idListview, 0, _GUICtrlListView_GetItemCount($idListview) - 1)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, _
            'Afer deleting "Item 8"' & @CRLF & _
            'Note "Item 7" : The index has changed, but the ID has not' & @CRLF & _
            'also other lower ListView items (rows)' & @CRLF & _
            '' & @CRLF & _
            '' & @CRLF & _
            '')

    ; remove almost all - keep "Item 9" as last added
    For $i = 7 To 1 Step -1
        _GUICtrlListView_DeleteItem($idListview, $i)
    Next
    _GUICtrlListView_InsertItem($idListview, "Item 10", 0)
    _GUICtrlListView_RedrawItems($idListview, 0, _GUICtrlListView_GetItemCount($idListview) - 1)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, _
            'Afer adding "Item 10"' & @CRLF & _
            'Note "Item 10" : The index has changed, new ID is 9' & @CRLF & _
            '')


    _GUICtrlListView_DeleteAllItems($idListview)
    For $i = 11 To 90
        _GUICtrlListView_InsertItem($idListview, "Item " & $i, 0)
    Next
    _GUICtrlListView_DeleteAllItems($idListview)
    For $i = 91 To 100
        _GUICtrlListView_InsertItem($idListview, "Item " & $i, 0)
    Next
    _GUICtrlListView_RedrawItems($idListview, 0, _GUICtrlListView_GetItemCount($idListview) - 1)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, _
            'Afer adding "Item 100"' & @CRLF & _
            'Note "Item 100" : new ID is 99' & @CRLF & _
            '')

    _GUICtrlListView_DeleteAllItems($idListview)
    _GUICtrlListView_InsertItem($idListview, "Item 101", 0)
    _GUICtrlListView_RedrawItems($idListview, 0, _GUICtrlListView_GetItemCount($idListview) - 1)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, _
            'Afer adding "Item 101" to empty list' & @CRLF & _
            'Note "Item 101" : new ID is 100' & @CRLF & _
            '')


    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()

EndFunc   ;==>Example

Func MY_WM_NOTIFY($hWnd, $msg, $wParam, $lParam) ; https://learn.microsoft.com/en-us/windows/win32/controls/wm-notify
    #forceref $hWnd, $msg, $wParam, $lParam
    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw

    If $tItem.Code <> $NM_CUSTOMDRAW Then Return $GUI_RUNDEFMSG
    Local $dwDrawStage = $tItem.dwDrawStage

    If $dwDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
    If $dwDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW

    Local $iItemIndex = $tItem.dwItemSpec
    Local $iItemID = _GUICtrlListView_MapIndexToID($tItem.hWndFrom, $iItemIndex)
    Local $hDC = $tItem.hdc ; Device context
    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))

    If $tItem.iSubitem = $__Example_LVColumn_ItemIndex Then
        _WinAPI_SetTextColor($hDC, $CLR_RED)
        _WinAPI_DrawText($hDC, $iItemIndex, $tRect, $DT_CENTER)
        Return $CDRF_SKIPDEFAULT
    ElseIf $tItem.iSubitem = $__Example_LVColumn_ItemID Then
        _WinAPI_SetTextColor($hDC, $CLR_BLUE)
        _WinAPI_DrawText($hDC, $iItemID, $tRect, $DT_CENTER)
        Return $CDRF_SKIPDEFAULT
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>MY_WM_NOTIFY

ItemIndex in column 1 ($__Example_LVColumn_ItemIndex) and ItemID in column 2 ($__Example_LVColumn_ItemID) 
are updated automaticaly by MY_WM_NOTIFY() 

Conclusion:
ItemIndex - is index showing current Item position in ListView

ItemID - is auto counted ID showing creation/adding order

 

Edited 3 hours ago by mLipok

[mLipok]

Please let me know what you think about this example also if I did any mistake in understanding the ListView or even any mistake in my "English" wording in this example.

EDIT: 
I added it to HelpFile as  _GUICtrlListView_MapIndexToID[2].au3

Edited 2 hours ago by mLipok