Maps 101: All you need to know about them!

[TheDcoder]

Hello Again! I previously stumbled upon a topic asking for maps datatype's instructions... I too wasn't sure what a map is until I tried it... So I am making this topic to help other newbies (and some oldbies) better understand the Maps datatype of AutoIt! Lets start!

A Note for Readers

The maps datatype is still in development and is currently in Alpha Stage (More Risky than Beta) and its unstable, so AutoIt can crash indefinably while using Maps! I can't guarantee if this will be implemented in stable versions, this is a fairly new thing to AutoIt coders & in my honest opinion I don't see any use for it Maps are the best datatype in AutoIt, Very Useful ... Not hurting anyone though .  Also the maps datatype is DISABLED IN STABLE VERSIONS, So you need to install the latest beta version of AutoIt to make maps work . If you find any bugs while using a map, please report it in the Official Bug Tracker

Introduction To Maps

Maps are just like arrays, instead they use "keys" to access elements inside them... A key can be either a string or an integer (Other datatypes work too but they are converted to a integer [Equivalent to Int($vKey)] before assignment [Source]). Although Integers don't represent the order of elements in a map unlike in an array...

Declaring Maps

Its similar to declaring an Array:

; This is the only way to declare a map
; You must have a declarative keyword like Dim/Global/Local before the declaration unless the map is assigned a value from a functions return

Local $mMap[] ; Don't insert any numbers or strings it!

Simple, Isn't it?

Using Maps

Using maps is similar to arrays (again!):

Local $mMap[] ; Lets declare our map first!

; Adding data to maps is easy...

; This is our key
;       |
;       v
$mMap["Key"] = "Value" ; <--- And our value!

; A key is Case-Sensitive meaning "Key" is not same as "key"!

$mMap["key"] = "value" ; Not the same as $mMap["Key"]!

; There are 2 different ways to access an element in a map

$mMap["Key"] ; 1st Method
$mMap.Key    ; 2nd Method

 Enumerating Maps

Its quite easy to enumerate through arrays but what about maps? how can I enumerate through them!?

#include <MsgBoxConstants.au3>

; Lets create our map first
Local $mMap[]

; Lets add some information to the map, feel free to modify & add new elements
$mMap["Name"] = "Damon Harris"
$mMap["Alias"] = "TheDcoder"
$mMap["Gender"] = "Male"
$mMap["Age"] = 14
$mMap["Location"] = "India"

$aMapKeys = MapKeys($mMap) ; MapKeys function returns all the keys in the format of an array
Local $sProfile = "Profile of " & $mMap["Name"] & ':' & @CRLF ; We will use this string later

For $vKey In $aMapKeys ; We use this to get the keys in a map :)
    $sProfile &= @CRLF & $vKey & ': ' & $mMap[$vKey] ; Add some details to the profile string using our map!
Next

MsgBox($MB_ICONINFORMATION + $MB_OK, "Profile", $sProfile) ; Finally display the profile :)

It is easy as always

Multi-Dimensional Maps

Now now... I know that you are a little confused that how can an multi-dimensional maps exist... Although I am not 100% sure if its called that but lets continue:

#include <MsgBoxConstants.au3>

; Multi-Dimensional maps are just maps in a map

Local $mMapOfMapsvilla[] ; This map will store an other map

Local $mParkMap[] ; This Park map will be inserted in the Mapsvilla's map :P

$mMapOfMapsvilla["Map Item 1"] = "Town Hall"
$mMapOfMapsvilla["Map Item 2"] = "Police Station"
$mMapOfMapsvilla["Map Item 3"] = "Shopping Mall"
$mMapOfMapsvilla["Map Item 4"] = "Residential Area"
$mMapOfMapsvilla["Map Item 5"] = "Park"

$mParkMap["Map Item 1"] = "Cottan Candy Stand"
$mParkMap["Map Item 2"] = "Public Toilet"
$mParkMap["Map Item 3"] = "Woods"

$mMapOfMapsvilla.Park = $mParkMap

MsgBox($MB_OK, "Map Location", $mMapOfMapsvilla["Map Item 1"]) ; Will display Town Hall
MsgBox($MB_OK, "Map Location", $mMapOfMapsvilla.Park["Map Item 1"]) ; Will display Cottan Candy Stand

I am sure its easy for you to understand now

Frequently Asked Questions (FAQs) & Their answers

Q #1. Help! My code does not respond to anything (or) I get an "Variable subscript badly formatted" error on the line of declaration...
A. DONT USE F5 or Go, Instead use Alt + F5 or Tools -> Beta Run in SciTE (Make sure that you have Beta installed)

Q #2. Why are you using "m" in-front of every map variable?
A. Best coding Practices: Names of Variables 

Q #3. What are "Elements" which you mention frequently???
A. This is a newbie question (I have no intention of insulting you ), so I guess you are new to programming. "Elements" are data slots inside a Map (or an Array), you can imagine elements as individual variable which are stored in a Map. You can access them using "keys", Please refer to "Introduction to Maps" section at the starting of this post

