20 replies to this topic

[guinness]

I've recently been uncovering the useful commandline tools that can be found natively in Windows, one of which was findstr (there is also a GUI interface available in SciTE4AutoIt3.) After coming across this little gem and implementing in SciTE Jump, it felt only right that I should share this on the forums as a standalone UDF. Thanks

Function:

AutoIt        expandcollapse  popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _FindInFile
; Description ...: Search for a string within files located in a specific directory.
; Syntax ........: _FindInFile($sSearch, $sFilePath[, $sMask = '*'[, $fRecursive = True[, $fLiteral = Default[,
;                  $fCaseSensitive = Default[, $fDetail = Default]]]]])
; Parameters ....: $sSearch             - The keyword to search for.
;                  $sFilePath           - The folder location of where to search.
;                  $sMask               - [optional] A list of filetype extensions separated with ';' e.g. '*.au3;*.txt'. Default is all files.
;                  $fRecursive          - [optional] Search within subfolders. Default is True.
;                  $fLiteral            - [optional] Use the string as a literal search string. Default is False.
;                  $fCaseSensitive      - [optional] Use Search is case-sensitive searching. Default is False.
;                  $fDetail             - [optional] Show filenames only. Default is False.
; Return values .: Success - Returns a one-dimensional and is made up as follows:
;                            $aArray[0] = Number of rows
;                            $aArray[1] = 1st file
;                            $aArray[n] = nth file
;                  Failure - Returns an empty array and sets @error to non-zero
; Author ........: guinness
; Remarks .......: For more details: http://ss64.com/nt/findstr.html
; Example .......: Yes
; ===============================================================================================================================
Func _FindInFile($sSearch, $sFilePath, $sMask = '*', $fRecursive = True, $fLiteral = Default, $fCaseSensitive = Default, $fDetail = Default)
    Local $sCaseSensitive = '/i', $sDetail = '/m', $sRecursive = ''
    If $fCaseSensitive Then
        $sCaseSensitive = ''
    EndIf
    If $fDetail Then
        $sDetail = '/n'
    EndIf
    If $fLiteral Then
        $sSearch = ' /c:' & $sSearch
    EndIf
    If $fRecursive Or $fRecursive = Default Then
        $sRecursive = '/s'
    EndIf
    If $sMask = Default Then
        $sMask = '*'
    EndIf

    $sFilePath = StringRegExpReplace($sFilePath, '[\\/]+\z', '') & '\'
    Local Const $aMask = StringSplit($sMask, ';')
    Local $iPID = 0, $sOutput = ''
    For $i = 1 To $aMask[0]
        $iPID = Run(@ComSpec & ' /c ' & 'findstr ' & $sCaseSensitive & ' ' & $sDetail & ' ' & $sRecursive & ' "' & $sSearch & '" "' & $sFilePath & $aMask[$i] & '"', @SystemDir, @SW_HIDE, 6)
        While 1
            $sOutput &= StdoutRead($iPID)
            If @error Then
                ExitLoop
            EndIf
        WEnd
    Next

    Return StringSplit(StringStripWS(StringStripCR($sOutput), 3), @LF)
EndFunc   ;==>_FindInFile

Example use of Function:

#include <Array.au3>

Local $hTimer = TimerInit()
Local $aArray = _FindInFile('findinfile', @ScriptDir, '*.au3;*.txt') ; Search for 'findinfile' within the @ScripDir and only in .au3 & .txt files.
ConsoleWrite(Round(TimerDiff($hTimer) / 1000, 2) & ' (Seconds)' & @CRLF)
_ArrayDisplay($aArray)

$hTimer = TimerInit()
$aArray = _FindInFile('autoit', @ScriptDir, '*.au3') ; Search for 'autoit' within the @ScripDir and only in .au3 files.
ConsoleWrite(Round(TimerDiff($hTimer) / 1000, 2) & ' (Seconds)' & @CRLF)
_ArrayDisplay($aArray)

Edited by guinness, 21 February 2013 - 12:50 PM.

[VelvetElvis]

I love these simple yet powerful scripts. This works great with very large files.
Thank you!

[akurakkauaaa]

bad working for no-english transcription.
č, ř, ž, ý, á, é, ß, ä, ö, ą, ę, ć, ź, ż... ect...

[Ascend4nt]

This command could probably use the '/u' unicode switch, as long as it pipes to a file or a pipe.

/U: Causes the output of internal commands to a pipe or file to be Unicode

A few of us have used this successfully. Check this link by KaFu on how to use Named pipes:
Retrieve Unicode results from Console by KaFu

There's also links to posts by msfecteau and me in which the Unicode switch is used to output to a file before being read.

*Edit: Just tried this, and found out that 'findstr' only works in ANSI/ASCII mode, so no luck using this for Unicode files. Might as well use Notepad++'s built-in find&replace tool for doing multi-file search&replace

Edited by Ascend4nt, 27 September 2011 - 12:13 PM.

[guinness]

Thanks Ascend4nt for confirming.

I've just updated the code which wasn't setting @error if no files were found, only when the SRE failed. Updated the original post.

Edited by guinness, 13 November 2011 - 06:34 PM.

[wakillon]

Have a look at martin version : http://www.autoitscript.com/forum/topic/85567-find-string-in-files/

[guinness]

Added a new parameter that will search the string as a literal string. What this means is if you search at present "This text" it will search either for "This" or "text", whereas if you set $iLiteral as 1 it will only search for "This text".

[guinness]

Updated the syntax and reduced the total number of lines for the function. See the original post for downloading.

[Renuka]

This script is not working for .exe and can you modify this script so that it is compatible for searching .exe's

[guinness]

Why would you want to search for text in an executable?

[JScript]

Jeez, I had not seen this UDF!! It will help me a lot my friend, no doubt...

You deserve

Thanks 4 shared!

JS

[sundar]

I know this is old thread but the function is not working for me. I am trying to find the string "sundar" in files with *.txt extension in desktop directory. I don not know what went wrong but i did not change anything in the function. Iused only used example script with change in search string and file path/extension. The result of the function is attached.

Attached Thumbnails

• 

[guinness]

What about now? The Forum stripped backslashes again.

[sundar]

What about now? The Forum stripped backslashes again.

You are too good. Your function does what it says. Thank you vermuch for the quick help. :-)
If forum formating is an issue, then why don't you upload the UDF instead of just desplaying?

[guinness]

I think I will do that from now on for large UDFs such as this. Thanks for bringing it to my attention.

[BrewManNH]

I must have missed this thread back in the day, good use of findstr.exe. Keeps me from having to fileinstall Jos' version of it. I didn't even realize Windows has its own version of the program natively.

[guinness]

Thanks BrewManNH.

[qwert]

What is needed to cause the search results to sort by either Date Last Modified or File Size? I would prefer to click on the column header (like Win Explorer), but a couple of buttons would be OK, too.

I've used this convenient search for at least a year, but I've never been able to get a handle on how to implement column sorting.

Thanks in advance for any help.

[BrewManNH]

The _ArrayDisplay is a debugging function only used to display the contents of the array. If you want more control over the display, you'll need to create your own listview control to do so.

[guinness]

To add to what BrewManNH said, search the Forum for _ForFiles. It's another function I created.

Actually, here's the link >> http://www.autoitscript.com/forum/topic/147834-forfiles-command-not-working-with-autoit/#entry1049090

Edit: Forget it, this is for searching within filenames, not inside files.

Edited by guinness, 22 February 2013 - 10:28 AM.