Jump to content

[SOLVED] Help with context menu on listview


Luigi
 Share

Recommended Posts

Greetings forum,

Hi develop this script, to use context menu with listview.

It's work fine, run and click with left or right mouse button, you see on Console the id from item.

If you click none, the id is -1, like this:

$NM_RCLICK[-1]
$NM_RCLICK[-1]
$NM_RCLICK[2]
$NM_RCLICK[1]
$NM_RCLICK[0]
$NM_RCLICK[1]

That is correct.

But if you uncoment the line:

GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

You have to click with left button (over item or none) and after click with right button.

LeftButton is to update $HOSTS_INDEX.

RightButton is to open ContextMenu.

 

Exist another way to update $HOSTS_INDEX?

Example:

Call WM_NOTIFY every time WM_CONTEXTMENU is called?

I ask this, becouse i cant understanding why $HOSTS_INDEX is not updated when WM_CONTEXTMENU is uncomented.

Someone can explain or help me?

 

Best regards.

;~ #AutoIt3Wrapper_AU3Check_Parameters= -q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
;~ #Tidy_Parameters=/sf

#include-once
#include-once
#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

#include <Timers.au3>
#include <AutoItConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <FontConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <String.au3>


OnAutoItExitRegister("OnExit")

Opt("GUIOnEventMode", 1)
Opt("GUIEventOptions", 1)
Opt("MustDeclareVars", 1)

Global Enum $eCREATE = 1000, $eUPDATE, $eDELETE, $eICON_TABLE, $eDEFAULT, $eEXPORT_HTML
Global Const $EMPTY = -1

Global $HOSTS_INDEX = -1
Global $HOST_Host

Global $aGuiSize[2] = [800, 600]
Global $sGuiTitle = "GuiTitle"
Global $hGui
Global $iList, $hList

$hGui = GUICreate($sGuiTitle, $aGuiSize[0], $aGuiSize[1])
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

$iList = GUICtrlCreateListView("nome", 20, 50, 240, 490)
$hList = GUICtrlGetHandle($iList)
_GUICtrlListView_SetColumnWidth($hList, 0, 236)

Populate()

GUISetState(@SW_SHOW, $hGui)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
;~ GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

While Sleep(25)
WEnd

Func OnExit()
    GUISetState($hGui, @SW_HIDE)
    GUIDelete($hGui)
EndFunc   ;==>OnExit

Func Quit()
    Exit
EndFunc   ;==>Quit

Func Populate()
    Local $arr[4] = [3, "nome 1", "nome 2", "nome 3"]
    _GUICtrlListView_BeginUpdate($hList)
    _GUICtrlListView_DeleteAllItems($hList)
    For $ii = 1 To $arr[0]
        _GUICtrlListView_AddItem($hList, $arr[$ii])
    Next
    _GUICtrlListView_SetItemSelected($hList, 0, True, True)
    _GUICtrlListView_EndUpdate($hList)
EndFunc   ;==>Populate

