A Non-Strict JSON UDF (JSMN)

[DonChunior]

JSON variables with a period in variable names are not supported by the Json_Get function:

#include "Json.au3"

Local $Json = '{"@odata_count": 24,"@odata.count": 24,"@odata-count": 24}'

Json_Dump($Json)

Local $Data = Json_Decode($Json)
If @error Then
    ConsoleWrite("Json_Decode: @error = " & @error & @CRLF)
EndIf

Local $iCount = Json_Get($Data, ".@odata_count")
If @error Then
    ConsoleWrite("Json_Get (1): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

$iCount = Json_Get($Data, ".@odata.count")
If @error Then
    ConsoleWrite("Json_Get (2): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

$iCount = Json_Get($Data, ".@odata-count")
If @error Then
    ConsoleWrite("Json_Get (3): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

The second call of Json_Get results in @error being 1.
Unfortunately, the Open Data Protocol (OData) standard defines some variables that contain a dot in their name (e.g. "@odata.context", "@odata.count", "@odata.id" ...).

[TheXman]

@DonChunior

Using your example, the correct syntax would be:

$iCount = Json_Get($Data, '."@odata.count"')  ;Using dot-notation

or 

$iCount = Json_Get($Data, '["@odata.count"]')  ;Using bracket-notation

If key names contain special characters, such as periods, the key names should be wrapped in double quotes.

Edited August 7 by TheXman

[DonChunior]

19 minutes ago, TheXman said:

@DonChunior

Using your example, the correct syntax would be:

$iCount = Json_Get($Data, '."@odata.count"')  ;Using dot-notation

or 

$iCount = Json_Get($Data, '["@odata.count"]')  ;Using bracket-notation

 

Hi @TheXman,

unfortunately that doesn't work for me. 😕
I'm still getting 1 as @error.

[TheXman]

It works for me.  Below, is your updated script that I ran:

Spoiler

#include "Json.au3"

Global $Json = '{"@odata_count": 24,"@odata.count": 24,"@odata-count": 24}'

Json_Dump($Json)

Global $Data = Json_Decode($Json)
If @error Then
    ConsoleWrite("Json_Decode: @error = " & @error & @CRLF)
EndIf

Global $iCount = Json_Get($Data, ".@odata_count")
If @error Then
    ConsoleWrite("Json_Get (1): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

$iCount = Json_Get($Data, '."@odata.count"')
;~ $iCount = Json_Get($Data, '["@odata.count"]')
If @error Then
    ConsoleWrite("Json_Get (2): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

$iCount = Json_Get($Data, ".@odata-count")
If @error Then
    ConsoleWrite("Json_Get (3): @error = " & @error & @CRLF)
Else
    ConsoleWrite("$iCount = " & $iCount & @CRLF)
EndIf

Output

+-> .@odata_count  =24
+-> .@odata.count  =24
+-> .@odata-count  =24
$iCount = 24
$iCount = 24
$iCount = 24

 

 

Edited August 7 by TheXman

[DonChunior]

Still not for me.
Have you modified (fixed) the UDF in comparison to the original of @Ward?

[TheXman]

I used the most current version posted in the first post. ( _Json(2021.11.20).zip )

Edit:  See my post below to get a copy of the version that I used.

Edited August 7 by TheXman

[Jos]

There's a fix for dot notations in a couple of versions back.

[TheXman]

3 hours ago, DonChunior said:

Have you modified (fixed) the UDF in comparison to the original of @Ward?

I apologize.  I just rechecked my version.  It looks like I did make a small change back in 2022 that fixed this (and other) issues.  I haven't used this UDF for processing JSON datasets in several years, so I must have forgotten about the modification.  Here is the version I used:

Json(2022.09.18).au3

Edited August 7 by TheXman

[mLipok]

Spoiler

On 11/18/2021 at 4:28 PM, TheXman said:

Json (modified).au3Unavailable

We could not locate the item you are trying to view.

 

Sorry, the newer version works.

Edited Sunday at 11:38 PM by mLipok

[mLipok]

I have a question about this following example:

#include "Json.au3"

ConsoleWrite("- Test8() : " & Test8() & @CRLF)

Func Test8()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":{}}'
    Local $Json2 = '{"MainCity":"Paris","MainCountry":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'

    ; Decode
    Local $obj1 = Json_Decode($Json1)
    Local $obj2 = Json_Decode($Json2)
    Local $obj2a = $obj2
    Local $obj3 = Json_Decode($Json3)

    ; Insert obj2 into obj1 under a key (e.g. "location")
    $obj1.Item("locations") = $obj2   ; <-- This puts data into object
    $obj1.Item("locations").Item("location1") = $obj2a  ; <-- This creates a sub-object
    $obj1.Item("locations").Item("location2") = $obj3  ; <-- This creates a sub-object

    ; Encode back to JSON
    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)
EndFunc   ;==>Test8

Why I can't use $obj2a in the same way as I used $obj3.
I know I already used $obj2 but why I can't use them again ?

I know that I can use them like this:

;~  $obj1.Item("locations") = $obj2   ; <-- This puts data into object
    $obj1.Item("locations").Item("location1") = $obj2a  ; <-- This creates a sub-object

But why can't use them together ?

Edited 23 hours ago by mLipok
typo

[mLipok]

I also have other question.

How to connactate this following string

Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'

to get such results:

{"name":"John","age":30,"locations":[{"City":"Paris","Country":"France"},{"City":"London","Country":"England"}]

The previosuly published example did similar things but as result there was "locations" as JSON_OBJECT - a dicionary element in JSON structure,

but this time the "locations" it is an JSON_ARRAY - a list of elements in JSON structure

[Jos]

Something like this ?

#include "Json.au3"

ConsoleWrite("- Test8() : " & Test8() & @CRLF)

Func Test8()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)
    Json_ObjPut($obj1,"locations", Json_Decode("[" & $Json2 & "," & $Json3 & "]"))

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)
EndFunc   ;==>Test8

 

[mLipok]

3 hours ago, Jos said:

Something like this ?

#include "Json.au3"

ConsoleWrite("- Test8() : " & Test8() & @CRLF)

Func Test8()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)
    Json_ObjPut($obj1,"locations", Json_Decode("[" & $Json2 & "," & $Json3 & "]"))

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)
EndFunc   ;==>Test8

 

Simple and effective.

Simply brilliant.
Thanks.

[mLipok]

but I was wondering also about something like this:

#include "Json.au3"

ConsoleWrite("- Test8b() : " & Test8b() & @CRLF)

Func Test8b()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; as for first step I only know the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "]"))

    ; .... and a while later I was notified about new location, so here I try to add them .....
    Local $Json3 = '{"City":"London","Country":"England"}'
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json3 & "]"))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)
EndFunc   ;==>Test8b