Q #4. Are Maps faster than Arrays?
A. You need to understand that Maps have different purpose than Arrays. Maps are designed to store data dynamically (like storing information for certain controlIDs of GUI) and Arrays are designed to store data in a order (for instance, Storing every character of a string in an element for easy access). If you still want to know then if Maps are faster, then the answer is maybe... Maps are *supposed* (I am not sure ) to be faster in addition of elements (while Arrays are painfully slow while adding or removing elements). Here (Post #24) is a benchmark (Thanks kealper! )

 

More FAQs coming soon! Feel free to ask a question in the mean while

Edited January 29, 2016 by TheDcoder
Modified "Introduction To Maps" about using other datatypes as keys...

[TheDcoder]

I am lucky because:

1. The above post was my 1123rd post
2. I completed the post just before deadline

I hope you may enjoy the read, TD

[ViciousXUSMC]

Wow this looks cool, I am sure it will come in handy.  I just sort of got comfortable with Arrays not too long ago, I assume that Maps are going to be sort of like RegEx.

"The best practice is to not use them unless you need them" and still stick to Arrays for most tasks.

I would love to see some real life examples however of where a map can more easily do what an array could not so that I can sort of wrap my head around when this would be best used or make a task easier. 

[TheDcoder]

I can't think use of maps too , But I guess I will eventually discover its use

[iamtheky]

use a For..In Loop, instead of a For...To Loop.     Unless thats bad form, imho it looks cleaner.

[JohnOne]

$mParkMap["Map Item 1"] = "Cottan Candy Stand"
$mParkMap["Map Item 2"] = "Public Toilet"
$mMapOfMapsvilla["Map Item 3"] = "Woods"

I don't get that bit.

Are you deliberately moving the woods in the park to the shopping mall in mapsvilla?

[TheDcoder]

@JohnOne People in the shopping mall wanted some sandal wood

@boththose How can I get the key to the element if I use For...In?

Edited October 22, 2015 by TheDcoder
forgot to reply boththose

[iamtheky]

#include <MsgBoxConstants.au3>

; Lets create our map first
Local $mMap[]

; Lets add some information to the map, feel free to modify & add new elements
$mMap["Name"] = "Damon Harris"
$mMap["Alias"] = "TheDcoder"
$mMap["Gender"] = "Male"
$mMap["Age"] = 14
$mMap["Location"] = "India"

$aMapKeys = MapKeys($mMap) ; MapKeys function returns all the keys in the format of an array
Local $sProfile = "Profile of " & $mMap[$aMapKeys[0]] & ':' & @CRLF ; We will use this string later

For $Key In $aMapKeys
    msgbox(0, '' , $Key & " = " & $mMap[$Key])
next

 

[TheDcoder]

@boththose

[iamtheky]

You can also keep your Funcs in your map with your data

; Lets create our map first
Local $mMap[]

; Lets add some information to the map, feel free to modify & add new elements
$mMap["Name"] = "Damon Harris"
$mMap["Alias"] = "TheDcoder"
$mMap["Gender"] = "Male"
$mMap["Age"] = 14
$mMap["Location"] = "India"
$mMap["Keys"] = MapKeys($mMap)


For $Key In $mMap["Keys"]
    If $Key <> "Keys" Then msgbox(0, '' , $Key & " = " & $mMap[$Key])
next

 

Edited October 22, 2015 by boththose

[TheDcoder]

@boththose Nice trick , But I will implement it in another example

[guinness]

I really don't like documenting alpha (not beta) functionality in the open Forum, because it's suggesting that this will at some point be included in a future release of AutoIt, unless @TheDcoder has been told something I don't know about?!

[TheDcoder]

@guinness I think I will update the introduction to be more specific on the current stage of development of maps

@TheDcoder has been told something I don't know about?!

Ummm... Maybe.... Maybe Not

[iamtheky]

i would want to explore maps in maps to achieve the OP.  start at the smallest unit throwing them into larger and larger containers..

Local $mMapGlo[]
Local $mMapLocAus[]
Local $mMapLocDal[]
Local $mMapPersonNorth[]
Local $mMapPersonSouth[]
Local $mMapPersonDallas[]


$mMapPersonNorth["Jeff"] = "Jeff in N. Austin"
$mMapPersonSouth["Jack"] = "Jack in S. Austin"
$mMapPersonDallas["John"] = "John in Dallas"

$mMapLocAus["NorthAus"] = $mMapPersonNorth
$mMapLocAus["SouthAus"] = $mMapPersonSouth
$mMapLocDal["Dallas"] = $mMapPersonDallas

$mMapGlo["CentralTx"] = $mMapLocAus
$mMapGlo["NorthTx"] = $mMapLocDal


For $loc in $mMapGlo
    For $key in mapkeys($loc)
        For $item in $loc[$key]
            msgbox(0, '' , $key & @LF & $item)
        Next
    Next
next

 

[matwachich]

I think I found a maps usage

Need feedback

[Luigi]

Its very similar to Scripting.Dictionary!

I thinking maps is recursive, it is?

[TheDcoder]

@Luigi Yes

 

I am happy to see people discovering new things with maps! Keep up the good work guys!

[MartinMarris]

Are Maps similar to dynamic arrays? If you are inserting or deleting from a Map, does it work faster than an array?

[iamtheky]

maps are similar to scripting.dictionary which is similar to an ini which i guess is similar to a 2D array with equal signs?

Edited November 11, 2015 by boththose

[TheDcoder]

@MartinMarris  I thinks its a yes... I am not familiar with the concept of dynamic arrays but a quick google search explained me about them, though I didn't use them, I can say that a Map is similar (not same) to dynamic arrays, Resizing a map (i.e adding or removing elements from it) is faster compared to arrays.

 

Sorry for late reply, I was busy, TD