Func WM_CONTEXTMENU($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    ConsoleWrite("WM_CONTEXTMENU..( $hWnd=" & $hWnd & ", $iMsg=" & $iMsg & ", $wParam=" & $wParam & ", $lParam=" & $lParam & " )" & @LF)

    Local $exec = 0
    Local $hMenu
    Switch $wParam
        Case $hList
            Local $TRY_ID = _GUICtrlListView_GetHotItem($hList)
            If Not ($TRY_ID = $HOSTS_INDEX) Then $HOSTS_INDEX = $TRY_ID

            Local $aOrigin = _GUICtrlListView_GetOrigin($hList)

            ConsoleWrite("WM_CONTEXTMENU $HOSTS_INDEX[" & $HOSTS_INDEX & "] $aOrigin[" & _GUICtrlListView_GetOriginX($iList) & "]" & @LF)
            $hMenu = _GUICtrlMenu_CreatePopup()
            If $HOSTS_INDEX = $EMPTY Then
                _GUICtrlMenu_InsertMenuItem($hMenu, 0, "Add", $eCREATE)
            Else
                _GUICtrlMenu_InsertMenuItem($hMenu, 0, "Rename", $eUPDATE)
                _GUICtrlMenu_InsertMenuItem($hMenu, 1, "Del", $eDELETE)

            EndIf

            _GUICtrlMenu_SetMenu($hGui, $hMenu)
            $exec = _GUICtrlMenu_TrackPopupMenu($hMenu, $wParam, -1, -1, 1, 1, 2, 1)
            _GUICtrlMenu_DestroyMenu($hMenu)
    EndSwitch

    Return True
EndFunc   ;==>WM_CONTEXTMENU


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Local $TRY_ID

    Switch $hWndFrom
        Case $hList
            $TRY_ID = _GUICtrlListView_GetHotItem($hList)
            If Not ($TRY_ID = $HOSTS_INDEX) Then $HOSTS_INDEX = $TRY_ID
            Switch $iCode
                Case $NM_CLICK
                    ConsoleWrite("$NM_CLICK[" & $TRY_ID & "]" & @LF)
                    If $HOSTS_INDEX = $EMPTY Or $HOST_Host Then
;~                      HOSTS_Clear()
;~                      HOSTS_ListView_ItemCancel()
;~                      GUICtrlSetState($HOSTS_ITEM_DEL, $GUI_DISABLE)
;~                      GUICtrlSetState($HOSTS_ITEM_UPD, $GUI_DISABLE)
                    Else
                        Local $name = _GUICtrlListView_GetItemText($hList, $HOSTS_INDEX)
;~                      HOSTS_FieldLoad($name)
;~                      GUICtrlSetState($HOSTS_ITEM_DEL, $GUI_ENABLE)
;~                      GUICtrlSetState($HOSTS_ITEM_UPD, $GUI_ENABLE)
                    EndIf
                    Return 0 ; allow the default processing
                Case $NM_RCLICK
                    ConsoleWrite("$NM_RCLICK[" & $TRY_ID & "]" & @LF)
                    Return 0 ; allow the default processing
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

Edited by Luigi

Visit my repository

Link to comment
Share on other sites

What is wrong with GUICtrlCreateContextMenu?

Spoiler

Renamer - Rename files and folders, remove portions of text from the filename etc.

GPO Tool - Export/Import Group policy settings.

MirrorDir - Synchronize/Backup/Mirror Folders

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

String Trigger - Triggers pasting text or applications or internet links on specific strings.

Inconspicuous - Hide files in plain sight, not fully encrypted.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Au3Record.exe

Link to comment
Share on other sites

Greetings @careca,

GUICtrlCreateContextMenu does not work with GuiCtrlCreateListView (or I do not know how to do).

The requirement is, click with right buttom mouse over ListView, and it open a custom Contextmenu, if:

a) is over item, show: edit, delete

b] none item, show: add

 

With the example script, I can do this, but... is not perfect.

I need to improve the detection of the item with the right mouse button.

Visit my repository

Link to comment
Share on other sites

This works for me.

 

#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

; ========================================================================
; Global variables
; ========================================================================

Global Enum $idEdit = 1000, $idDelete, $idAdd

; ========================================================================
; Main
; ========================================================================

$hGUI = GUICreate('Context Menu Demo (Right Click)', 400, 300)
$hListView = _GUICtrlListView_Create($hGUI, "", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState()

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

; Load images
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
_GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 200)


; Add items
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

