Is user is asked for a number, is there any easy way to add a "0" and "00" to numbers below 100 ("0" for 1-9, "00" for 10-99)?

[Diana (Cda)]

If I have this in my GUI and numbers are asked for:

$Input1 = GUICtrlCreateInput("", 15, 40, 30, 25)     ; left, top, width, height

which is then output like this:

ClipPut("Pg." & GUICtrlRead($Input1) & "- " & $StandardDateSHORT & ".pdf")

is there an easy way to ensure if the input is less than 100, i.e., 1-99, that a zero gets added to 1-9 and two zeros before 10-99 automatically without the user worrying about any of that?

I ask because sometimes code to do this is easy - i.e., in my MP3 tag app, I just have to choose the right syntax for this type of thing to happen automatically, zero padding or soemthing I think it's called.

Just wondering if there was something easy enough to build right into my AutoIt GUI to ensure that any number comes out in the right format without bother to the user.

No worries if not, just would like to make this GUI truly automated in its output.

Thank you!

[mLipok]

_AddLeadingZeros() ??

[Melba23]

Diana (Cda),

StringFormat is what you need:

#include <MsgBoxConstants.au3>

MsgBox($MB_SYSTEMMODAL, "0 Padded", StringFormat("%03i", 9) & @CRLF & StringFormat("%03i", 10))

%    - Format code string begins
0    - Add leading zeros...
3    - ...to make string this length
i    - Use integer format

M23

[Malkey]

I'll 'ave a go,

; "...if the input is less than 100, i.e., 1-99, that a zero gets added to 1-9 and
; two zeros before 10-99 automatically..."

Local $iNumber = 8, $sNum = $iNumber

If $iNumber >= 1 And $iNumber <= 9 Then $sNum = "0" & $iNumber
If $iNumber > 9 And $iNumber <= 99 Then $sNum = "00" & $iNumber

MsgBox(1, "Padded Zeros Mk1", $sNum)
;---------------------------------------------------------------------

;or
Local $iNumber = 8
MsgBox(1, "Padded Zeros Mk2", (($iNumber >= 1 And $iNumber <= 9) ? "0" : (($iNumber > 9 And $iNumber <= 99) ? "00" : "")) & $iNumber)

#cs  Test Results:-
    Number    Result
     -8          -8    ; Out of range
      8          08     ; A zero gets added to 1-9
     58        0058    ; Two zeros before 10-99
    108         108    ; Out of range
#ce

or two.

[Diana (Cda)]

I'll 'ave a go,

; "...if the input is less than 100, i.e., 1-99, that a zero gets added to 1-9 and
; two zeros before 10-99 automatically..."

Local $iNumber = 8, $sNum = $iNumber

If $iNumber >= 1 And $iNumber <= 9 Then $sNum = "0" & $iNumber
If $iNumber > 9 And $iNumber <= 99 Then $sNum = "00" & $iNumber

MsgBox(1, "Padded Zeros Mk1", $sNum)
;---------------------------------------------------------------------

;or
Local $iNumber = 8
MsgBox(1, "Padded Zeros Mk2", (($iNumber >= 1 And $iNumber <= 9) ? "0" : (($iNumber > 9 And $iNumber <= 99) ? "00" : "")) & $iNumber)

#cs  Test Results:-
    Number    Result
     -8          -8    ; Out of range
      8          08     ; A zero gets added to 1-9
     58        0058    ; Two zeros before 10-99
    108         108    ; Out of range
#ce

or two.

 

Thanks so much, Malkey!  The second one looked like the most recyclable for me.  But it seems like I'm doing something wrong again <sigh>.  I've tried every which way I can think of to balance the brackets, as I'm getting a balance brackets error, but no go.  My lack of actual programming training again, I guess, despite being a power user.

Here is how I structured it to use and re-use, and once the brackets are balanced, I think and hope it'll work really nicely.

p.s., I always use $input1 for input GUIs, so it's safe to keep that.  And putting the variable as $ZeroPadding seems like the easiest for me to work with down the road.  Anyway, here's what I have translated so far into the GUI and, if I've interpreted this correctly (?), I think should work once fixed (?):

$ZeroPadding = ($Input1 >= 1 And $Input1 <= 9) ? "00" : (($Input1 > 9 And $Input1 <= 99) ? "0" : "")) & $Input1)
;----------------------------------------------------------------------------------------------------------------------------
ClipPut("Pg." & GUICtrlRead($ZeroPadding) & "- " & $StandardDateSHORT & ".pdf")

Oh, I did change the zeroes for the zero padding.  Since I need 3 places, 1-9 get 2 zeroes, and 10-99 gets only one.  That's the only change to the output format.  That way, I'll always get something like this:  001, 002, 003, 010, 019, 029, 044, 179, 832 ...

I'm not worrying yet about going above 999 (i.e., going into 4 number places) at this time.  I guess I'll know soon enough if I have the potential to generate more than 999 log pages; if that turns out to be the case, I'm guessing I can adjust that padding by adding an extra zero to each of the 2 items above in the $ZeroPadding line, as well as adding a reference to >999, somehow ...

