A Non-Strict JSON UDF (JSMN)

[mLipok]

Give me few hours.
I will test with my WD related projects.

Edited November 18, 2021 by mLipok

[mLipok]

  On 11/18/2021 at 6:35 PM, mLipok said:

Give me few hours.
I will test with my WD related projects.

Expand  

Works well on 2 advanced WD automation also with my capabilities UDF.

 

[TheXman]

Thanks for the additional testing.

[TheXman]

For anyone who may need it and in response to the above post, I have attached a modified version of the latest UDF that adds 3 new "helper" functions:

1. Json_ArrayAdd(ByRef $Var, $Notation, $Data)
   Adds an item (String, number, object, array, or boolean) to an existing array.
2. Json_ArrayInsert(ByRef $Var, $Notation, $Index, $Data)
   Inserts an array item (String, number, object, array, or boolean) at the specified index.
3. Json_ArrayDelete(ByRef $Var, $Notation, $Range)
   Deletes a single item, a range of items, or multiple items, from an existing array.  The syntax for $Range is the same as _ArrayDelete() since that is what it uses to delete array items.

Note:  Json_ArrayAdd() and Json_ArrayInsert() only allow adding or inserting a single array item (String, number, object, array, or boolean) at a time.

Below are some examples using the functions and the output that's generated

  Reveal hidden contents

expandcollapse popup

#include <Constants.au3>
#include <Array.au3>

#include "Json(with array funcs).au3"

Const $JSON = _
    '{' & _
    '   "description": "Test JSON Dataset",' & _
    '   "author": "TheXman",' & _
    '   "obj_array": [' & _
    '      {"name": "Ben Dover", "email": "bdover@example.com"}' & _
    '   ],' & _
    '   "numeric_array": [1,2,3]' & _
    '}'

example()

Func example()
    Local $oJSON = Null, $o
    Local $sKey = ""
    Local $a[0]

    $oJSON = Json_Decode($JSON)
    If @error Then Exit MsgBox($MB_ICONERROR + $MB_TOPMOST, "ERROR", "Unable to decode JSON")

    ;Display current JSON
    ConsoleWrite("Original JSON" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Add objects to the obj_array
    Json_Put($o, '[0].name' , "Eileen Dover")
    Json_Put($o, '[0].email', "email", "edover@example.com")
    Json_ArrayAdd($oJSON, ".obj_array", $o)

    Json_ArrayAdd($oJSON, ".obj_array", Json_Decode('{"name": "John Doe", "email": "jdoe@example.com"}'))
    
    ConsoleWrite(@CRLF & "2 objects added to obj_array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Delete obj_array index 1
    Json_ArrayDelete($oJSON, ".obj_array", 1)
    ConsoleWrite(@CRLF & "Deleted index 1 from obj_array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Insert obj_array index 0
    Json_ArrayInsert($oJSON, ".obj_array", 0, Json_Decode('{"name": "John Smith", "email": "jsmith@example.com"}'))
    ConsoleWrite(@CRLF & "Inserted index 0 into obj_array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Add numbers to the numeric_array
    Json_ArrayAdd($oJSON, ".numeric_array", 4)
    Json_ArrayAdd($oJSON, ".numeric_array", 5)
    Json_ArrayAdd($oJSON, ".numeric_array", 6)
    ConsoleWrite(@CRLF & "Added 4, 5, 6 to numeric array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Delete indexes 3-5 from numeric array
    Json_ArrayDelete($oJSON, ".numeric_array", "3-5")
    If @error Then Exit MsgBox($MB_ICONERROR + $MB_TOPMOST, "ERROR", "Json_ArrayDelete failed - @error = " & @error)
    ConsoleWrite(@CRLF & "Deleted indexes 3-5 from numeric array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)

    ;Insert 4,5,6 at the beginning of numeric_array
    Json_ArrayInsert($oJSON, ".numeric_array", 0, 4)
    Json_ArrayInsert($oJSON, ".numeric_array", 1, 5)
    Json_ArrayInsert($oJSON, ".numeric_array", 2, 6)
    ConsoleWrite(@CRLF & "Inserted 4,5,6 at the beginning of numeric_array" & @CRLF)
    ConsoleWrite(@CRLF & Json_Encode($oJSON, $JSON_PRETTY_PRINT, "   ") & @CRLF)
EndFunc

 

Output:

  Reveal hidden contents

expandcollapse popup

Original JSON

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "obj_array": [
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      }
   ],
   "numeric_array": [
      1,
      2,
      3
   ]
}

2 objects added to obj_array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "numeric_array": [
      1,
      2,
      3
   ],
   "obj_array": [
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "Eileen Dover",
         "email": "edover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ]
}

Deleted index 1 from obj_array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "numeric_array": [
      1,
      2,
      3
   ],
   "obj_array": [
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ]
}

Inserted index 0 into obj_array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "numeric_array": [
      1,
      2,
      3
   ],
   "obj_array": [
      {
         "name": "John Smith",
         "email": "jsmith@example.com"
      },
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ]
}

Added 4, 5, 6 to numeric array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "obj_array": [
      {
         "name": "John Smith",
         "email": "jsmith@example.com"
      },
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ],
   "numeric_array": [
      1,
      2,
      3,
      4,
      5,
      6
   ]
}

Deleted indexes 3-5 from numeric array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "obj_array": [
      {
         "name": "John Smith",
         "email": "jsmith@example.com"
      },
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ],
   "numeric_array": [
      1,
      2,
      3
   ]
}

