SciTE Colo(u)r Chooser

[BrewManNH]

Ever had the need to pick a hex value for a color for a GUI or a control? Ever tried to figure out how to get those numbers into your script once you've picked the perfect color? I have come up with an extremely small script, that when compiled and placed in a folder inside the SciTE folder will allow you to quickly select the color you want using the _ChooseColor dialog. It will then paste this color code into your script where you cursor is currently placed. It works with Scite only for now, mainly because it uses ControlSend to paste the value into SciTE's editor window, but can easily be modified to work with any editor by changing the window title and control ID it's sending to. This code will work when compiled and placed into the "Autoit3\Scite\ColorChooser" folder, or wherever you have your installation of SciTE, but has to be in the folder named ColorChooser for the tool code to work, or you'll have to change that yourself.

Here's the code for the colorchooser:

expandcollapse popup

#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_Tidy=y
#Tidy_Parameters=/rel
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/so
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Misc.au3>
#include <SendMessage.au3>
Opt("WinTitleMatchMode", 2)
Global $sDefaultColor = 0
Global $iMode = 1
Global Const $WM_COPYDATA = 0x004A
If $cmdline[0] > 0 Then
    $sDefaultColor = $cmdline[1]
EndIf
If StringLeft($sDefaultColor, 2) <> "0x" Then
    $iMode = 0
    $sDefaultColor = "0x" & $sDefaultColor
EndIf
$sReturn = _ChooseColor(2, $sDefaultColor, 2)
If $sReturn = -1 Then Exit (1)
If Not $iMode Then
    $sReturn = StringMid($sReturn, 3)
EndIf
_SciTE_InsertText($sReturn)
Func _SciTE_InsertText($sString)
    Return _SciTE_Send_Command(0, WinGetHandle("DirectorExtension"), "insert:" & $sString)
EndFunc   ;==>_SciTE_InsertText
Func _SciTE_Send_Command($hHandle, $hSciTE, $sString)
    Local $ilParam, $tData
    If StringStripWS($sString, 8) = "" Then
        Return SetError(2, 0, 0) ; String is blank.
    EndIf
    $sString = ":" & Dec(StringTrimLeft($hHandle, 2)) & ":" & $sString
    $tData = DllStructCreate("char[" & StringLen($sString) + 1 & "]") ; wchar
    DllStructSetData($tData, 1, $sString)
    $ilParam = DllStructCreate("ptr;dword;ptr") ; ulong_ptr;dword;ptr
    DllStructSetData($ilParam, 1, 1) ; $ilParam, 1, 1
    DllStructSetData($ilParam, 2, DllStructGetSize($tData))
    DllStructSetData($ilParam, 3, DllStructGetPtr($tData))
    _SendMessage($hSciTE, $WM_COPYDATA, $hHandle, DllStructGetPtr($ilParam))
    Return Number(Not @error)
EndFunc   ;==>_SciTE_Send_Command

As you can see, there's not a whole lot to it. It just pops open the color chooser dialog, copies the results to the clipboard and then pastes it into SciTE using the ControlSend command. You will also notice, that if you don't choose a color, by hitting cancel in the Color Chooser dialog, it will also exit without pasting anything, so you shouldn't need to worry about pasting something you don't want in your scripts.

This code should be added to your SciTEUser.properties file so that you can call it from within SciTE by hitting Ctrl-Alt-C, this can be changed if you already have a hot key set to that combination.

# 43 Color Chooser
command.name.43.*=Color Chooser
command.43.*="$(SciteDefaultHome)\ColorChooser\ColorChooser.exe" $(CurrentSelection)
command.shortcut.43.*=Ctrl+Alt+C

That's all there is to it, enjoy.

EDIT: I have updated the script and the SciTEUser.properties code so that if you have a color code that's currently selected when this is called, it will send that to the _ChooseColor dialog now as the starting color.

UPDATED: 31-May-12

I've updated the script so that it now uses the "DirectorExtension" as suggested by guinness instead of copying the data to the clipboard and pasting it into SciTE, which might cause problems with what you have on the clipboard currently.

I have also updated it so that if you send the script a color in the format "FFFFFF" without the preceeding "0x", it will return the color code in the same format. This is useful if, for example, you're changing a color in one of SciTE's properties files, which don't start with "0x".

I've also changed the command.43.* line, I've moved the quote from the end of the line to the end of the command because I've noticed that a lot of times it causes issues if the color code is inside the quotes.

Edited May 31, 2012 by BrewManNH

[BrewManNH]

Updated the code in the original post to now include sending the currently selected text to the program so that it can use that as the default color in the color picker dialog.

Don't worry if you've selected something other than a color code, you can always cancel the box and nothing gets changed, and the default color chosen is black in this case.

The command line sent to the ColorChooser.exe program is displayed in the console output in SciTE so you can monitor what you're sending the program.

[JFX]

Very usefull!

But save the old clipboard data and put it back after the Controlsend.

[guinness]

Another approach is to use the DirectorExtension to interact with SciTE.

expandcollapse popup

#include <Misc.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Exit Example()