Thank you!

Edited November 25, 2014 by Diana (Cda)

[Gianni]

I think this is what you need

ClipPut("Pg." & StringFormat("%03i", GUICtrlRead($Input1)) & "- " & $StandardDateSHORT & ".pdf")

[Malkey]

Hoping you will find what you can use in this example.

Local $Input1 = 8

#cs This following example returns :-
     8 to   08
    67 to 0067
    I believe this format was asked for in Post#1
#ce
$ZeroPadding = (($Input1 >= 1 And $Input1 <= 9) ? "0" : (($Input1 > 9 And $Input1 <= 99) ? "00" : "")) & $Input1
ConsoleWrite($ZeroPadding & @LF)
ConsoleWrite("-----------" & @LF)
; =======================================================================

#cs The following examples returns :-
     8 to 008
    67 to 067
#ce
$ZeroPadding = (($Input1 >= 1 And $Input1 <= 9) ? "00" : (($Input1 > 9 And $Input1 <= 99) ? "0" : "")) & $Input1
ConsoleWrite($ZeroPadding & @LF)
; ---------------- or ----------------------

$ZeroPadding = StringRight("000" & $Input1, 3) ; Returns the right most 3 characters.
ConsoleWrite($ZeroPadding & @LF)
; ---------------- or ----------------------

; Use StringFormat() function as Melba post#3 and Chimp post#6 have done.

[TheSaint]

I've only scanned this question quickly, but I always just use a very simple StringRight method.

$num = StringRight("00" & $num, 3)

If $num is a single digit, then two zero's are added at start.

If $num is two digits, then one zero is added at start.

This is because the function reads number of characters from right to left, and any extra to the left is omitted.

This is very flexible, because if you wish your String to be four numbers, you just pad with an extra zero and increase the count, and so on.

$num = StringRight("000" & $num, 4)

P.S. In your case, if you are only after two digits, then it is - $num = StringRight("0" & $num, 2)

Edited November 27, 2014 by TheSaint

[kylomas]

Dana,

See M23's response (#3).  It is no more complicated than this... 

ClipPut("Pg." & stringformat('%03i',GUICtrlRead($Input1)) & "- " & $StandardDateSHORT & ".pdf")

kylomas

edit:

1-99, that a zero gets added to 1-9 and two zeros before 10-99

 

Do you really mean...

 1-99, that two zeros gets added to 1-9 and one zeros before 10-99

Edited November 28, 2014 by kylomas

[Gianni]

Dana,

See M23's response (#3).  It is no more complicated than this... 

ClipPut("Pg." & stringformat('%03i',GUICtrlRead($Input1)) & "- " & $StandardDateSHORT & ".pdf")

kylomas

....

 

it looks similar to post6 

[kylomas]

@Chimp - Yea, sorry, I missed your post...

[Diana (Cda)]

 

I think this is what you need

ClipPut("Pg." & StringFormat("%03i", GUICtrlRead($Input1)) & "- " & $StandardDateSHORT & ".pdf")

 

So sorry for delay in responding back.  I've been having crazy days again.  I think I broke a record recently - last week doesn't count as I was sick one day (so only a 44-hour, 4-day week there! <lol>), but the week before my Nexus work logger app is telling me I worked 71 hours and 14 minutes!!!  And it's been 2 months of craziness here where I work with those kinds of crazy hours <lol>. But I'm sure many of you can really relate to that ... <g>  But what a nice surprise to come here to try to catch up on things and find the perfect solution!  Woohoo!

<dancing a jig> - that code above is BRILLIANTLY simple!!  LOVE IT!  Easy peasy and it's done!  I just tried it and it tests out beautifully.  And since this script helps with an important task in my time management system, this just got streamlined down to nothing.  <sigh>

Thank you, Chimp, this is a super nifty solution and very much appreciated!  I'm saving this to my code snippets folder which always carry full references with including name, URLs, dates, times, so I'll always know who provided this lovely line that now truly allows me to just get the filename with path and off the document goes to it's safe saving spot!

Thanks so much!

Edited December 19, 2014 by Diana (Cda)

[Diana (Cda)]

Thank you, everyone!  Your help was very much appreciated.  This works beautifully now with no user editing necessary script has been run.

Cheers!

[Gianni]

you are welcome
 

Edited December 20, 2014 by Chimp

[Guest]

If you want immediate change then try this example:

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 186, 84, 192, 124)
$Input1 = GUICtrlCreateInput("00", 64, 16, 49, 37, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER,$ES_NUMBER))
GUICtrlSetFont(-1, 18, 400, 0, "MS Sans Serif")
;GUICtrlSetLimit(-1,3)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
    $Input1Read = GUICtrlRead($Input1)
    $tmp1 = StringFormat("%03i", $Input1Read)
    If $Input1Read <> $tmp1 Then GUICtrlSetData($Input1,$tmp1)
    If $Input1Read > 99 Then GUICtrlSetData($Input1,099)
    $nMsg = GUIGetMsg()


    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd