Jump to content

EXAMPLE: XLS , MDB from scratch with ADOX

mLipok

By mLipok
in AutoIt Example Scripts

 Share

Recommended Posts

mLipok Universalist

mLipok

Posted
Posted (edited)

A one user ask about Creating XLS file with ADO.

 

This was interesting to me so I use uncle google and find this:

https://forums.autodesk.com/t5/visual-basic-customization/ado-connection-create-file-excel/td-p/1675928

EDIT: https://msdn.microsoft.com/en-us/library/ms675849(v=vs.85).aspx

 

How you can read in this mentioned above link, This is not posible with ADO but quite easy with ADOX.

Here is AutoIt example: 

;~ https://forums.autodesk.com/t5/visual-basic-customization/ado-connection-create-file-excel/td-p/1675928
;~ https://msdn.microsoft.com/en-us/library/ms675849(v=vs.85).aspx

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

Global Const $ADO_adInteger = 3
Global Const $ADO_adVarWChar = 202

#include <Array.au3>
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    #forceref $oErrorHandler

    Local $oConnection = ObjCreate('ADODB.Connection')
    Local $oCatalog = ObjCreate('ADOX.Catalog')
    Local $oTable = ObjCreate('ADOX.Table')
    ; Local $oColumn = ObjCreate('ADOX.Column')

    $oConnection.open("Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & @ScriptDir & '\ADOX_EXAMPLE__MyContacts.xls' & ";Extended Properties=Excel 8.0")
    $oCatalog.ActiveConnection = $oConnection

    With $oTable
        .Name = "MyContacts"
        .ParentCatalog = $oCatalog
        
        ; Create fields and append them to the new Table object.
        .Columns.Append("ContactId", $ADO_adInteger)
        .Columns.Append("CustomerID", $ADO_adVarWChar, 16)
        
        ; Make the ContactId column and auto incrementing column
        .Columns("ContactId").Properties("AutoIncrement") = True
                
        ; Create fields and append them to the new Table object.
        .Columns.Append("FirstName", $ADO_adVarWChar, 80)
        .Columns.Append("LastName", $ADO_adVarWChar, 80)
        .Columns.Append("Phone", $ADO_adVarWChar, 20)
        .Columns.Append("Notes", $ADO_adVarWChar)
    EndWith

    $oCatalog.Tables.Append($oTable)

    ;Clean up
    $oConnection.Close

    $oConnection = Null
    ; $oColumn = Null
    $oTable = Null
    $oCatalog = Null
EndFunc    ;==>_Example


; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc    ;==>_ErrFunc

 

Have fun,
mLipok

Edited by mLipok
Title changed - mdb

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

mLipok Universalist

mLipok

Posted
  • Author
Posted (edited)

Some time ago I asked on the forum: how to make SQL Schema comparison of the two databases.
Now Thanks to ADOX I think this is possible to enumerate each DB element and store information about it to XML file.
In that case this will be easy to compare 2 separate XML files at least with WinMerge.
I hope that before the beginning of summer I can do it.

EDIT:
Reference:

https://msdn.microsoft.com/en-us/library/ms254934(v=vs.110).aspx

https://msdn.microsoft.com/en-us/library/cc668760(v=vs.110).aspx

 

EDIT2:

Save Recordsets To/Load Recordsets From XML Files Using ADO 2.5:
http://www.freevbcode.com/ShowCode.asp?ID=312

http://www.freevbcode.com/ShowCode.asp?ID=1204

Persisting Records in XML Format
https://msdn.microsoft.com/en-us/library/ms681538(v=vs.85).aspx

Saving to the XML DOM Object
https://msdn.microsoft.com/en-us/library/ms675954(v=vs.85).aspx

Schema Section
https://msdn.microsoft.com/en-us/library/ms675943(v=vs.85).aspx
 

Hierarchical Recordsets in XML
https://msdn.microsoft.com/en-us/library/ms676166(v=vs.85).aspx

Edited by mLipok

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

  • 3 weeks later...
mLipok Universalist

mLipok

Posted
  • Author
Posted

Here is new version of this example. Now also with MS ACCESS file: 

;~ https://forums.autodesk.com/t5/visual-basic-customization/ado-connection-create-file-excel/td-p/1675928
;~ https://msdn.microsoft.com/en-us/library/ms675849(v=vs.85).aspx

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

Global Const $ADO_adInteger = 3
Global Const $ADO_adVarWChar = 202
Global Const $ADOX_adPermObjTable = 1 ; The object is a table.
Global Const $ADOX_adAccessRevoke = 4 ; Any explicit access rights of the group or user will be revoked.
Global Const $ADOX_adRightFull = 268435456 ;            (&H10000000)The user or group has all permissions on the object.

#include <Array.au3>
#include <MsgBoxConstants.au3>

_Example_XLS()
_Example_ACCESS()

Func _Example_XLS()
    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    #forceref $oErrorHandler

    Local $oConnection = ObjCreate('ADODB.Connection')
    Local $oCatalog = ObjCreate('ADOX.Catalog')
    Local $oTable = ObjCreate('ADOX.Table')
    ; Local $oColumn = ObjCreate('ADOX.Column')

    $oConnection.open("Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & @ScriptDir & '\ADOX_Example_XLS__MyContacts.xls' & ";Extended Properties=Excel 8.0")
    $oCatalog.ActiveConnection = $oConnection

    With $oTable
        .Name = "MyContacts"
        .ParentCatalog = $oCatalog

        ; Create fields and append them to the new Table object.
        .Columns.Append("ContactId", $ADO_adInteger)
        .Columns.Append("CustomerID", $ADO_adVarWChar, 16)

        ; Make the ContactId column and auto incrementing column
        .Columns("ContactId").Properties("AutoIncrement") = True

        ; Create fields and append them to the new Table object.
        .Columns.Append("FirstName", $ADO_adVarWChar, 80)
        .Columns.Append("LastName", $ADO_adVarWChar, 80)
        .Columns.Append("Phone", $ADO_adVarWChar, 20)
        .Columns.Append("Notes", $ADO_adVarWChar)
    EndWith

    $oCatalog.Tables.Append($oTable)

    ;Clean up
    $oConnection.Close

    $oConnection = Null
    ; $oColumn = Null
    $oTable = Null
    $oCatalog = Null
EndFunc   ;==>_Example_XLS

Func _Example_ACCESS()
    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    #forceref $oErrorHandler

    ; https://msdn.microsoft.com/en-us/library/ms680934(v=vs.85).aspx
    Local $oCatalog = ObjCreate('ADOX.Catalog')
    Local $oTable = ObjCreate('ADOX.Table')
    ; Local $oColumn = ObjCreate('ADOX.Column')

    FileDelete('Example_from_AutoIt.mdb')
;~  Local $sConnectionString = "Driver={Microsoft Access Driver (*.mdb, *.accdb)};Data Source=Example_from_AutoIt.mdb"
;~  Local $sConnectionString = "Driver={Microsoft Access Driver (*.mdb)};Data Source=Example_from_AutoIt.mdb"
;~  Local $sConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=Example_from_AutoIt.mdb"
    Local $sConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=Example_from_AutoIt.mdb"
    Local $oConnection = $oCatalog.Create($sConnectionString)
    With $oTable
        .Name = "MyContacts"
        .ParentCatalog = $oCatalog

        ; Create fields and append them to the new Table object.
        .Columns.Append("ContactId", $ADO_adInteger)
        .Columns.Append("CustomerID", $ADO_adVarWChar, 16)

        ; Make the ContactId column and auto incrementing column
        .Columns("ContactId").Properties("AutoIncrement") = True

        ; Create fields and append them to the new Table object.
        .Columns.Append("FirstName", $ADO_adVarWChar, 80)
        .Columns.Append("LastName", $ADO_adVarWChar, 80)
        .Columns.Append("Phone", $ADO_adVarWChar, 20)
        .Columns.Append("Notes", $ADO_adVarWChar)
    EndWith

    $oCatalog.Tables.Append($oTable)

    #Region something not working here yet - work in progress
    ; Groups and Users Append, ChangePassword Methods Example (VB)
    ; https://msdn.microsoft.com/en-us/library/ms678350(v=vs.85).aspx
;~  Local $oUser = ObjCreate('ADOX.User')
;~  $oUser.Name = 'AutoIt'
;~  $oUser.ChangePassword("", "Forum")
;~  Local $oUsers_coll = $oCatalog.Users
;~  $oUsers_coll.Refresh()
;~  MsgBox(0, '', $oUsers_coll.Count)
;~  $oCatalog.Groups.Append("Accounting")
;~  $oCatalog.Users.Append("AutoIt2","Forum")

    ; GetPermissions and SetPermissions Methods Example (VB)
    ; https://msdn.microsoft.com/en-us/library/ms677537(v=vs.85).aspx
;~  $oCatalog.Users("AutoIt").SetPermissions("MyContacts", $ADOX_adPermObjTable, $ADOX_adAccessRevoke, $ADOX_adRightFull)
    #EndRegion something not working here yet - work in progress

    ;Clean up
    $oConnection.Close

    $oConnection = Null
    $oTable = Null
    $oCatalog = Null
EndFunc   ;==>_Example_ACCESS

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

 

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

  • 4 months later...

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing
×
×
  • Create New...