GUISetState()

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func ListView_RClick()
    Local $aHit

    $aHit = _GUICtrlListView_SubItemHitTest($hListView)
    If ($aHit[0] <> -1) Then
        ; Create a standard popup menu
        ; -------------------- To Do --------------------
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Edit", $idEdit)
        _GUICtrlMenu_AddMenuItem($hMenu, "Delete", $idDelete)
        ; ========================================================================
        ; Shows how to capture the context menu selections
        ; ========================================================================
        Switch _GUICtrlMenu_TrackPopupMenu($hMenu, $hListView, -1, -1, 1, 1, 2)
            Case $idEdit
                _DebugPrint("Edit: " & StringFormat("Item, SubItem [%d, %d]", $aHit[0], $aHit[1]))
            Case $idDelete
                _DebugPrint("Delete: " & StringFormat("Item, SubItem [%d, %d]", $aHit[0], $aHit[1]))
        EndSwitch
        _GUICtrlMenu_DestroyMenu($hMenu)
    Else
        ; Create a standard popup menu
        ; -------------------- To Do --------------------
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Add", $idAdd)
        ; ========================================================================
        ; Shows how to capture the context menu selections
        ; ========================================================================
        Switch _GUICtrlMenu_TrackPopupMenu($hMenu, $hListView, -1, -1, 1, 1, 2)
            Case $idAdd
                _DebugPrint("Add a New Item.")
        EndSwitch
        _GUICtrlMenu_DestroyMenu($hMenu)

    EndIf
EndFunc   ;==>ListView_RClick


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    ;$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_RCLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    ListView_RClick()
                    Return 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint

Saludos

Link to comment
Share on other sites

@Danyfirex, thank you for your reply!

 

I made one simple change...

If you only move the mouse over listview, you see:

-1 to none item

0,1 or 2 to any item

Use the right mouse and click over any item... and them... click over another item with right mouse button...

I expected the id's item was change, you can see in gui title and context menu "Edit[id item]", but, i my opnion, miss a code to handle this...

If you click with right mouse button, close the context menu, and click in another item, is perfect!

The problem is: if you not close the context menu...the id's item ( _GUICtrlListView_GetHotItem($hListView) ) was not change! It need close/destroy the context menu.
 

Maybe I use the wrong function (_GUICtrlListView_GetHotItem).

In the visual, you see the right mouse change the focus for other item (line), and you expected the code reflect the new ID.

But not work. the code to operate this, is wrong or missing, for this point.

Best regards.

#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

Global Enum $idEdit = 1000, $idDelete, $idAdd


Global $hGui = GUICreate('Context Menu Demo (Right Click)', 400, 300)
Global $hListView = _GUICtrlListView_Create($hGui, "", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
GUISetState(@SW_SHOW, $hGui)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

; Load images
Global $hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
_GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 200)


; Add items
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

GUISetState()

While Sleep(25) And GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func ListView_RClick()
    Local $aHit

    $aHit = _GUICtrlListView_SubItemHitTest($hListView)
    If ($aHit[0] <> -1) Then
        Local $TRY_ID = _GUICtrlListView_GetHotItem($hListView)
        ; Create a standard popup menu
        ; -------------------- To Do --------------------
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Edit[" & $TRY_ID & "]", $idEdit)
        _GUICtrlMenu_AddMenuItem($hMenu, "Delete", $idDelete)
        ; ========================================================================
        ; Shows how to capture the context menu selections
        ; ========================================================================
        Switch _GUICtrlMenu_TrackPopupMenu($hMenu, $hListView, -1, -1, 1, 1, 2)
            Case $idEdit
                _DebugPrint("Edit: " & StringFormat("Item, SubItem [%d, %d]", $aHit[0], $aHit[1]))
            Case $idDelete
                _DebugPrint("Delete: " & StringFormat("Item, SubItem [%d, %d]", $aHit[0], $aHit[1]))
        EndSwitch
        _GUICtrlMenu_DestroyMenu($hMenu)
    Else
        ; Create a standard popup menu
        ; -------------------- To Do --------------------
        $hMenu = _GUICtrlMenu_CreatePopup()
        _GUICtrlMenu_AddMenuItem($hMenu, "Add", $idAdd)
        ; ========================================================================
        ; Shows how to capture the context menu selections
        ; ========================================================================
        Switch _GUICtrlMenu_TrackPopupMenu($hMenu, $hListView, -1, -1, 1, 1, 2)
            Case $idAdd
                _DebugPrint("Add a New Item.")
        EndSwitch
        _GUICtrlMenu_DestroyMenu($hMenu)

    EndIf
