Help: Launching a Browser

[VinzParamore]

Hello guyz...

I am new here!

Does anybody know how to Launch your default Browser?

Like Mozilla or Chrome or Opera ETC.?...

I don't like IE...

my default Browser is Mozilla..

any Help??

Good Help will be appreciated...

[water]

This should give you the default Browser

ConsoleWrite(RegRead("HKCR\HTTP\shell\open\command\", ""))

Use ShellExecute to start the Browser.

See this post.

[MARAN]

ShellExecute("http://www.autoitscript.com/forum")

It will open your default browser within the AutoIt Forums page.

[Yashied]

$Command = RegRead('HKCR\' & RegRead('HKCR\.html', '') & '\shell\open\command', '')
If StringLeft($Command, 1) = '"' Then
    $Path = StringRegExpReplace($Command, '\A"+|".*\z', '')
Else
    $Path = StringRegExpReplace($Command, '\A\s+|\s.*\z', '')
EndIf
ConsoleWrite($Path & @CR)
ShellExecute($Path)

Pattern for StringRegExpReplace() is written by MrCreatoR.

Edited September 8, 2009 by Yashied

[Yashied]

Another way.

Global Const $ASSOCSTR_EXECUTABLE = 2

$Path = _WinAPI_AssocQueryString('.html', $ASSOCSTR_EXECUTABLE)
ShellExecute($Path)

Func _WinAPI_AssocQueryString($sAssoc, $iType, $iFlags = 0, $sExtra = '')

    Local $TypeOfExtra = 'wstr'

    If StringStripWS($sExtra, 3) = '' Then
        $TypeOfExtra = 'ptr'
        $sExtra = 0
    EndIf

    Local $Ret

    $Ret = DllCall('shlwapi.dll', 'int', 'AssocQueryStringW', 'dword', $iFlags, 'dword', $iType, 'wstr', $sAssoc, $TypeOfExtra, $sExtra, 'ptr', 0, 'dword*', 0)
    If (@error) Or (Not ($Ret[0] = 1)) Then
        Return SetError(1, 0, '')
    EndIf

    Local $tData = DllStructCreate('wchar[' & $Ret[6] & ']')

    $Ret = DllCall('shlwapi.dll', 'int', 'AssocQueryStringW', 'dword', $iFlags, 'dword', $iType, 'wstr', $sAssoc, $TypeOfExtra, $sExtra, 'ptr', DllStructGetPtr($tData), 'dword*', $Ret[6])
    If (@error) Or (Not ($Ret[0] = 0)) Then
        Return SetError(1, 0, '')
    EndIf
    Return DllStructGetData($tData, 1)
EndFunc   ;==>_WinAPI_AssocQueryString

[VinzParamore]

A Lot of Thank you guys....

This Post is Solved

I love this Forum!