7 replies to this topic

[guinness]

I came across a situation the other day where I had to find a file in "LOCALAPPDATA", now the obvious solution was to use @UserProfileDir & "AppDataLocal" and this was fine. But being the curious type I was interested to know if there was a way of extracting "LOCALAPPDATA" from the Registry (Vista above) and this is when I came across HKEY_CURRENT_USERVolatile Environment.

The Function will enumerate through the Registry Key (HKEY_CURRENT_USERVolatile Environment) adding the values to an Array. Because the final size of the Array is unknown, I've started to use ReDim in an efficent way! Check out _ReDim() for more details.

Note: This will work on XP and above, but it should be noted that "LOCALAPPDATA" can't be found on XP!

Function: Save as _GetSystemPaths.au3

AutoIt        expandcollapse  popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetSystemPaths
; Description ...: Retrieve details about the system paths from HKEY_CURRENT_USER\Volatile Environment\.
; Syntax ........: _GetSystemPaths()
; Parameters ....: None
; Return values .: Success - Returns a 2 dimensional array where element[n][0] is the registry item and element[n][1] is the value.
;                  The number of elements returned will be in $aArray[0][0].
;                  Failure - None
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func _GetSystemPaths()
    Local $aReturn[1][3] = [[0, 3, 0]], _
            $iCount = 1, _
            $sRegistryKey = 'HKEY_CURRENT_USER\Volatile Environment\', $sRegistryValue = ''
    While 1
        $sRegistryValue = RegEnumVal($sRegistryKey, $iCount)
        If @error Then
            ExitLoop
        EndIf
        If ($aReturn[0][0] + 1) >= $aReturn[0][2] Then
            $aReturn[0][2] = Ceiling(($aReturn[0][0] + 1) * 1.3)
            ReDim $aReturn[$aReturn[0][2]][$aReturn[0][1]]
        EndIf
        $aReturn[0][0] += 1
        $aReturn[$aReturn[0][0]][0] = $sRegistryValue
        $aReturn[$aReturn[0][0]][1] = RegRead($sRegistryKey, $sRegistryValue)
        $iCount += 1
    WEnd
    ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1] - 1]
    $aReturn[0][1] = ''
    Return $aReturn
EndFunc   ;==>_GetSystemPaths

Example use of Function:

#include <Array.au3>

#include '_GetSystemPaths.au3'

Local $aArray = _GetSystemPaths()
_ArrayDisplay($aArray)

Edited by guinness, 09 April 2013 - 04:09 PM.

[Ascend4nt]

Also check out 'SHGetFolderPath' and 'SHGetKnownFolderPath' API functions.

[guinness]

I know of those API's (I use SHGetKnownFolderPath in _SendTo()) but didn't think to check for LOCALAPPDATA!! Thanks Ascend4nt

Edit: Just checked WinAPIEx.au3 and found it >> _WinAPI_ShellGetSpecialFolderPath($CSIDL_LOCAL_APPDATA), don't I look like a fool . Oh well it only took me 5mins to create. I always forget to check APIConstant.au3 and opt for the Help File instead, now I know.

Edited by guinness, 23 June 2011 - 12:57 AM.

[BrewManNH]

You could also use the environment variables to get them, might be easier if running under a non-admin account.

[guinness]

I could have done that too BrewManNH . But the most important thing was I was looking for alternative routes too.

MsgBox(64, "Get %LOCALAPPDATA%", EnvGet("LOCALAPPDATA"))

[wakillon]

MsgBox(64, "Get %LOCALAPPDATA%", EnvGet("LOCALAPPDATA"))

What's the difference between %LOCALAPPDATA% and %APPDATA% who works on XP ?

MsgBox(64, "Get %APPDATA%", EnvGet("APPDATA")) 

[guinness]

%LOCALAPPDATA% doesn't exist on XP but its a folder that stores data for local (non-roaming).

For more details: http://www.vistaonwindows.com/environment_variables.php

[guinness]

Fixed code above.