EndFunc   ;==>ListView_RClick


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    ;$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            WinSetTitle($hGui, "", _GUICtrlListView_GetHotItem($hListView))
            Switch $iCode
                Case $NM_RCLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    ListView_RClick()
                    Return 0
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint

 

Visit my repository

Link to comment
Share on other sites

Use  Local $TRY_ID = $aHit[0]   instead  this Local $TRY_ID = _GUICtrlListView_GetHotItem($hListView)

 

Saludos

Link to comment
Share on other sites

I simply make a menu and then check the item inside the function associated.

;=========================================================================
$ContextMenu = GUICtrlCreateContextMenu($cListView)
GUICtrlCreateMenuItem("Copy to Desktop", $ContextMenu, 1)
GUICtrlSetOnEvent(-1, "Copy2Dsktp")
;=============================================================================
Func Copy2Dsktp()
    $GetLTLV = _GUICtrlListView_GetNextItem($cListView, -1, 0, 8) ;This is the one that finds it
    $SubTextFolder = _GUICtrlListView_GetItemText($cListView, $GetLTLV, 1)
    $SubTextFile = _GUICtrlListView_GetItemText($cListView, $GetLTLV, 2)
    FileCopy($SubTextFolder & $SubTextFile, @DesktopDir, 1)
    MsgBox(64, 'Info', 'Copied to desktop: ' & $SubTextFolder & $SubTextFile)
EndFunc   ;==>Copy2Dsktp
;=============================================================================

 

Spoiler

Renamer - Rename files and folders, remove portions of text from the filename etc.

GPO Tool - Export/Import Group policy settings.

MirrorDir - Synchronize/Backup/Mirror Folders

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

String Trigger - Triggers pasting text or applications or internet links on specific strings.

Inconspicuous - Hide files in plain sight, not fully encrypted.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Au3Record.exe

Link to comment
Share on other sites

Hello,

I update an exemple. It's work fine.

Thanks to @Danyfirex and @careca.

 

;~ What is wrong with GUICtrlCreateContextMenu?

;~ #AutoIt3Wrapper_AU3Check_Parameters= -q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
;~ #Tidy_Parameters=/sf

#include-once
#include-once
#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

#include <Timers.au3>
#include <AutoItConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <FontConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <String.au3>


OnAutoItExitRegister("OnExit")

Opt("GUIOnEventMode", 1)
Opt("GUIEventOptions", 1)
Opt("MustDeclareVars", 1)

Global Enum $eCREATE = 1000, $eUPDATE, $eDELETE, $eICON_TABLE, $eDEFAULT, $eEXPORT_HTML
Global Const $EMPTY = -1

Global $HOSTS_INDEX = -1
Global $HOST_Host

Global $aGuiSize[2] = [800, 600]
Global $sGuiTitle = "GuiTitle"
Global $hGui
Global $iList, $hList

$hGui = GUICreate($sGuiTitle, $aGuiSize[0], $aGuiSize[1])
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

$iList = GUICtrlCreateListView("nome", 20, 50, 240, 490)
$hList = GUICtrlGetHandle($iList)
_GUICtrlListView_SetColumnWidth($hList, 0, 236)


Populate()

GUISetState(@SW_SHOW, $hGui)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

While Sleep(25)
WEnd

Func OnExit()
    GUISetState($hGui, @SW_HIDE)
    GUIDelete($hGui)
EndFunc   ;==>OnExit

Func Quit()
    Exit
EndFunc   ;==>Quit

Func Populate()
    Local $arr[4] = [3, "nome 1", "nome 2", "nome 3"]
    _GUICtrlListView_BeginUpdate($hList)
    _GUICtrlListView_DeleteAllItems($hList)
    For $ii = 1 To $arr[0]
        _GUICtrlListView_AddItem($hList, $arr[$ii])
    Next
    _GUICtrlListView_SetItemSelected($hList, 0, True, True)
    _GUICtrlListView_EndUpdate($hList)