Func Example()
    Local $bDefaultColor = 0
    If $CmdLine[0] > 0 Then
        $bDefaultColor = $CmdLine[1]
    EndIf
    Local $bReturn = _ChooseColor(2, $bDefaultColor, 2)
    If $bReturn = -1 Then
        Return SetError(1, 0, 1001)
    EndIf
    _SciTE_InsertText(@CRLF & $bReturn & @CRLF)
EndFunc   ;==>Example

#region SciTE UDF - Unreleased.
Func _SciTE_InsertText($sString)
    $sString = _ScITE_ReplaceMarcos(StringReplace($sString, "", ""))
    Return _SciTE_Send_Command(0, WinGetHandle("DirectorExtension"), "insert:" & $sString)
EndFunc   ;==>_SciTE_InsertText

Func _ScITE_ReplaceMarcos($sString)
    $sString = StringReplace($sString, @TAB, "t")
    $sString = StringReplace($sString, @CR, "r")
    $sString = StringReplace($sString, @LF, "n")
    Return $sString
EndFunc   ;==>_ScITE_ReplaceMarcos

Func _SciTE_Send_Command($hHandle, $hSciTE, $sString)
    Local $ilParam, $tData

    If StringStripWS($sString, 8) = "" Then
        Return SetError(2, 0, 0) ; String is blank.
    EndIf
    $sString = ":" & Dec(StringTrimLeft($hHandle, 2)) & ":" & $sString
    $tData = DllStructCreate("char[" & StringLen($sString) + 1 & "]") ; wchar
    DllStructSetData($tData, 1, $sString)

    $ilParam = DllStructCreate("ptr;dword;ptr") ; ulong_ptr;dword;ptr
    DllStructSetData($ilParam, 1, 1) ; $ilParam, 1, 1
    DllStructSetData($ilParam, 2, DllStructGetSize($tData))
    DllStructSetData($ilParam, 3, DllStructGetPtr($tData))
    _SendMessage($hSciTE, $WM_COPYDATA, $hHandle, DllStructGetPtr($ilParam))
    Return Number(Not @error)
EndFunc   ;==>_SciTE_Send_Command
#region SciTE UDF - Unreleased.

[BrewManNH]

Very usefull!

But save the old clipboard data and put it back after the Controlsend.

Should be easy to modify it to save that information, just add a ClipGet at the start of the script, and a ClipPut just after the paste operation.

Here's an alternate version that preserves the clipboard information, added 2 lines to the script.

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Run_Tidy=y
#Tidy_Parameters=/rel
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/so
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Misc.au3>
Global $Temp = ClipGet() ; <<<<<< Save the clipboard contents to a variable
Opt("WinTitleMatchMode", 2)
$DefaultColor = 0
If $cmdline[0] > 0 Then $DefaultColor = $cmdline[1]
$Return = _ChooseColor(2, $DefaultColor, 2)
If $Return = -1 Then Exit (1)
ClipPut($Return)
Sleep(100)
ControlSend(" SciTE", "", "[CLASS:Scintilla]", "^v")
ClipPut($Temp) ; <<<<<<< Put the original contents of the clipboard back again.

Edited May 24, 2012 by BrewManNH

[guinness]

I forgot to mention thanks for posting BrewManNH.

[jaberwacky]

I am currently working on a version of SciTE for another language (LSL). May I modify this this and include it in distributions?

[BrewManNH]

Anything I post here is free, as in beer, to use where ever (unless otherwise marked), if it's not mentioned, then consider it available to use.

The code added to the properties file is written in a way that you can use it for any language, it's not .au3 specific.

[wraithdu]

Should be easy to modify it to save that information, just add a ClipGet at the start of the script, and a ClipPut just after the paste operation.

Well... not quite. ClipGet() and ClipPut() only work with string data. So if you have anything else on the clipboard like HTML, rich text, or images, those functions won't save / restore it properly.

I wrote some clipboard functions a while back to do this properly. They should work for most formats. I seem to remember some might still fail though, like pure bitmap data. Anyway, give them a try: Clipboard functions

Edited May 24, 2012 by wraithdu

[BrewManNH]

For some reason, on my home computer which is running Windows 7 x86, my work computer runs Windows 7 x64, the Lua script won't run the colorchooser program if you've highlighted any text. To fix this I had to change the command in SciTEUser.properties, see below.

# change this line
command.43.*="$(SciteDefaultHome)ColorChooserColorChooser.exe $(CurrentSelection)"

# to this
command.43.*="$(SciteDefaultHome)ColorChooserColorChooser.exe" $(CurrentSelection)

If it's not working for you with the original line, saying it can't find the file specified, make that change above and try it again, after saving the properties file of course.

[Topher]

Works perfectly, thanks

[BrewManNH]

I've updated the script in the first post, it now uses the DirectorExtension of SciTE to paste the color code into the editor window instead of copying and pasting it from the clipboard. I've also implemented a new feature where if you send it a color code in the format of "FFFFFF" it will return the color code in that format, without the preceeding "0x".

[guinness]

Nice. By the way there is no real need for setting WinTitleMatchMode, I haven't had a problem with the default option.

Edited June 1, 2012 by guinness

[BrewManNH]

I used it that way in the previous script because SciTE's window title changes depending upon what file is open in the main screen, it's an artifact from my original script that's no longer necessary because I don't cut and paste the data any more.

[Chad2]

Just wanted to say Thanks and Very Useful.