as for now with no success

[mLipok]

Your answer inspire me to solve it this way:

#include "Json.au3"

ConsoleWrite("- Test8b() : " & Test8b() & @CRLF)

Func Test8b()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; as for first step I only know the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "]"))

    ; and a while later I was notified about new location, so here to add them

    ; firstly get current known locations
    Local $oLocations = Json_ObjGet($obj1, "locations")
    Local $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)

    ; new location
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    Local $sJson_concatenated = "[" & StringTrimRight($sCurrentLocations, 1) & ',' & $Json3 & "]"
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)
EndFunc   ;==>Test8b

 

[Jos]

Alternatively, you can do something like this to add an location to the Json array:

#include "Json.au3"

ConsoleWrite("- Test8() : " & Test8() & @CRLF)

Func Test8()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    Local $obj1 = Json_Decode($Json1)
    AddLocation($obj1, $Json2)
    AddLocation($obj1, $Json3)
    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)

EndFunc   ;==>Test8

Func AddLocation(ByRef $oObj,$iJson)
    Local $iObj = Json_Decode($iJson)
    Local $City = Json_get($iObj,'.City')
    Local $Country = Json_get($iObj,'.Country')
    ; Find first free slot
    $loccount = 0
    for $Locations in Json_ObjGet($oObj, "locations")
;~      ConsoleWrite('$oObj.locations = ' & Json_Get($Locations, ".City") & "-" & Json_Get($Locations, ".Country") & @CRLF)
        $loccount += 1
    Next
    Json_Put($oObj,".locations[" & $loccount & "].City",$City)
    Json_Put($oObj,".locations[" & $loccount & "].Country",$Country)
EndFunc

- or a bit more compact version:

#Region ; *** Dynamically added Include files ***
#include <APILocaleConstants.au3>                            ; added:11/17/25 16:18:54
#EndRegion ; *** Dynamically added Include files ***
#include "Json.au3"

ConsoleWrite("- Test8() : " & Test8() & @CRLF)