Inserted 4,5,6 at the beginning of numeric_array

{
   "description": "Test JSON Dataset",
   "author": "TheXman",
   "obj_array": [
      {
         "name": "John Smith",
         "email": "jsmith@example.com"
      },
      {
         "name": "Ben Dover",
         "email": "bdover@example.com"
      },
      {
         "name": "John Doe",
         "email": "jdoe@example.com"
      }
   ],
   "numeric_array": [
      4,
      5,
      6,
      1,
      2,
      3
   ]
}

 

 

Json(with array funcs).au3Fetching info...

Edited February 22, 2022 by TheXman

[mLipok]

Please consider to add somehing like $__JSONVERSION and $__BinaryCall_VERSION then other UDF (for example WebDriver UDF) can check if they are recent and put the version to console on debuging runs.

This feature could prevent such issues:

https://github.com/Danp2/WebDriver/pull/173#issuecomment-1029042637

Edited February 3, 2022 by mLipok

[mLipok]

I have a problem with Json_ObjGetCount()

Here is my code:

#include "Json.au3"

test5()

Func test5()
    Local $_WD_CAPS__OBJECT
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][0]", 'www.google.com')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][1]", 'www.yahoo.com')
    ConsoleWrite("Test #5 Result: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)

    Local $oTemp

    $oTemp = Json_ObjGet($_WD_CAPS__OBJECT, 'capabilities.firstMatch[0]')
    ConsoleWrite("! " & @CRLF)

    ConsoleWrite("- " & Json_ObjGetCount($oTemp) & @CRLF)

    Local $noProxy = Json_ObjGet($_WD_CAPS__OBJECT, '[capabilities][firstMatch][0][proxy][noProxy]')
    ConsoleWrite("- " & Json_ObjGetCount($noProxy) & @CRLF)


EndFunc   ;==>test5

 

My question is:  How to get number of [noProxy] entries ?

[mLipok]

uff.. 
Found this:
 

Local $noProxy = Json_Get($_WD_CAPS__OBJECT, '[capabilities][firstMatch][0][proxy][noProxy]')
    ConsoleWrite("! $noProxy = " & VarGetType($noProxy) & @CRLF)
    ConsoleWrite(UBound($noProxy) & @CRLF)

 

[Danp2]

  On 3/20/2022 at 10:29 PM, mLipok said:

I have a problem with Json_ObjGetCount()

Expand  

Actually, you need to check for error following the call to Json_ObjGet.

[mLipok]

Why?

[Danp2]

Because it's failing.

[mLipok]

Yes. But for my needs it is not necesary as I check it with UBound()
 

#include "Json.au3"

ConsoleWrite('> #' & test5() & @CRLF)

Func test5()
    Local $_WD_CAPS__OBJECT
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][0]", 'www.google.com')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][1]", 'www.yahoo.com')
    ConsoleWrite("Test #5 Result: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)
    Return UBound(Json_Get($_WD_CAPS__OBJECT, '[capabilities][firstMatch][0][proxy][noProxy]'))
EndFunc   ;==>test5

 

Edited March 20, 2022 by mLipok

[LukeWCS]

  On 11/20/2021 at 8:32 PM, TheXman said:

For anyone who may need it and in response to the above post, I have attached a modified version of the latest UDF that adds 3 new "helper" functions:

Expand  

Hi

Saw today that there is an update on this UDF, thanks TheXman. 

Tested with my mod manager, no problems found. 

 

Edited March 27, 2022 by LukeWCS

[MarcoMonte]

Sorry, I dont understand very well english, I am trying to use webdriver to automate Chrome, I download webdriver but I am keep receveing an error like "#include json.udf" I think it's due to lack of this library, but I cannot find where to get it, Can someone help me? Once I downloaded it I should insert it in the include directory in the autoit directory right?

[Musashi]

  On 3/30/2022 at 12:05 PM, MarcoMonte said:

but I am keep receveing an error like "#include json.udf"

Expand  

The include statement should look like this :

#include "Json.au3"

 

[mLipok]

Does the Json_ObjExists() function should support brace-based notation?

I had some problem with this:

#include "Json.au3"

test5()

Func test5()
    Local $_WD_CAPS__OBJECT
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][alwaysMatch]", '{}')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][0]", 'www.google.com')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][1]", 'www.yahoo.com')
    ConsoleWrite("Test #5 Result: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)
    Local $v_Test

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, '[capabilities][firstMatch]')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.firstMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, '[capabilities][alwaysMatch]')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.alwaysMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

