AutoIt3_x64.exe crashing @ Windows 10 x64

[Azevedo]

I'm trying to run this script with AutoIt3_x64.exe but it always crashes. It only works If I run with AutoIt3.exe.

Windows 10 x64.

[Azevedo]

Hello?

 

[Danp2]

You should try to determine which line is causing the error. Just guessing, but the issue is probabl related to the structure definition and the difference in field sizes between 32 / 64 bit.

[jchd]

I can't make it crash (W7 x64) as x64 nor x32. Anyone having the same issue?

[Jos]

2 hours ago, Azevedo said:

Hello?

Impatient?

When running scripts that contains DLLCall's, you are expected to understand what you are doing as that can easily cause a crash when the you cause memory corruption or invalid field lenghts used in x86/x64. 
So first thing to do is check for the proper definitions in the DllStructCreate() and DllCall() statements.

Jos

Edited April 21, 2017 by Jos

[mLipok]

4 minutes ago, jchd said:

I can't make it crash (W7 x64) as x64 nor x32. Anyone having the same issue?

Also I can't crash this script.

 

[Jos]

3 minutes ago, jchd said:

I can't make it crash (W7 x64) as x64 nor x32. Anyone having the same issue?

It has a pretty hard crash:

--> Press Ctrl+Alt+END to Restart or Ctrl+Break -or- Ctrl+END to Stop
!>16:49:53 AutoIt3.exe ended.rc:-1073741819

Jos

[Jos]

Try this version:

expandcollapse popup

#AutoIt3Wrapper_UseX64=y
#include <WinAPI.au3>
#include <WindowsConstants.au3>
HotKeySet('{ESC}', '_Close')

;~ If Not IsDeclared('WM_MOUSEWHEEL') Then Global Const $WM_MOUSEWHEEL = 0x020A
Global Const $tagMSLLHOOKSTRUCT = _
    $tagPOINT & _
    ';uint mouseData;' & _
    'uint flags;' & _
    'uint time;' & _
    'ulong_ptr dwExtraInfo;'

Global $hFunc, $pFunc
Global $hHook, $hMod
Global $iCounter = 0 ; The variable in question.

$hFunc = DllCallbackRegister('_MouseProc', "lresult", "int;wparam;lparam")
$pFunc = DllCallbackGetPtr($hFunc)
$hMod = _WinAPI_GetModuleHandle(0)

$hHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, $pFunc, $hMod)

While 1
    Sleep(20)
WEnd

Func _MouseProc($iCode, $iwParam, $ilParam)
    Local $tMSLL, $iDelta

    If $iCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)

    $tMSLL = DllStructCreate($tagMSLLHOOKSTRUCT, $ilParam)

    If $iwParam = $WM_MOUSEWHEEL Then
        $iDelta = BitShift(DllStructGetData($tMSLL, 'mouseData'), 16)
        If $iDelta < 0 Then
            $iCounter -= 1
        Else
            $iCounter += 1
        EndIf

        ConsoleWrite($iCounter & @LF)
    EndIf

    Return 1
    Return _WinAPI_CallNextHookEx($hHook, $iCode, $iwParam, $ilParam)
EndFunc

Func _Close()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hHook)
    Exit
EndFunc

Jos

Edit: This line was changed:

$hFunc = DllCallbackRegister('_MouseProc', 'lresult', 'int;int;int')

 

Edited April 21, 2017 by Jos

[Azevedo]

Thanks Jos! Now it works
 

$hFunc = DllCallbackRegister('_MouseProc', "lresult", "int;wparam;lparam")
; $hFunc = DllCallbackRegister('_MouseProc', 'lresult', 'int;int;int') ; works in x86 only

 

[jchd]

Just for fun, I tried again and can't get the hard crash under W7, ran as .au3 or compiled, x64 or x32.

[Jos]

It just acts weird, sometimes hanged a bit and required quite some back and forth rolling of the mousewheel for me, but could get it to crash each time.

Jos