Func Test8()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    Local $obj1 = Json_Decode($Json1)
    AddLocation($obj1, $Json2)
    AddLocation($obj1, $Json3)
    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite($final & @CRLF)

EndFunc   ;==>Test8

Func AddLocation(ByRef $oObj,$iJson)
    Local $iObj = Json_Decode($iJson)
    local $loccount = UBound(Json_ObjGet($oObj, "locations"))
    Json_Put($oObj,".locations[" & $loccount & "].City",Json_get($iObj,'.City'))
    Json_Put($oObj,".locations[" & $loccount & "].Country",Json_get($iObj,'.Country'))
EndFunc

 

Edited 9 hours ago by Jos

[mLipok]

expandcollapse popup

#include "Json.au3"

;~ ConsoleWrite("- Test8a() :"  & @CRLF & Test8a() & @CRLF)
;~ ConsoleWrite("- Test8b() :" & @CRLF & Test8b() & @CRLF)
ConsoleWrite("- Test8c() :"  & @CRLF & Test8c() & @CRLF)

Func Test8a()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "," & $Json3 & "]"))

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8a


Func Test8b()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; as for first step I only know the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "]"))

    ; and a while later I was notified about new location, so here to add them

    ; firstly get current known locations
    Local $oLocations = Json_ObjGet($obj1, "locations")
    Local $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; new location
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    Local $sJson_concatenated = "[" & StringTrimRight($sCurrentLocations, 1) & ',' & $Json3 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8b

Func Test8c()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; add empty "locations" JSOR ARRAY element
    Json_ObjPut($obj1, "locations", Json_Decode('[]'))
    Local $step0 = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $step0= ' & $step0 & @CRLF)

    Local $oLocations, $sCurrentLocations, $sJson_concatenated
    ; get current known locations
    $oLocations = Json_ObjGet($obj1, "locations")
    $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    If $sCurrentLocations = '[]' Then $sCurrentLocations = ''
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; as for first step - here we know only the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    $sJson_concatenated = (($sCurrentLocations) ? (StringTrimRight($sCurrentLocations, 1) & ',') : ('[')) & $Json2 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))

    Local $step1 = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $step1= ' & $step1 & @CRLF)

    ; and a while later I was notified about new location, so here to add them

    ; second step - again get current "Locations" STRING
    $oLocations = Json_ObjGet($obj1, "locations")
    $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    If $sCurrentLocations = '[]' Then $sCurrentLocations = ''
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; new location
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    $sJson_concatenated = (($sCurrentLocations) ? (StringTrimRight($sCurrentLocations, 1) & ',') : ('[')) & $Json3 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8c

as for now I was working on:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/148114-a-non-strict-json-udf-jsmn/page/20/#comment-1547453
#include "Json.au3"

;~ ConsoleWrite("- Test8a() :"  & @CRLF & Test8a() & @CRLF)
;~ ConsoleWrite("- Test8b() :" & @CRLF & Test8b() & @CRLF)
ConsoleWrite("- Test8c() :"  & @CRLF & Test8c() & @CRLF)

Func Test8a()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "," & $Json3 & "]"))

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8a


Func Test8b()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; as for first step I only know the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Json_ObjPut($obj1, "locations", Json_Decode("[" & $Json2 & "]"))

    ; and a while later I was notified about new location, so here to add them

    ; firstly get current known locations
    Local $oLocations = Json_ObjGet($obj1, "locations")
    Local $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; new location
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    Local $sJson_concatenated = "[" & StringTrimRight($sCurrentLocations, 1) & ',' & $Json3 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8b