EndFunc   ;==>test5

 

Edited April 8, 2022 by mLipok

[mLipok]

Using Json_ObjExists() I get err that variable must be object.

Should we check IsObj() like this:
 

Func Json_ObjExists(ByRef $Object, $Key)
    If Not IsObj($Object) Then Return False

?

 

[mLipok]

Interesting reading about:  Primitive and compound JSON data types

[mLipok]

  On 4/8/2022 at 6:38 AM, mLipok said:

Using Json_ObjExists() I get err that variable must be object.

Expand  

 

here is my testing script:
 

expandcollapse popup

#include "Json.au3"

test5()

Func test5()
    Local $_WD_CAPS__OBJECT
    Local $v_Test

    Json_Put($_WD_CAPS__OBJECT, '[capabilities]', '{}')
    ConsoleWrite("Test #5 Empty: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.alwaysMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.firstMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)


    Json_Put($_WD_CAPS__OBJECT, "[capabilities][alwaysMatch]", '{}')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][0]", 'www.google.com')
    Json_Put($_WD_CAPS__OBJECT, "[capabilities][firstMatch][0][proxy][noProxy][1]", 'www.yahoo.com')
    ConsoleWrite("Test #5 Result: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)

    $v_Test = UBound(Json_Get($_WD_CAPS__OBJECT, '[capabilities][firstMatch][0][proxy][noProxy]'))
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = UBound(Json_Get($_WD_CAPS__OBJECT, '[capabilities][firstMatch]'))
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, '[capabilities][firstMatch]')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.firstMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, '[capabilities][alwaysMatch]')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.alwaysMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

EndFunc   ;==>test5

I get this error:

"Z:\!!!_SVN_AU3\UDF_Forum\Other_Members\Official_AutoIt_Forum\JSON\Json.au3" (356) : ==> Variable must be of type "Object".:
If $DynObject.Exists($Keys[$x]) Then
If $DynObject^ ERROR

On this line:

Func Json_ObjExists(ByRef $Object, $Key)
    Local $DynObject = $Object
    Local $Keys = StringSplit($Key, ".")
    For $x = 1 To $Keys[0]
        If $DynObject.Exists($Keys[$x]) Then

Here is smaller reproducion script:
 

#include "Json.au3"

test5()

Func test5()
    Local $_WD_CAPS__OBJECT
    Local $v_Test

    Json_Put($_WD_CAPS__OBJECT, '[capabilities]', '{}')
    ConsoleWrite("Test #5 Empty: " & Json_Encode($_WD_CAPS__OBJECT) & @LF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

    $v_Test = Json_ObjExists($_WD_CAPS__OBJECT, 'capabilities.alwaysMatch')
    ConsoleWrite("- " & @ScriptLineNumber &  ' $v_Test = ' & $v_Test  & @CRLF)

EndFunc   ;==>test5

 

[jugador]

@mLipok try with this Json_ObjExists modification

Func Json_ObjExists(ByRef $Object, $Key)
    Local $DynObject = $Object
    Local $Keys = StringSplit($Key, ".")
    For $x = 1 To $Keys[0]
        If $DynObject.Exists($Keys[$x]) Then
            If $x = $Keys[0] Then
                Return True
            Else
                $DynObject = Json_ObjGet($DynObject, $Keys[$x])
                If Not IsObj($DynObject) Then Return False      ;~~~~ add this line to Check if $DynObject is object
            EndIf
        Else
            Return False
        EndIf
    Next
    Return False
EndFunc   ;==>Json_ObjExists

 

[Danp2]

@jugadorThe error occurs earlier in the function, so I don't believe that change will have the desired effect.