EndFunc   ;==>Populate

Func WM_CONTEXTMENU($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    ConsoleWrite("WM_CONTEXTMENU..( $hWnd=" & $hWnd & ", $iMsg=" & $iMsg & ", $wParam=" & $wParam & ", $lParam=" & $lParam & " )" & @LF)

    Local $exec = 0
    Local $hMenu
    Switch $wParam
        Case $hList
            Local $aHit = _GUICtrlListView_SubItemHitTest($hList)
            If Not ($aHit[0] = $HOSTS_INDEX) Then $HOSTS_INDEX = $aHit[0]

            $hMenu = _GUICtrlMenu_CreatePopup()
            If $aHit[0] = $EMPTY Then
                _GUICtrlMenu_InsertMenuItem($hMenu, 0, "Add", $eCREATE)
            Else
                _GUICtrlMenu_InsertMenuItem($hMenu, 0, "Rename", $eUPDATE)
                _GUICtrlMenu_InsertMenuItem($hMenu, 1, "Del", $eDELETE)

            EndIf

            _GUICtrlMenu_SetMenu($hGui, $hMenu)
            $exec = _GUICtrlMenu_TrackPopupMenu($hMenu, $wParam, -1, -1, 1, 1, 2, 1)
            _GUICtrlMenu_DestroyMenu($hMenu)
    EndSwitch

    Return True
EndFunc   ;==>WM_CONTEXTMENU


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Local $TRY_ID

    Switch $hWndFrom
        Case $hList
            $TRY_ID = _GUICtrlListView_GetHotItem($hList)
            If Not ($TRY_ID = $HOSTS_INDEX) Then $HOSTS_INDEX = $TRY_ID
            Switch $iCode
                Case $NM_CLICK
                    ConsoleWrite("$NM_CLICK[" & $TRY_ID & "]" & @LF)
                    If $HOSTS_INDEX = $EMPTY Or $HOST_Host Then
;~                      HOSTS_Clear()
;~                      HOSTS_ListView_ItemCancel()
;~                      GUICtrlSetState($HOSTS_ITEM_DEL, $GUI_DISABLE)
;~                      GUICtrlSetState($HOSTS_ITEM_UPD, $GUI_DISABLE)
                    Else
                        Local $name = _GUICtrlListView_GetItemText($hList, $HOSTS_INDEX)
;~                      HOSTS_FieldLoad($name)
;~                      GUICtrlSetState($HOSTS_ITEM_DEL, $GUI_ENABLE)
;~                      GUICtrlSetState($HOSTS_ITEM_UPD, $GUI_ENABLE)
                    EndIf
                    Return 0 ; allow the default processing
                Case $NM_RCLICK
                    ConsoleWrite("$NM_RCLICK[" & $TRY_ID & "]" & @LF)
                    Return 0 ; allow the default processing
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

Visit my repository

Link to comment
Share on other sites

;~ #AutoIt3Wrapper_AU3Check_Parameters= -q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
;~ #Tidy_Parameters=/sf

#include-once
#include-once
#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>

#include <Timers.au3>
#include <AutoItConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <FontConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <String.au3>


OnAutoItExitRegister("OnExit")

Opt("GUIOnEventMode", 1)
Opt("GUIEventOptions", 1)
Opt("MustDeclareVars", 1)

Global Enum $eCREATE = 1000, $eUPDATE, $eDELETE, $eICON_TABLE, $eDEFAULT, $eEXPORT_HTML
Global Const $EMPTY = -1

Global $HOSTS_INDEX = -1
Global $HOST_Host

Global $aGuiSize[2] = [800, 600]
Global $sGuiTitle = "GuiTitle"
Global $hGui
Global $iList, $hList

$hGui = GUICreate($sGuiTitle, $aGuiSize[0], $aGuiSize[1])
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

$iList = GUICtrlCreateListView("nome", 20, 50, 240, 490)
$hList = GUICtrlGetHandle($iList)
_GUICtrlListView_SetColumnWidth($hList, 0, 236)

;=========================================================================
Global $ContextMenu = GUICtrlCreateContextMenu($iList)
GUICtrlCreateMenuItem("Rename", $ContextMenu, 1)
GUICtrlSetOnEvent(-1, "Rename")
GUICtrlCreateMenuItem("Del", $ContextMenu, 2)
GUICtrlSetOnEvent(-1, "Del")
;=============================================================================

Populate()

GUISetState(@SW_SHOW, $hGui)

While 1
Sleep(100)
WEnd

;=============================================================================
Func Rename()
   Local $GetLTLV = _GUICtrlListView_GetNextItem($iList, -1, 0, 8) ;This is the one that finds it
   Local $SubText = _GUICtrlListView_GetItemText($iList, $GetLTLV, 0)
    Local $inputb = InputBox('Rename', '')
    If not @error Then
        _GUICtrlListView_SetItem($iList, $inputb, $GetLTLV, 0)
    EndIf
EndFunc   ;==>Copy2Dsktp
;=============================================================================
Func Del()
   Local $GetLTLV = _GUICtrlListView_GetNextItem($iList, -1, 0, 8) ;This is the one that finds it
   Local $SubText = _GUICtrlListView_GetItemText($iList, $GetLTLV, 0)
   _GUICtrlListView_DeleteItem ($iList, $GetLTLV)
EndFunc   ;==>Copy2Dsktp
;=============================================================================

Func OnExit()
    GUISetState($hGui, @SW_HIDE)
    GUIDelete($hGui)
EndFunc   ;==>OnExit

Func Quit()
    Exit
EndFunc   ;==>Quit

Func Populate()
    Local $arr[4] = [3, "nome 1", "nome 2", "nome 3"]
    _GUICtrlListView_BeginUpdate($hList)
    _GUICtrlListView_DeleteAllItems($hList)
    For $ii = 1 To $arr[0]
        _GUICtrlListView_AddItem($hList, $arr[$ii])
    Next
    _GUICtrlListView_SetItemSelected($hList, 0, True, True)
    _GUICtrlListView_EndUpdate($hList)
EndFunc   ;==>Populate

Another, simpler way in my view.

Spoiler

Renamer - Rename files and folders, remove portions of text from the filename etc.

GPO Tool - Export/Import Group policy settings.

MirrorDir - Synchronize/Backup/Mirror Folders

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

String Trigger - Triggers pasting text or applications or internet links on specific strings.

Inconspicuous - Hide files in plain sight, not fully encrypted.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Au3Record.exe

Link to comment
Share on other sites

@careca your example does not show add when you click where there are not items.

 

Saludos

Link to comment
Share on other sites

hmmm

 

#include-once
#include <Array.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <SendMessage.au3>
#include <GUIConstantsEx.au3>
#include <Timers.au3>
#include <AutoItConstants.au3>
#include <EditConstants.au3>
#include <File.au3>
#include <Misc.au3>
#include <FontConstants.au3>
#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <TreeViewConstants.au3>
#include <String.au3>


OnAutoItExitRegister("OnExit")

Opt("GUIOnEventMode", 1)
Opt("GUIEventOptions", 1)
Opt("MustDeclareVars", 1)

Global $aGuiSize[2] = [800, 600]
Global $sGuiTitle = "GuiTitle"
Global $hGui, $CursorInfo
Global $iList, $hList, $GetLTLV

$hGui = GUICreate($sGuiTitle, $aGuiSize[0], $aGuiSize[1])
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")
GUISetState(@SW_SHOW, $hGui)
$iList = GUICtrlCreateListView("nome", 20, 50, 240, 490, -1, $LVS_EX_TRACKSELECT)
$hList = GUICtrlGetHandle($iList)
_GUICtrlListView_SetColumnWidth($hList, 0, 236)

;=========================================================================
Global $ContextMenu = GUICtrlCreateContextMenu($iList)
Local $Ren = GUICtrlCreateMenuItem("Rename", $ContextMenu, 1)
GUICtrlSetOnEvent(-1, "Rename")
Local $Del = GUICtrlCreateMenuItem("Del", $ContextMenu, 2)
GUICtrlSetOnEvent(-1, "Del")
Local $AddCtx = GUICtrlCreateMenuItem("Add", $ContextMenu, 3)
GUICtrlSetOnEvent(-1, "Add")
GUICtrlSetState($AddCtx, $GUI_DISABLE)
;=============================================================================

Populate()

While 1
    $CursorInfo = GUIGetCursorInfo($hGui)
    ConsoleWrite($CursorInfo[4] &' - '&@MSEC&@CRLF)
    If $CursorInfo[4] = 3 Then
                ;If _IsPressed("02") Then
                _GUICtrlListView_SetHoverTime ( $iList, 50 )
                    $GetLTLV = _GUICtrlListView_GetNextItem($iList, -1, 0, 8)
                    ConsoleWrite('$GetLTLV '&$GetLTLV&@CRLF)
                    If $GetLTLV = -1 Then
                        GUICtrlSetState($AddCtx, $GUI_ENABLE)
                        GUICtrlSetState($Ren, $GUI_DISABLE)
                        GUICtrlSetState($Del, $GUI_DISABLE)
                    Else
                        GUICtrlSetState($AddCtx, $GUI_DISABLE)
                        GUICtrlSetState($Ren, $GUI_ENABLE)
                        GUICtrlSetState($Del, $GUI_ENABLE)
                    EndIf
                ;EndIf
    EndIf
Sleep(100)
WEnd

;=============================================================================
Func Rename()
   Local $GetLTLV = _GUICtrlListView_GetNextItem($iList, -1, 0, 8) ;This is the one that finds it
   Local $SubText = _GUICtrlListView_GetItemText($iList, $GetLTLV, 0)
    Local $inputb = InputBox('Rename', '')
    If not @error Then
        _GUICtrlListView_SetItem($iList, $inputb, $GetLTLV, 0)
    EndIf
EndFunc   ;==>Copy2Dsktp
;=============================================================================
Func Del()
   Local $GetLTLV = _GUICtrlListView_GetNextItem($iList, -1, 0, 8) ;This is the one that finds it
   Local $SubText = _GUICtrlListView_GetItemText($iList, $GetLTLV, 0)
   _GUICtrlListView_DeleteItem ($iList, $GetLTLV)
EndFunc   ;==>Copy2Dsktp
;=============================================================================
Func Add()
   _GUICtrlListView_AddItem ($iList, '123')
EndFunc   ;==>Copy2Dsktp
;=============================================================================

Func OnExit()
    GUISetState($hGui, @SW_HIDE)
    GUIDelete($hGui)
EndFunc   ;==>OnExit

Func Quit()
    Exit
EndFunc   ;==>Quit

Func Populate()
    Local $arr[4] = [3, "nome 1", "nome 2", "nome 3"]
    _GUICtrlListView_BeginUpdate($hList)
    _GUICtrlListView_DeleteAllItems($hList)
    For $ii = 1 To $arr[0]
        _GUICtrlListView_AddItem($hList, $arr[$ii])
    Next
    _GUICtrlListView_SetItemSelected($hList, 0, True, True)
    _GUICtrlListView_EndUpdate($hList)
EndFunc   ;==>Populate

 

Spoiler

Renamer - Rename files and folders, remove portions of text from the filename etc.

GPO Tool - Export/Import Group policy settings.

MirrorDir - Synchronize/Backup/Mirror Folders

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

String Trigger - Triggers pasting text or applications or internet links on specific strings.

Inconspicuous - Hide files in plain sight, not fully encrypted.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Au3Record.exe

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

×
×
  • Create New...