Func Test8c()
    ; Your three JSON strings
    Local $Json1 = '{"name":"John","age":30}'
    ; Decode
    Local $obj1 = Json_Decode($Json1)

    ; add empty "locations" JSOR ARRAY element
    Json_ObjPut($obj1, "locations", Json_Decode('[]'))
    Local $step0 = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $step0= ' & $step0 & @CRLF)

    Local $oLocations, $sCurrentLocations, $sJson_concatenated
    ; get current known locations
    $oLocations = Json_ObjGet($obj1, "locations")
    $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    If $sCurrentLocations = '[]' Then $sCurrentLocations = ''
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; as for first step - here we know only the first location
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    $sJson_concatenated = (($sCurrentLocations) ? (StringTrimRight($sCurrentLocations, 1) & ',') : ('[')) & $Json2 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))

    Local $step1 = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    ConsoleWrite(@ScriptLineNumber & ' $step1= ' & $step1 & @CRLF)

    ; and a while later I was notified about new location, so here to add them

    ; second step - again get current "Locations" STRING
    $oLocations = Json_ObjGet($obj1, "locations")
    $sCurrentLocations = Json_Encode($oLocations, $JSON_PRETTY_PRINT)
    If $sCurrentLocations = '[]' Then $sCurrentLocations = ''
    ConsoleWrite(@ScriptLineNumber & ' $sCurrentLocations= ' & $sCurrentLocations & @CRLF)

    ; new location
    Local $Json3 = '{"City":"London","Country":"England"}'
    ; concatenate two JSON string, as first is JSON ARRAY object StringTrimRight(*, 1) must bu used
    $sJson_concatenated = (($sCurrentLocations) ? (StringTrimRight($sCurrentLocations, 1) & ',') : ('[')) & $Json3 & "]"
;~  ConsoleWrite(@ScriptLineNumber & ' $sJson_concatenated= ' & $sJson_concatenated & @CRLF)
    Json_ObjPut($obj1, "locations", Json_Decode($sJson_concatenated))
    ; issue: it replace it instead add new object to the array

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8c

but yours solutions looks nice.
Will take a look on them.

Edited 8 hours ago by mLipok

[mLipok]

So here is my recent snippet which uses  new function:  Json_ArrayPut() inspired by @Jos  AddLocation()

expandcollapse popup

#include "Json.au3"
ConsoleWrite("- Test8d() :" & @CRLF & Test8d() & @CRLF)

Func Test8d()
    ; Your three JSON strings
;~  Local $Json1 = '{"name":"John","age":30,"locations":[]}'
    Local $Json1 = '{"name":"John","age":30}'
    Local $Json2 = '{"City":"Paris","Country":"France"}'
    Local $Json3 = '{"City":"London","Country":"England"}'

    ; create object from first JSON string
    Local $obj1 = Json_Decode($Json1)
    ConsoleWrite('counting elements in "locations" = ' & UBound(Json_ObjGet($obj1, "locations")) & ' ERR=' & @error & ' EXT=' & @extended & @CRLF)

    ; add second JSON string to the object as an last elemnt of "JSON_ARRAY" structure called "locations"
    Json_ArrayPut($obj1, "locations", $Json2)
;~  Json_ArrayPut($obj1, "locations.main", $Json2)
    ConsoleWrite('counting elements in "locations" = ' & UBound(Json_ObjGet($obj1, "locations")) & ' ERR=' & @error & ' EXT=' & @extended & @CRLF)

    ; add third JSON string to the object as an last elemnt of "JSON_ARRAY" structure called "locations"
    Json_ArrayPut($obj1, "locations", $Json3)
;~  Json_ArrayPut($obj1, "locations.addtional", $Json3)
    ConsoleWrite('counting elements in "locations" = ' & UBound(Json_ObjGet($obj1, "locations")) & ' ERR=' & @error & ' EXT=' & @extended & @CRLF)

    Local $final = Json_Encode($obj1, $JSON_PRETTY_PRINT)
    Return $final
EndFunc   ;==>Test8d

Func Json_ArrayPut(ByRef $oObj, $Key, $vJson_toAdd)
    Json_IsObject($oObj)
    If @error Then Return SetError(1, 1)
;~  Local $current = Json_Encode($oObj, $JSON_PRETTY_PRINT)
;~  ConsoleWrite('$current = ' & $current & @CRLF)
;~  ConsoleWrite('$vJson_toAdd = ' & $vJson_toAdd & @CRLF)

    Local $count = UBound(Json_ObjGet($oObj, $Key))
;~  ConsoleWrite($count & @CRLF)
;~  ConsoleWrite(VarGetType($aFound) & @CRLF)

    Local $oJson_snippet
    If (IsString($vJson_toAdd) And StringLen($vJson_toAdd)) Then
        $oJson_snippet = Json_Decode($vJson_toAdd)
        If @error Then Return SetError(3, 3)
    ElseIf Json_IsObject($vJson_toAdd) Then
        $oJson_snippet = $vJson_toAdd ; just $vJson_toAdd be passed to Json_Put()
    Else
        Return SetError(4, 3)
    EndIf

    Json_Put($oObj, "." & $Key & "[" & $count & "]", $oJson_snippet)
    If @error Then Return SetError(5, 0)
EndFunc   ;==>Json_ArrayPut